meta-audio-4a-framework/recipes-multimedia/alsa/alsa-utils_1.1.6.bb

   1 SUMMARY = "ALSA sound utilities"
   2 HOMEPAGE = "http://www.alsa-project.org"
   3 BUGTRACKER = "http://alsa-project.org/main/index.php/Bug_Tracking"
   4 SECTION = "console/utils"
   5 LICENSE = "GPLv2+"
   6 LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \
   7                     file://alsactl/utils.c;beginline=1;endline=20;md5=2ce7f7b6739487fb72c689d46521f958"
   8 DEPENDS = "alsa-lib ncurses libsamplerate0"
   9
  10 PACKAGECONFIG ??= "udev"
  11
  12 # alsabat can be built also without fftw support (with reduced functionality).
  13 # It would be better to always enable alsabat, but provide an option for
  14 # enabling/disabling fftw. The configure script doesn't support that, however
  15 # (at least in any obvious way), so for now we only support alsabat with fftw
  16 # or no alsabat at all.
  17 PACKAGECONFIG[bat] = "--enable-bat,--disable-bat,fftwf"
  18
  19 PACKAGECONFIG[udev] = "--with-udev-rules-dir=`pkg-config --variable=udevdir udev`/rules.d,--with-udev-rules-dir=/unwanted/rules.d,udev"
  20 PACKAGECONFIG[manpages] = "--enable-xmlto, --disable-xmlto, xmlto-native docbook-xml-dtd4-native docbook-xsl-stylesheets-native"
  21
  22 MIRRORS += "\
  23 ftp://ftp.alsa-project.org    http://www.mirrorservice.org/sites/ftp.alsa-project.org \n \
  24 "
  25
  26 SRC_URI = "ftp://ftp.alsa-project.org/pub/utils/alsa-utils-${PV}.tar.bz2 \
  27           "
  28
  29 SRC_URI[md5sum] = "50ae75567459646b843bed78d916b002"
  30 SRC_URI[sha256sum] = "155caecc40b2220f686f34ba3655a53e3bdbc0586adb1056733949feaaf7d36e"
  31
  32 # On build machines with python-docutils (not python3-docutils !!) installed
  33 # rst2man (not rst2man.py) is detected and compile fails with
  34 # | make[1]: *** No rule to make target 'alsaucm.1', needed by 'all-am'.  Stop.
  35 # Avoid this by disabling expicitly
  36 EXTRA_OECONF = "--disable-rst2man"
  37
  38 inherit autotools gettext pkgconfig manpages
  39
  40 # This are all packages that we need to make. Also, the now empty alsa-utils
  41 # ipk depends on them.
  42
  43 ALSA_UTILS_PKGS = "\
  44              ${@bb.utils.contains('PACKAGECONFIG', 'bat', 'alsa-utils-alsabat', '', d)} \
  45              alsa-utils-alsamixer \
  46              alsa-utils-alsatplg \
  47              alsa-utils-midi \
  48              alsa-utils-aplay \
  49              alsa-utils-amixer \
  50              alsa-utils-aconnect \
  51              alsa-utils-iecset \
  52              alsa-utils-speakertest \
  53              alsa-utils-aseqnet \
  54              alsa-utils-aseqdump \
  55              alsa-utils-alsactl \
  56              alsa-utils-alsaloop \
  57              alsa-utils-alsaucm \
  58             "
  59
  60 PACKAGES += "${ALSA_UTILS_PKGS}"
  61 RDEPENDS_${PN} += "${ALSA_UTILS_PKGS}"
  62
  63 FILES_${PN} = ""
  64 FILES_alsa-utils-alsabat     = "${bindir}/alsabat"
  65 FILES_alsa-utils-alsatplg    = "${bindir}/alsatplg"
  66 FILES_alsa-utils-aplay       = "${bindir}/aplay ${bindir}/arecord"
  67 FILES_alsa-utils-amixer      = "${bindir}/amixer"
  68 FILES_alsa-utils-alsamixer   = "${bindir}/alsamixer"
  69 FILES_alsa-utils-speakertest = "${bindir}/speaker-test ${datadir}/sounds/alsa/ ${datadir}/alsa/speaker-test/"
  70 FILES_alsa-utils-midi        = "${bindir}/aplaymidi ${bindir}/arecordmidi ${bindir}/amidi"
  71 FILES_alsa-utils-aconnect    = "${bindir}/aconnect"
  72 FILES_alsa-utils-aseqnet     = "${bindir}/aseqnet"
  73 FILES_alsa-utils-iecset      = "${bindir}/iecset"
  74 FILES_alsa-utils-alsactl     = "${sbindir}/alsactl */udev/rules.d */*/udev/rules.d ${systemd_unitdir} ${localstatedir}/lib/alsa ${datadir}/alsa/init/"
  75 FILES_alsa-utils-aseqdump    = "${bindir}/aseqdump"
  76 FILES_alsa-utils-alsaloop    = "${bindir}/alsaloop"
  77 FILES_alsa-utils-alsaucm     = "${bindir}/alsaucm"
  78
  79 SUMMARY_alsa-utils-alsabat      = "Command-line sound tester for ALSA sound card driver"
  80 SUMMARY_alsa-utils-alsatplg     = "Converts topology text files into binary format for kernel"
  81 SUMMARY_alsa-utils-aplay        = "Play (and record) sound files using ALSA"
  82 SUMMARY_alsa-utils-amixer       = "Command-line control for ALSA mixer and settings"
  83 SUMMARY_alsa-utils-alsamixer    = "ncurses-based control for ALSA mixer and settings"
  84 SUMMARY_alsa-utils-speakertest  = "ALSA surround speaker test utility"
  85 SUMMARY_alsa-utils-midi         = "Miscellaneous MIDI utilities for ALSA"
  86 SUMMARY_alsa-utils-aconnect     = "ALSA sequencer connection manager"
  87 SUMMARY_alsa-utils-aseqnet      = "Network client/server for ALSA sequencer"
  88 SUMMARY_alsa-utils-iecset       = "ALSA utility for setting/showing IEC958 (S/PDIF) status bits"
  89 SUMMARY_alsa-utils-alsactl      = "Saves/restores ALSA-settings in /etc/asound.state"
  90 SUMMARY_alsa-utils-aseqdump     = "Shows the events received at an ALSA sequencer port"
  91 SUMMARY_alsa-utils-alsaloop     = "ALSA PCM loopback utility"
  92 SUMMARY_alsa-utils-alsaucm      = "ALSA Use Case Manager"
  93
  94 RRECOMMENDS_alsa-utils-alsactl = "alsa-states"
  95
  96 ALLOW_EMPTY_alsa-utils = "1"
  97
  98 do_install() {
  99         autotools_do_install
 100
 101         # We don't ship this here because it requires a dependency on bash.
 102         # See alsa-utils-scripts_${PV}.bb
 103         rm ${D}${sbindir}/alsaconf
 104         rm ${D}${sbindir}/alsa-info.sh
 105         rm -f ${D}${sbindir}/alsabat-test.sh
 106
 107         # If udev is disabled, we told configure to install the rules
 108         # in /unwanted, so we can remove them now. If udev is enabled,
 109         # then /unwanted won't exist and this will have no effect.
 110         rm -rf ${D}/unwanted
 111 }