meta-app-framework/recipes-security/audit/audit_2.8.5.bb

   1 SUMMARY = "User space tools for kernel auditing"
   2 DESCRIPTION = "The audit package contains the user space utilities for \
   3 storing and searching the audit records generated by the audit subsystem \
   4 in the Linux kernel."
   5 HOMEPAGE = "http://people.redhat.com/sgrubb/audit/"
   6 SECTION = "base"
   7 LICENSE = "GPLv2+ & LGPLv2+"
   8 LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
   9
  10 SRC_URI = "git://github.com/linux-audit/${BPN}-userspace.git;branch=2.8_maintenance;protocol=https \
  11            file://Add-substitue-functions-for-strndupa-rawmemchr.patch \
  12            file://Fixed-swig-host-contamination-issue.patch \
  13            file://0001-lib-i386_table.h-add-new-syscall.patch \
  14            file://auditd \
  15            file://auditd.service \
  16            file://audit-volatile.conf \
  17 "
  18
  19 S = "${WORKDIR}/git"
  20 SRCREV = "5fae55c1ad15b3cefe6890eba7311af163e9133c"
  21
  22 inherit autotools python3native update-rc.d systemd
  23
  24 UPDATERCPN = "auditd"
  25 INITSCRIPT_NAME = "auditd"
  26 INITSCRIPT_PARAMS = "defaults"
  27
  28 SYSTEMD_PACKAGES = "auditd"
  29 SYSTEMD_SERVICE:auditd = "auditd.service"
  30
  31 DEPENDS += "python3 tcp-wrappers libcap-ng linux-libc-headers swig-native"
  32
  33 EXTRA_OECONF += "--without-prelude \
  34         --with-libwrap \
  35         --enable-gssapi-krb5=no \
  36         --with-libcap-ng=yes \
  37         --with-python3=yes \
  38         --libdir=${base_libdir} \
  39         --sbindir=${base_sbindir} \
  40         --without-python \
  41         --without-golang \
  42         --disable-zos-remote \
  43         "
  44 EXTRA_OECONF:append:arm = " --with-arm=yes"
  45 EXTRA_OECONF:append:aarch64 = " --with-aarch64=yes"
  46
  47 EXTRA_OEMAKE += "PYLIBVER='python${PYTHON_BASEVERSION}' \
  48         PYINC='${STAGING_INCDIR}/$(PYLIBVER)' \
  49         pyexecdir=${libdir}/python${PYTHON_BASEVERSION}/site-packages \
  50         STDINC='${STAGING_INCDIR}' \
  51         pkgconfigdir=${libdir}/pkgconfig \
  52         "
  53
  54 SUMMARY:audispd-plugins = "Plugins for the audit event dispatcher"
  55 DESCRIPTION:audispd-plugins = "The audispd-plugins package provides plugins for the real-time \
  56 interface to the audit system, audispd. These plugins can do things \
  57 like relay events to remote machines or analyze events for suspicious \
  58 behavior."
  59
  60 PACKAGES =+ "audispd-plugins"
  61 PACKAGES += "auditd ${PN}-python"
  62
  63 FILES:${PN} = "${sysconfdir}/libaudit.conf ${base_libdir}/libaudit.so.1* ${base_libdir}/libauparse.so.*"
  64 FILES:auditd += "${bindir}/* ${base_sbindir}/* ${sysconfdir}/*"
  65 FILES:audispd-plugins += "${sysconfdir}/audisp/audisp-remote.conf \
  66         ${sysconfdir}/audisp/plugins.d/au-remote.conf \
  67         ${sbindir}/audisp-remote ${localstatedir}/spool/audit \
  68         "
  69 FILES:${PN}-dbg += "${libdir}/python${PYTHON_BASEVERSION}/*/.debug"
  70 FILES:${PN}-python = "${libdir}/python${PYTHON_BASEVERSION}"
  71
  72 CONFFILES:auditd += "${sysconfdir}/audit/audit.rules"
  73 RDEPENDS:auditd += "bash"
  74
  75 do_install:append() {
  76         rm -f ${D}/${libdir}/python${PYTHON_BASEVERSION}/site-packages/*.a
  77         rm -f ${D}/${libdir}/python${PYTHON_BASEVERSION}/site-packages/*.la
  78
  79         # reuse auditd config
  80         [ ! -e ${D}/etc/default ] && mkdir ${D}/etc/default
  81         mv ${D}/etc/sysconfig/auditd ${D}/etc/default
  82         rmdir ${D}/etc/sysconfig/
  83
  84         # replace init.d
  85         install -D -m 0755 ${WORKDIR}/auditd ${D}/etc/init.d/auditd
  86         rm -rf ${D}/etc/rc.d
  87
  88         if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  89                 install -d ${D}${sysconfdir}/tmpfiles.d/
  90                 install -m 0644 ${WORKDIR}/audit-volatile.conf ${D}${sysconfdir}/tmpfiles.d/
  91         fi
  92
  93         # install systemd unit files
  94         install -d ${D}${systemd_unitdir}/system
  95         install -m 0644 ${WORKDIR}/auditd.service ${D}${systemd_unitdir}/system
  96
  97         # audit-2.5 doesn't install any rules by default, so we do that here
  98         mkdir -p ${D}/etc/audit ${D}/etc/audit/rules.d
  99         cp ${S}/rules/10-base-config.rules ${D}/etc/audit/rules.d/audit.rules
 100
 101         chmod 750 ${D}/etc/audit ${D}/etc/audit/rules.d
 102         chmod 640 ${D}/etc/audit/auditd.conf ${D}/etc/audit/rules.d/audit.rules
 103
 104         # Based on the audit.spec "Copy default rules into place on new installation"
 105         cp ${D}/etc/audit/rules.d/audit.rules ${D}/etc/audit/audit.rules
 106 }