meta-app-framework/recipes-core/applaunchd/applaunchd_git.bb

   1 SUMMARY     = "AGL Application Launcher service"
   2 DESCRIPTION = "AGL Application Launcher service build with recipe method"
   3 HOMEPAGE    = "https://git.automotivelinux.org/src/applaunchd"
   4 SECTION     = "apps"
   5 LICENSE     = "Apache-2.0"
   6 LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
   7
   8 DEPENDS = " \
   9     glib-2.0 \
  10     glib-2.0-native \
  11     systemd \
  12 "
  13
  14 PV = "2.0+git${SRCPV}"
  15
  16 SRC_URI = " \
  17     git://gerrit.automotivelinux.org/gerrit/src/applaunchd;protocol=https;branch=${AGL_BRANCH}  \
  18     file://agl-app@.service \
  19     file://agl-app-web@.service \
  20     file://agl-app-flutter@.service \
  21     file://no-network.conf \
  22     file://private-tmp.conf \
  23 "
  24 SRCREV = "c675bafdf15cc19276bd8276c34f56404a5ecb62"
  25
  26 S = "${WORKDIR}/git"
  27
  28 inherit meson pkgconfig
  29
  30 do_install:append() {
  31     # Install generic template for all agl-app services
  32     install -d ${D}${systemd_system_unitdir}
  33     install -m 644 ${WORKDIR}/agl-app@.service ${D}${systemd_system_unitdir}/
  34     install -m 644 ${WORKDIR}/agl-app-web@.service ${D}${systemd_system_unitdir}/
  35     install -m 644 ${WORKDIR}/agl-app-flutter@.service ${D}${systemd_system_unitdir}/
  36
  37     # Install individual sandboxing overrides/drop-ins to be used by apps
  38     install -d ${D}${systemd_system_unitdir}/sandboxing
  39     install -m 644 ${WORKDIR}/no-network.conf ${D}${systemd_system_unitdir}/sandboxing/
  40     install -m 644 ${WORKDIR}/private-tmp.conf ${D}${systemd_system_unitdir}/sandboxing/
  41 }
  42
  43 PACKAGE_BEFORE_PN += "${PN}-template-agl-app ${PN}-template-agl-app-web ${PN}-template-agl-app-flutter"
  44
  45 FILES:${PN} += "${systemd_system_unitdir} ${datadir}/dbus-1/"
  46
  47 FILES:${PN}-template-agl-app = "${systemd_system_unitdir}/agl-app@.service"
  48
  49 FILES:${PN}-template-agl-app-web = "${systemd_system_unitdir}/agl-app-web@.service"
  50
  51 FILES:${PN}-template-agl-app-flutter = "${systemd_system_unitdir}/agl-app-flutter@.service"
  52
  53 RDEPENDS:${PN} += " \
  54     agl-session \
  55     polkit-rule-agl-app \
  56 "
  57
  58 RDEPENDS:${PN}-template-agl-app = "${PN}"
  59
  60 RDEPENDS:${PN}-template-agl-app-web = "${PN}"
  61
  62 RDEPENDS:${PN}-template-agl-app-flutter = "${PN}"