meta-app-framework/recipes-core/af-main/af-main_git.bb

   1 require af-main_${PV}.inc
   2
   3 # NOTE: using libcap-native and setcap in install doesn't work
   4 # NOTE: maybe setting afm_name to agl-framework is cleaner but has implications
   5 # NOTE: there is a hack of security for using groups and dbus (to be checked)
   6 # NOTE: using ZIP programs creates directories with mode 777 (very bad)
   7
   8 inherit cmake pkgconfig useradd systemd
   9 BBCLASSEXTEND = "native"
  10
  11 SECTION = "base"
  12
  13 DEPENDS = "openssl libxml2 xmlsec1 systemd libzip json-c systemd security-manager af-binder"
  14 DEPENDS_class-native = "openssl libxml2 xmlsec1 libzip json-c"
  15 RDEPENDS_${PN}_class-target += "af-binder-tools"
  16
  17 PACKAGE_WRITE_DEPS_append_with-lsm-smack = " smack-native libcap-native"
  18
  19 EXTRA_OECMAKE_class-native  = "\
  20         -DUSE_LIBZIP=1 \
  21         -DUSE_SIMULATION=1 \
  22         -DUSE_SDK=1 \
  23         -DAGLVERSION=${AGLVERSION} \
  24         -Dafm_name=${afm_name} \
  25         -Dafm_confdir=${afm_confdir} \
  26         -Dafm_datadir=${afm_datadir} \
  27 "
  28
  29 EXTRA_OECMAKE = "\
  30         -DUSE_LIBZIP=1 \
  31         -DUSE_SIMULATION=0 \
  32         -DUSE_SDK=0 \
  33         -DAGLVERSION=${AGLVERSION} \
  34         -Dafm_name=${afm_name} \
  35         -Dafm_confdir=${afm_confdir} \
  36         -Dafm_datadir=${afm_datadir} \
  37         -Dsystemd_units_root=${systemd_units_root} \
  38         -DUNITDIR_USER=${systemd_user_unitdir} \
  39         -DUNITDIR_SYSTEM=${systemd_system_unitdir} \
  40 "
  41
  42 # ------------------------ WARNING WARNING WARNNING ---------------------------
  43 #
  44 # ATM (FF.rc2), forcing all apps to be signed is an issue when building without
  45 # agl-devel feature. A workaround is to define ALLOW_NO_SIGNATURE=ON for all
  46 # builds but this must be removed later. See SPEC-1614 for more details.
  47 #
  48 # A variable AGL_FORBID_UNSIGNED_APPS is introduced to enable/disable this
  49 # workaround in local.conf and allow transition to signed apps:
  50 # * forbid unsigned apps by setting: AGL_FORBID_UNSIGNED_APPS="1"
  51 # * [DEFAULT] allow unsigned apps: do nothing (or set: AGL_FORBID_UNSIGNED_APPS="0")
  52 AGL_FORBID_UNSIGNED_APPS ?= "0"
  53 #
  54 # WORKAROUND:
  55 EXTRA_OECMAKE_append_agl-devel = " -DAGL_DEVEL=1"
  56 EXTRA_OECMAKE_append = " ${@bb.utils.contains('AGL_FORBID_UNSIGNED_APPS','1','','-DALLOW_NO_SIGNATURE=ON', d)}"
  57 #
  58 # Correct version (IMPORTANT TODO: to be restored later):
  59 #EXTRA_OECMAKE_append_agl-devel = " -DAGL_DEVEL=1 -DALLOW_NO_SIGNATURE=ON"
  60 #
  61 # ------------------------ WARNING WARNING WARNNING ---------------------------
  62
  63
  64 USERADD_PACKAGES = "${PN}"
  65 USERADD_PARAM_${PN} = "-g ${afm_name} -d ${afm_datadir} -r ${afm_name}"
  66 GROUPADD_PARAM_${PN} = "-r ${afm_name}"
  67
  68 FILES_${PN} += "\
  69         ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '${systemd_user_unitdir}/afm-user-daemon.service', '', d)} \
  70 "
  71 RDEPENDS_${PN}_append_with-lsm-smack = " smack bash"
  72 DEPENDS_append_with-lsm-smack = " smack-native"
  73
  74 # short hacks here
  75 SRC_URI += "\
  76         file://Hack-to-allow-the-debugging.patch \
  77 "
  78
  79 do_install_append_class-target() {
  80     install -d ${D}${bindir}
  81     install -d -m 0775 ${D}${systemd_units_root}/system
  82     install -d -m 0775 "${D}${systemd_units_root}/system/afm-user-session@.target.wants"
  83     install -d -m 0775 ${D}${systemd_units_root}/user
  84     install -d -m 0775 ${D}${systemd_units_root}/user/default.target.wants
  85     install -d -m 0775 ${D}${systemd_units_root}/user/sockets.target.wants
  86     install -d ${D}${afm_datadir}/applications
  87     install -d ${D}${afm_datadir}/icons
  88     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  89         install -d -m 0755 ${D}${systemd_user_unitdir}/default.target.wants
  90         ln -s ../afm-user-daemon.service ${D}${systemd_user_unitdir}/default.target.wants/afm-user-daemon.service
  91         ln -s ../afm-user-session.service ${D}${systemd_user_unitdir}/default.target.wants/afm-user-session.service
  92         install -d -m 0755 ${D}${systemd_system_unitdir}/multi-user.target.wants
  93         install -d -m 0755 ${D}${systemd_system_unitdir}/sockets.target.wants
  94         ln -sf ../afm-system-setup.service ${D}${systemd_system_unitdir}/multi-user.target.wants/afm-system-setup.service
  95         ln -sf ../afm-system-daemon.service ${D}${systemd_system_unitdir}/multi-user.target.wants/afm-system-daemon.service
  96         ln -sf ../afm-system-daemon.socket ${D}${systemd_system_unitdir}/sockets.target.wants/afm-system-daemon.socket
  97     fi
  98     echo "QT_WAYLAND_SHELL_INTEGRATION=ivi-shell" > ${D}${afm_confdir}/unit.env.d/qt-for-ivi-shell
  99 }
 100
 101 pkg_postinst_${PN}() {
 102     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
 103         chgrp ${afm_name} $D${systemd_units_root}/system
 104         chgrp ${afm_name} $D${systemd_units_root}/system/afm-user-session@.target.wants
 105         chgrp ${afm_name} $D${systemd_units_root}/user/default.target.wants
 106         chgrp ${afm_name} $D${systemd_units_root}/user/sockets.target.wants
 107     fi
 108     chown ${afm_name}:${afm_name} $D${afm_datadir}
 109     chown ${afm_name}:${afm_name} $D${afm_datadir}/applications
 110     chown ${afm_name}:${afm_name} $D${afm_datadir}/icons
 111 }
 112
 113 pkg_postinst_${PN}_append_with-lsm-smack() {
 114     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
 115         chsmack -a 'System::Shared' -t $D${systemd_units_root}/system
 116         chsmack -a 'System::Shared' -t $D${systemd_units_root}/system/afm-user-session@.target.wants
 117         chsmack -a 'System::Shared' -t $D${systemd_units_root}/user/default.target.wants
 118         chsmack -a 'System::Shared' -t $D${systemd_units_root}/user/sockets.target.wants
 119     fi
 120     chsmack -a 'System::Shared' -t $D${afm_datadir}
 121     chsmack -a 'System::Shared' -t $D${afm_datadir}/applications
 122     chsmack -a 'System::Shared' -t $D${afm_datadir}/icons
 123 }
 124 FILES_${PN} += "${systemd_units_root}/* ${systemd_system_unitdir} ${systemd_user_unitdir}"
 125
 126 PACKAGES =+ "${PN}-binding ${PN}-binding-dbg"
 127 FILES_${PN}-binding = " ${afb_binding_dir}/afm-main-binding.so "
 128 FILES_${PN}-binding-dbg = " ${afb_binding_dir}/.debug/afm-main-binding.so "
 129
 130 PACKAGES =+ "${PN}-tools ${PN}-tools-dbg"
 131 FILES_${PN}-tools = "${bindir}/wgtpkg-*"
 132 FILES_${PN}-tools-dbg = "${bindir}/.debug/wgtpkg-*"