meta-audio-4a-framework/recipes-multimedia/alsa/alsa-tools_1.1.6.bb

   1 SUMMARY = "Advanced tools for certain ALSA sound card drivers"
   2 HOMEPAGE = "http://www.alsa-project.org"
   3 BUGTRACKER = "http://alsa-project.org/main/index.php/Bug_Tracking"
   4 SECTION = "console/utils"
   5 LICENSE = "GPLv2 & LGPLv2+"
   6 DEPENDS = "alsa-lib"
   7
   8 LIC_FILES_CHKSUM = "file://hdsploader/COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \
   9                     file://ld10k1/COPYING.LIB;md5=a916467b91076e631dd8edb7424769c7 \
  10                     "
  11
  12 SRC_URI = "ftp://ftp.alsa-project.org/pub/tools/${BP}.tar.bz2 \
  13            file://0002-Fix-clang-Wreserved-user-defined-literal-warnings.patch \
  14            file://musl.patch \
  15            "
  16
  17 SRC_URI[md5sum] = "5ca8c9437ae779997cd62fb2815fef19"
  18 SRC_URI[sha256sum] = "d69c4dc2fb641a974d9903e9eb78c94cb0c7ac6c45bae664f0c9d6c0a1593227"
  19
  20 inherit autotools-brokensep pkgconfig
  21 # brokensep as as10k1 (and probably more) fail out of tree
  22 CLEANBROKEN = "1"
  23
  24 # Here we use PACKAGECONFIG options to pick which directories we configure/build.
  25 # Remember on upgrades to check that no new tools have been added.
  26 PACKAGECONFIG ??= "as10k1 hdajacksensetest hda-verb hdsploader ld10k1 mixartloader pcxhrloader \
  27                    sb16_csp seq--sbiload sscape_ctl us428control usx2yloader vxloader \
  28                    ${@bb.utils.contains_any('DISTRO_FEATURES', '${GTK2DISTROFEATURES}', 'echomixer envy24control rmedigicontrol', '', d)} \
  29                    ${@bb.utils.contains_any('DISTRO_FEATURES', '${GTK3DISTROFEATURES}', 'hdajackretask', '', d)} \
  30                    "
  31
  32 PACKAGECONFIG[as10k1] = ""
  33 PACKAGECONFIG[echomixer] = ",,gtk+"
  34 PACKAGECONFIG[envy24control] = ",,gtk+"
  35 PACKAGECONFIG[hda-verb] = ""
  36 PACKAGECONFIG[hdajackretask] = ",,gtk+3"
  37 PACKAGECONFIG[hdajacksensetest] = ",,glib-2.0"
  38 PACKAGECONFIG[hdspconf] = ",,fltk"
  39 PACKAGECONFIG[hdsploader] = ""
  40 PACKAGECONFIG[hdspmixer] = ",,fltk"
  41 PACKAGECONFIG[hwmixvolume] = ",,,python-core python-pygtk"
  42 PACKAGECONFIG[ld10k1] = ""
  43 PACKAGECONFIG[mixartloader] = ""
  44 PACKAGECONFIG[pcxhrloader] = ""
  45 PACKAGECONFIG[qlo10k1] = ",,qt-x11-free"
  46 PACKAGECONFIG[rmedigicontrol] = ",,gtk+"
  47 PACKAGECONFIG[sb16_csp] = ""
  48 PACKAGECONFIG[seq--sbiload] = ""
  49 PACKAGECONFIG[sscape_ctl] = ""
  50 PACKAGECONFIG[us428control] = ""
  51 PACKAGECONFIG[usx2yloader] = ""
  52 PACKAGECONFIG[vxloader] = ""
  53
  54 python do_configure() {
  55     for subdir in d.getVar("PACKAGECONFIG").split():
  56         subdir = subdir.replace("--", "/")
  57         bb.note("Configuring %s" % subdir)
  58         dd = d.createCopy()
  59         dd.setVar("S", os.path.join(d.getVar("S"), subdir))
  60         bb.build.exec_func("autotools_do_configure", dd)
  61 }
  62
  63 python do_compile() {
  64     for subdir in d.getVar("PACKAGECONFIG").split():
  65         subdir = subdir.replace("--", "/")
  66         bb.note("Compiling %s" % subdir)
  67         dd = d.createCopy()
  68         dd.setVar("S", os.path.join(d.getVar("S"), subdir))
  69         bb.build.exec_func("autotools_do_compile", dd)
  70 }
  71
  72 python do_install() {
  73     for subdir in d.getVar("PACKAGECONFIG").split():
  74         subdir = subdir.replace("--", "/")
  75         bb.note("Installing %s" % subdir)
  76         dd = d.createCopy()
  77         dd.setVar("S", os.path.join(d.getVar("S"), subdir))
  78         bb.build.exec_func("autotools_do_install", dd)
  79
  80     # Just remove bash-needing init script that isn't installed as an init script
  81     try:
  82         os.remove(oe.path.join(d.getVar("D"), d.getVar("sbindir"), "ld10k1d"))
  83     except:
  84         pass
  85 }
  86
  87 FILES_${PN} += "${datadir}"