meta-audio-4a-framework/recipes-multimedia/4a-hal-generic/4a-hal-generic_git.bb

   1 SUMMARY     = "4A - Generic HAL"
   2 DESCRIPTION = "Generic HAL in 4A (AGL Advanced Audio Agent)"
   3 HOMEPAGE    = "https://github.com/iotbzh/4a-hal-generic/"
   4 SECTION     = "apps"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
   8
   9 SRC_URI = "gitsm://github.com/iotbzh/4a-hal-generic;protocol=https;branch=${AGL_BRANCH}"
  10 SRCREV = "e94909270325accdbeba7cde9f8e9e96e554dcda"
  11
  12 DEPENDS += "lua"
  13
  14 PV = "0.1+git${SRCPV}"
  15 S  = "${WORKDIR}/git"
  16
  17 inherit afb-system-cmake
  18
  19 # FIXME:
  20 #FILES_${PN}-dev += "${INSTALL_PREFIX}/4a-hal/htdocs"
  21 #FILES_${PN} += "${INSTALL_PREFIX}/afb-aaaa"
  22 #FILES_${PN} += "${INSTALL_PREFIX}/lib"
  23
  24 # The package is machine-specific due to variable config content
  25 PACKAGE_ARCH = "${MACHINE_ARCH}"
  26
  27 # when no specific HAL is defined, use a generic usb one
  28 4A_HAL_LIST ??= "2ch-generic-usb"
  29
  30 # for specific machines, activate only known HALs
  31 4A_HAL_LIST_m3ulcb          ?= "rcar-m3 rcar-m3kf"
  32 4A_HAL_LIST_h3ulcb          ?= "rcar-m3 rcar-m3kf"
  33 4A_HAL_LIST_intel-corei7-64 ?= "intel-minnow"
  34 4A_HAL_LIST_qemux86-64      ?= "intel-qemu"
  35
  36 # Due to bug SPEC-1610, default hal for RPI3 is not active yet
  37 # 4A_HAL_LIST_raspberrypi3    ?= "raspberry-pi-3"
  38
  39 ### TODO: this list should be completed for more machines
  40
  41 do_install_append () {
  42     # get pkgdir - note that '4a-hal' comes from project ${project_git_repo}/conf.d/cmake/config.cmake
  43     PKGDIR=${D}/${INSTALL_PREFIX}/4a-hal
  44
  45     # move all config files to a 'available' dir
  46     mv $PKGDIR/etc $PKGDIR/etc.available
  47
  48     # then install only required hals files in the etc folder
  49     mkdir -p $PKGDIR/etc
  50     for x in ${4A_HAL_LIST}; do
  51         hal=hal-4a-$x.json
  52         mv -v $PKGDIR/etc.available/${hal} $PKGDIR/etc/
  53     done
  54 }