meta-app-framework/recipes-core/af-main/af-main_1.0.bb

   1 require af-main_${PV}.inc
   2
   3 # NOTE: using libcap-native and setcap in install doesn't work
   4 # NOTE: maybe setting afm_name to agl-framework is cleaner but has implications
   5 # NOTE: there is a hack of security for using groups and dbus (to be checked)
   6 # NOTE: using ZIP programs creates directories with mode 777 (very bad)
   7
   8 inherit cmake pkgconfig useradd systemd
   9 BBCLASSEXTEND = "native"
  10
  11 SECTION = "base"
  12
  13 DEPENDS = "openssl libxml2 xmlsec1 systemd libzip json-c systemd security-manager af-binder"
  14 DEPENDS_class-native = "openssl libxml2 xmlsec1 libzip json-c"
  15 RDEPENDS_${PN}_class-target += "af-binder-tools"
  16
  17 PACKAGE_WRITE_DEPS_append_with-lsm-smack = " smack-native libcap-native"
  18
  19 EXTRA_OECMAKE_class-native  = "\
  20         -DUSE_LIBZIP=1 \
  21         -DUSE_SIMULATION=1 \
  22         -DUSE_SDK=1 \
  23         -Dafm_name=${afm_name} \
  24         -Dafm_confdir=${afm_confdir} \
  25         -Dafm_datadir=${afm_datadir} \
  26 "
  27
  28 EXTRA_OECMAKE = "\
  29         -DUSE_LIBZIP=1 \
  30         -DUSE_SIMULATION=0 \
  31         -DUSE_SDK=0 \
  32         -Dafm_name=${afm_name} \
  33         -Dafm_confdir=${afm_confdir} \
  34         -Dafm_datadir=${afm_datadir} \
  35         -Dsystemd_units_root=${systemd_units_root} \
  36         -DUNITDIR_USER=${systemd_user_unitdir} \
  37         -DUNITDIR_SYSTEM=${systemd_system_unitdir} \
  38 "
  39
  40 # ------------------------ WARNING WARNING WARNNING ---------------------------
  41 #
  42 # ATM (FF.rc2), forcing all apps to be signed is an issue when building without
  43 # agl-devel feature. A workaround is to define ALLOW_NO_SIGNATURE=ON for all
  44 # builds but this must be removed later. See SPEC-1614 for more details.
  45 #
  46 # A variable AGL_FORBID_UNSIGNED_APPS is introduced to enable/disable this
  47 # workaround in local.conf and allow transition to signed apps:
  48 # * forbid unsigned apps by setting: AGL_FORBID_UNSIGNED_APPS="1"
  49 # * [DEFAULT] allow unsigned apps: do nothing (or set: AGL_FORBID_UNSIGNED_APPS="0")
  50 AGL_FORBID_UNSIGNED_APPS ?= "0"
  51 #
  52 # WORKAROUND:
  53 EXTRA_OECMAKE_append_agl-devel = " -DAGL_DEVEL=1"
  54 EXTRA_OECMAKE_append = " ${@bb.utils.contains('AGL_FORBID_UNSIGNED_APPS','1','','-DALLOW_NO_SIGNATURE=ON', d)}"
  55 #
  56 # Correct version (IMPORTANT TODO: to be restored later):
  57 #EXTRA_OECMAKE_append_agl-devel = " -DAGL_DEVEL=1 -DALLOW_NO_SIGNATURE=ON"
  58 #
  59 # ------------------------ WARNING WARNING WARNNING ---------------------------
  60
  61
  62 USERADD_PACKAGES = "${PN}"
  63 USERADD_PARAM_${PN} = "-g ${afm_name} -d ${afm_datadir} -r ${afm_name}"
  64 GROUPADD_PARAM_${PN} = "-r ${afm_name}"
  65
  66 FILES_${PN} += "\
  67         ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '${systemd_user_unitdir}/afm-user-daemon.service', '', d)} \
  68 "
  69 RDEPENDS_${PN}_append_with-lsm-smack = " smack bash"
  70 DEPENDS_append_with-lsm-smack = " smack-native"
  71
  72 # short hacks here
  73 SRC_URI += "\
  74         file://Hack-to-allow-the-debugging.patch \
  75 "
  76
  77 do_install_append_class-target() {
  78     install -d ${D}${bindir}
  79     install -d -m 0775 ${D}${systemd_units_root}/system
  80     install -d -m 0775 "${D}${systemd_units_root}/system/afm-user-session@.target.wants"
  81     install -d -m 0775 ${D}${systemd_units_root}/user
  82     install -d -m 0775 ${D}${systemd_units_root}/user/default.target.wants
  83     install -d -m 0775 ${D}${systemd_units_root}/user/sockets.target.wants
  84     install -d ${D}${afm_datadir}/applications
  85     install -d ${D}${afm_datadir}/icons
  86     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  87         install -d -m 0755 ${D}${systemd_user_unitdir}/default.target.wants
  88         ln -s ../afm-user-daemon.service ${D}${systemd_user_unitdir}/default.target.wants/afm-user-daemon.service
  89         ln -s ../afm-user-session.service ${D}${systemd_user_unitdir}/default.target.wants/afm-user-session.service
  90         install -d -m 0755 ${D}${systemd_system_unitdir}/multi-user.target.wants
  91         install -d -m 0755 ${D}${systemd_system_unitdir}/sockets.target.wants
  92         ln -sf ../afm-system-setup.service ${D}${systemd_system_unitdir}/multi-user.target.wants/afm-system-setup.service
  93         ln -sf ../afm-system-daemon.service ${D}${systemd_system_unitdir}/multi-user.target.wants/afm-system-daemon.service
  94         ln -sf ../afm-system-daemon.socket ${D}${systemd_system_unitdir}/sockets.target.wants/afm-system-daemon.socket
  95     fi
  96     echo "QT_WAYLAND_SHELL_INTEGRATION=ivi-shell" > ${D}${afm_confdir}/unit.env.d/qt-for-ivi-shell
  97 }
  98
  99 pkg_postinst_${PN}() {
 100     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
 101         chgrp ${afm_name} $D${systemd_units_root}/system
 102         chgrp ${afm_name} $D${systemd_units_root}/system/afm-user-session@.target.wants
 103         chgrp ${afm_name} $D${systemd_units_root}/user/default.target.wants
 104         chgrp ${afm_name} $D${systemd_units_root}/user/sockets.target.wants
 105     fi
 106     chown ${afm_name}:${afm_name} $D${afm_datadir}
 107     chown ${afm_name}:${afm_name} $D${afm_datadir}/applications
 108     chown ${afm_name}:${afm_name} $D${afm_datadir}/icons
 109 }
 110
 111 pkg_postinst_${PN}_append_with-lsm-smack() {
 112     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
 113         chsmack -a 'System::Shared' -t $D${systemd_units_root}/system
 114         chsmack -a 'System::Shared' -t $D${systemd_units_root}/system/afm-user-session@.target.wants
 115         chsmack -a 'System::Shared' -t $D${systemd_units_root}/user/default.target.wants
 116         chsmack -a 'System::Shared' -t $D${systemd_units_root}/user/sockets.target.wants
 117     fi
 118     chsmack -a 'System::Shared' -t $D${afm_datadir}
 119     chsmack -a 'System::Shared' -t $D${afm_datadir}/applications
 120     chsmack -a 'System::Shared' -t $D${afm_datadir}/icons
 121 }
 122 FILES_${PN} += "${systemd_units_root}/* ${systemd_system_unitdir} ${systemd_user_unitdir}"
 123
 124 PACKAGES =+ "${PN}-binding ${PN}-binding-dbg"
 125 FILES_${PN}-binding = " ${afb_binding_dir}/afm-main-binding.so "
 126 FILES_${PN}-binding-dbg = " ${afb_binding_dir}/.debug/afm-main-binding.so "
 127
 128 PACKAGES =+ "${PN}-tools ${PN}-tools-dbg"
 129 FILES_${PN}-tools = "${bindir}/wgtpkg-*"
 130 FILES_${PN}-tools-dbg = "${bindir}/.debug/wgtpkg-*"