meta-audio-4a-framework/recipes-multimedia/alsa/alsa-lib_1.1.6.bb

   1 SUMMARY = "ALSA sound library"
   2 HOMEPAGE = "http://www.alsa-project.org"
   3 BUGTRACKER = "http://alsa-project.org/main/index.php/Bug_Tracking"
   4 SECTION = "libs/multimedia"
   5 LICENSE = "LGPLv2.1 & GPLv2+"
   6 LIC_FILES_CHKSUM = "file://COPYING;md5=a916467b91076e631dd8edb7424769c7 \
   7                     file://src/socket.c;md5=dd1bc7f44872690224d89c1a9806e495;beginline=1;endline=26 \
   8                     "
   9
  10 MIRRORS += "\
  11 ftp://ftp.alsa-project.org    http://www.mirrorservice.org/sites/ftp.alsa-project.org \n \
  12 "
  13
  14 SRC_URI = "ftp://ftp.alsa-project.org/pub/lib/${BP}.tar.bz2"
  15 SRC_URI[md5sum] = "2f981a8f7897c59ec2ddc44916d33788"
  16 SRC_URI[sha256sum] = "5f2cd274b272cae0d0d111e8a9e363f08783329157e8dd68b3de0c096de6d724"
  17
  18 inherit autotools pkgconfig
  19
  20 EXTRA_OECONF += " \
  21     ${@bb.utils.contains('TARGET_FPU', 'soft', '--with-softfloat', '', d)} \
  22     --disable-python \
  23 "
  24
  25 PACKAGES =+ "alsa-server libasound alsa-conf alsa-doc"
  26
  27 FILES_libasound = "${libdir}/libasound.so.*"
  28 FILES_alsa-server = "${bindir}/*"
  29 FILES_alsa-conf = "${datadir}/alsa/"
  30
  31 RDEPENDS_libasound = "alsa-conf"
  32
  33 # alsa-lib gets automatically added to alsa-lib-dev dependencies, but the
  34 # alsa-lib package doesn't exist. libasound is the real library package.
  35 RDEPENDS_${PN}-dev = "libasound"
  36
  37 # upgrade path
  38 RPROVIDES_${PN}-dev = "alsa-dev"
  39 RREPLACES_${PN}-dev = "alsa-dev"
  40 RCONFLICTS_${PN}-dev = "alsa-dev"
  41
  42 RPROVIDES_alsa-conf = "alsa-conf-base"
  43 RREPLACES_alsa-conf = "alsa-conf-base"
  44 RCONFLICTS_alsa-conf = "alsa-conf-base"
  45
  46 BBCLASSEXTEND = "native nativesdk"