meta-audio-4a-framework/recipes-multimedia/alsa/alsa-plugins_1.1.6.bb

   1 SUMMARY = "ALSA Plugins"
   2 HOMEPAGE = "http://alsa-project.org"
   3 BUGTRACKER = "http://alsa-project.org/main/index.php/Bug_Tracking"
   4 SECTION = "multimedia"
   5
   6 # The primary license of alsa-plugins is LGPLv2.1.
   7 #
   8 # m4/attributes.m4 is licensed under GPLv2+. m4/attributes.m4 is part of the
   9 # build system, and doesn't affect the licensing of the build result.
  10 #
  11 # The samplerate plugin source code is licensed under GPLv2+ to be consistent
  12 # with the libsamplerate license. However, if the licensee has a commercial
  13 # license for libsamplerate, the samplerate plugin may be used under the terms
  14 # of LGPLv2.1 like the rest of the plugins.
  15 LICENSE = "LGPLv2.1 & GPLv2+"
  16 LIC_FILES_CHKSUM = "\
  17         file://COPYING;md5=a916467b91076e631dd8edb7424769c7 \
  18         file://COPYING.GPL;md5=59530bdf33659b29e73d4adb9f9f6552 \
  19         file://m4/attributes.m4;endline=33;md5=b25958da44c02231e3641f1bccef53eb \
  20         file://rate/rate_samplerate.c;endline=35;md5=fd77bce85f4a338c0e8ab18430b69fae \
  21 "
  22
  23 SRC_URI = "ftp://ftp.alsa-project.org/pub/plugins/${BP}.tar.bz2"
  24 SRC_URI[md5sum] = "8387279e99feeb2ecffaac5f293223d7"
  25 SRC_URI[sha256sum] = "6f1d31ebe3b1fa1cc8dade60b7bed1cb2583ac998167002d350dc0a5e3e40c13"
  26
  27 DEPENDS += "alsa-lib"
  28
  29 inherit autotools pkgconfig
  30
  31 PACKAGECONFIG ??= "\
  32         samplerate \
  33         speexdsp \
  34         ${@bb.utils.filter('DISTRO_FEATURES', 'pulseaudio', d)} \
  35 "
  36 PACKAGECONFIG[avcodec] = "--enable-avcodec,--disable-avcodec,libav"
  37 PACKAGECONFIG[jack] = "--enable-jack,--disable-jack,jack"
  38 PACKAGECONFIG[maemo-plugin] = "--enable-maemo-plugin,--disable-maemo-plugin"
  39 PACKAGECONFIG[maemo-resource-manager] = "--enable-maemo-resource-manager,--disable-maemo-resource-manager,dbus"
  40 PACKAGECONFIG[pulseaudio] = "--enable-pulseaudio,--disable-pulseaudio,pulseaudio"
  41 PACKAGECONFIG[samplerate] = "--enable-samplerate,--disable-samplerate,libsamplerate0"
  42 PACKAGECONFIG[speexdsp] = "--with-speex=lib,--with-speex=no,speexdsp"
  43
  44 PACKAGES += "${@bb.utils.contains('PACKAGECONFIG', 'pulseaudio', 'alsa-plugins-pulseaudio-conf', '', d)}"
  45
  46 PACKAGES_DYNAMIC = "^libasound-module-.*"
  47
  48 # The alsa-plugins package doesn't itself contain anything, it just depends on
  49 # all built plugins.
  50 ALLOW_EMPTY_${PN} = "1"
  51
  52 do_install_append() {
  53         rm ${D}${libdir}/alsa-lib/*.la
  54
  55         # We use the example as is, so just drop the .example suffix.
  56         if [ "${@bb.utils.contains('PACKAGECONFIG', 'pulseaudio', 'yes', 'no', d)}" = "yes" ]; then
  57                 mv ${D}${datadir}/alsa/alsa.conf.d/99-pulseaudio-default.conf.example ${D}${datadir}/alsa/alsa.conf.d/99-pulseaudio-default.conf
  58         fi
  59 }
  60
  61 python populate_packages_prepend() {
  62     plugindir = d.expand('${libdir}/alsa-lib/')
  63     packages = " ".join(do_split_packages(d, plugindir, '^libasound_module_(.*)\.so$', 'libasound-module-%s', 'Alsa plugin for %s', extra_depends=''))
  64     d.setVar("RDEPENDS_alsa-plugins", packages)
  65 }
  66
  67 # The rate plugins create some symlinks. For example, the samplerate plugin
  68 # creates these links to the main plugin file:
  69 #
  70 #   libasound_module_rate_samplerate_best.so
  71 #   libasound_module_rate_samplerate_linear.so
  72 #   libasound_module_rate_samplerate_medium.so
  73 #   libasound_module_rate_samplerate_order.so
  74 #
  75 # The other rate plugins create similar links. We have to add the links to
  76 # FILES manually, because do_split_packages() skips the links (which is good,
  77 # because we wouldn't want do_split_packages() to create separate packages for
  78 # the symlinks).
  79 #
  80 # The symlinks cause QA errors, because usually it's a bug if a non
  81 # -dev/-dbg/-nativesdk package contains links to .so files, but in this case
  82 # the errors are false positives, so we disable the QA checks.
  83 FILES_${MLPREFIX}libasound-module-rate-lavcrate += "${libdir}/alsa-lib/*rate_lavcrate_*.so"
  84 FILES_${MLPREFIX}libasound-module-rate-samplerate += "${libdir}/alsa-lib/*rate_samplerate_*.so"
  85 FILES_${MLPREFIX}libasound-module-rate-speexrate += "${libdir}/alsa-lib/*rate_speexrate_*.so"
  86 INSANE_SKIP_${MLPREFIX}libasound-module-rate-lavcrate = "dev-so"
  87 INSANE_SKIP_${MLPREFIX}libasound-module-rate-samplerate = "dev-so"
  88 INSANE_SKIP_${MLPREFIX}libasound-module-rate-speexrate = "dev-so"
  89
  90 # 50-pulseaudio.conf defines a device named "pulse" that applications can use
  91 # if they explicitly want to use the PulseAudio plugin.
  92 # 99-pulseaudio-default.conf configures the "default" device to use the
  93 # PulseAudio plugin.
  94 FILES_${PN}-pulseaudio-conf += "\
  95         ${datadir}/alsa/alsa.conf.d/50-pulseaudio.conf \
  96         ${datadir}/alsa/alsa.conf.d/99-pulseaudio-default.conf \
  97 "
  98
  99 RDEPENDS_${PN}-pulseaudio-conf += "\
 100         libasound-module-conf-pulse \
 101         libasound-module-ctl-pulse \
 102         libasound-module-pcm-pulse \
 103 "