meta-audio-4a-framework/recipes-multimedia/alsa/alsa-tools_1.1.6.bb

   1 SUMMARY = "Advanced tools for certain ALSA sound card drivers"
   2 HOMEPAGE = "http://www.alsa-project.org"
   3 BUGTRACKER = "http://alsa-project.org/main/index.php/Bug_Tracking"
   4 SECTION = "console/utils"
   5 LICENSE = "GPLv2 & LGPLv2+"
   6 DEPENDS = "alsa-lib"
   7
   8 LIC_FILES_CHKSUM = "file://hdsploader/COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \
   9                     file://ld10k1/COPYING.LIB;md5=a916467b91076e631dd8edb7424769c7 \
  10                     "
  11
  12 MIRRORS += "\
  13 ftp://ftp.alsa-project.org    http://www.mirrorservice.org/sites/ftp.alsa-project.org \n \
  14 "
  15
  16 SRC_URI = "ftp://ftp.alsa-project.org/pub/tools/${BP}.tar.bz2 \
  17            file://0002-Fix-clang-Wreserved-user-defined-literal-warnings.patch \
  18            file://musl.patch \
  19            "
  20
  21 SRC_URI[md5sum] = "5ca8c9437ae779997cd62fb2815fef19"
  22 SRC_URI[sha256sum] = "d69c4dc2fb641a974d9903e9eb78c94cb0c7ac6c45bae664f0c9d6c0a1593227"
  23
  24 inherit autotools-brokensep pkgconfig
  25 # brokensep as as10k1 (and probably more) fail out of tree
  26 CLEANBROKEN = "1"
  27
  28 # Here we use PACKAGECONFIG options to pick which directories we configure/build.
  29 # Remember on upgrades to check that no new tools have been added.
  30 PACKAGECONFIG ??= "as10k1 hdajacksensetest hda-verb hdsploader ld10k1 mixartloader pcxhrloader \
  31                    sb16_csp seq--sbiload sscape_ctl us428control usx2yloader vxloader \
  32                    ${@bb.utils.contains_any('DISTRO_FEATURES', '${GTK2DISTROFEATURES}', 'echomixer envy24control rmedigicontrol', '', d)} \
  33                    ${@bb.utils.contains_any('DISTRO_FEATURES', '${GTK3DISTROFEATURES}', 'hdajackretask', '', d)} \
  34                    "
  35
  36 PACKAGECONFIG[as10k1] = ""
  37 PACKAGECONFIG[echomixer] = ",,gtk+"
  38 PACKAGECONFIG[envy24control] = ",,gtk+"
  39 PACKAGECONFIG[hda-verb] = ""
  40 PACKAGECONFIG[hdajackretask] = ",,gtk+3"
  41 PACKAGECONFIG[hdajacksensetest] = ",,glib-2.0"
  42 PACKAGECONFIG[hdspconf] = ",,fltk"
  43 PACKAGECONFIG[hdsploader] = ""
  44 PACKAGECONFIG[hdspmixer] = ",,fltk"
  45 PACKAGECONFIG[hwmixvolume] = ",,,python-core python-pygtk"
  46 PACKAGECONFIG[ld10k1] = ""
  47 PACKAGECONFIG[mixartloader] = ""
  48 PACKAGECONFIG[pcxhrloader] = ""
  49 PACKAGECONFIG[qlo10k1] = ",,qt-x11-free"
  50 PACKAGECONFIG[rmedigicontrol] = ",,gtk+"
  51 PACKAGECONFIG[sb16_csp] = ""
  52 PACKAGECONFIG[seq--sbiload] = ""
  53 PACKAGECONFIG[sscape_ctl] = ""
  54 PACKAGECONFIG[us428control] = ""
  55 PACKAGECONFIG[usx2yloader] = ""
  56 PACKAGECONFIG[vxloader] = ""
  57
  58 python do_configure() {
  59     for subdir in d.getVar("PACKAGECONFIG").split():
  60         subdir = subdir.replace("--", "/")
  61         bb.note("Configuring %s" % subdir)
  62         dd = d.createCopy()
  63         dd.setVar("S", os.path.join(d.getVar("S"), subdir))
  64         bb.build.exec_func("autotools_do_configure", dd)
  65 }
  66
  67 python do_compile() {
  68     for subdir in d.getVar("PACKAGECONFIG").split():
  69         subdir = subdir.replace("--", "/")
  70         bb.note("Compiling %s" % subdir)
  71         dd = d.createCopy()
  72         dd.setVar("S", os.path.join(d.getVar("S"), subdir))
  73         bb.build.exec_func("autotools_do_compile", dd)
  74 }
  75
  76 python do_install() {
  77     for subdir in d.getVar("PACKAGECONFIG").split():
  78         subdir = subdir.replace("--", "/")
  79         bb.note("Installing %s" % subdir)
  80         dd = d.createCopy()
  81         dd.setVar("S", os.path.join(d.getVar("S"), subdir))
  82         bb.build.exec_func("autotools_do_install", dd)
  83
  84     # Just remove bash-needing init script that isn't installed as an init script
  85     try:
  86         os.remove(oe.path.join(d.getVar("D"), d.getVar("sbindir"), "ld10k1d"))
  87     except:
  88         pass
  89 }
  90
  91 FILES_${PN} += "${datadir}"