meta-app-framework/recipes-core/af-main/af-main_1.0.bb

   1 require af-main_${PV}.inc
   2
   3 # NOTE: using libcap-native and setcap in install doesn't work
   4 # NOTE: there is no SYSTEMD_USER_SERVICE_...
   5 # NOTE: maybe setting afm_name to agl-framework is cleaner but has implications
   6 # NOTE: there is a hack of security for using groups and dbus (to be checked)
   7 # NOTE: using ZIP programs creates directories with mode 777 (very bad)
   8
   9 inherit cmake pkgconfig useradd systemd
  10
  11 SECTION = "base"
  12
  13 DEPENDS = "openssl libxml2 xmlsec1 systemd libzip json-c security-manager libcap-native af-binder"
  14
  15 afm_name    = "afm"
  16 afm_confdir = "${sysconfdir}/${afm_name}"
  17 afm_datadir = "${datadir}/${afm_name}"
  18 afb_binding_dir = "${libdir}/afb"
  19
  20 EXTRA_OECMAKE = "\
  21         -DUSE_LIBZIP=1 \
  22         -DUSE_SIMULATION=0 \
  23         -DUSE_SDK=0 \
  24         -Dafm_name=${afm_name} \
  25         -Dafm_confdir=${afm_confdir} \
  26         -Dafm_datadir=${afm_datadir} \
  27         -DUNITDIR_USER=${systemd_user_unitdir} \
  28         -DUNITDIR_SYSTEM=${systemd_system_unitdir} \
  29 "
  30
  31 USERADD_PACKAGES = "${PN}"
  32 USERADD_PARAM_${PN} = "-g ${afm_name} -d ${afm_datadir} -r ${afm_name}"
  33 GROUPADD_PARAM_${PN} = "-r ${afm_name}"
  34
  35 SYSTEMD_SERVICE_${PN} = "afm-system-daemon.service"
  36 SYSTEMD_AUTO_ENABLE = "enable"
  37
  38 FILES_${PN} += "\
  39         ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '${systemd_user_unitdir}/afm-user-daemon.service', '', d)} \
  40 "
  41
  42 RDEPENDS_${PN}_append_smack = " smack-userspace"
  43 DEPENDS_append_smack = " smack-userspace-native"
  44
  45 # short hack here
  46 SRC_URI += " file://Hack-to-allow-the-debugging.patch"
  47
  48 do_install_append() {
  49     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  50         mkdir -p ${D}${sysconfdir}/systemd/user/default.target.wants
  51         ln -sf ${systemd_user_unitdir}/afm-user-daemon.service ${D}${sysconfdir}/systemd/user/default.target.wants
  52     fi
  53 }
  54
  55 do_install_append_smack () {
  56     install -d ${D}/${sysconfdir}/smack/accesses.d
  57     cat > ${D}/${sysconfdir}/smack/accesses.d/default-access-domains-no-user <<EOF
  58 System User::App-Shared rwxat
  59 System User::Home       rwxat
  60 EOF
  61     chmod 0644 ${D}/${sysconfdir}/smack/accesses.d/default-access-domains-no-user
  62     install -d ${D}/${sysconfdir}/skel/app-data
  63     chsmack -a 'User::Home' -t -D ${D}/${sysconfdir}/skel
  64     chsmack -a 'User::App-Shared' -D ${D}/${sysconfdir}/skel/app-data
  65 }
  66
  67 pkg_postinst_${PN}() {
  68     mkdir -p $D${afm_datadir}/applications $D${afm_datadir}/icons
  69     setcap cap_mac_override,cap_dac_override=ep $D${bindir}/afm-system-daemon
  70     setcap cap_mac_override,cap_mac_admin,cap_setgid=ep $D${bindir}/afm-user-daemon
  71 }
  72
  73 pkg_postinst_${PN}_smack() {
  74     mkdir -p $D${afm_datadir}/applications $D${afm_datadir}/icons
  75     chown ${afm_name}:${afm_name} $D${afm_datadir} $D${afm_datadir}/applications $D${afm_datadir}/icons
  76     chsmack -a 'System::Shared' -t $D${afm_datadir} $D${afm_datadir}/applications $D${afm_datadir}/icons
  77     setcap cap_mac_override,cap_dac_override=ep $D${bindir}/afm-system-daemon
  78     setcap cap_mac_override,cap_mac_admin,cap_setgid=ep $D${bindir}/afm-user-daemon
  79 }
  80
  81 PACKAGES =+ "${PN}-binding ${PN}-binding-dbg"
  82 FILES_${PN}-binding = " ${afb_binding_dir}/afm-main-binding.so "
  83 FILES_${PN}-binding-dbg = " ${afb_binding_dir}/.debug/afm-main-binding.so "
  84
  85 PACKAGES =+ "${PN}-tools ${PN}-tools-dbg"
  86 FILES_${PN}-tools = "${bindir}/wgtpkg-*"
  87 FILES_${PN}-tools-dbg = "${bindir}/.debug/wgtpkg-*"
  88