meta-app-framework/recipes-core/af-main/af-main_1.0.bb

   1 require af-main_${PV}.inc
   2
   3 # NOTE: using libcap-native and setcap in install doesn't work
   4 # NOTE: there is no SYSTEMD_USER_SERVICE_...
   5 # NOTE: maybe setting afm_name to agl-framework is cleaner but has implications
   6 # NOTE: there is a hack of security for using groups and dbus (to be checked)
   7 # NOTE: using ZIP programs creates directories with mode 777 (very bad)
   8
   9 inherit cmake pkgconfig useradd systemd
  10 BBCLASSEXTEND = "native"
  11
  12 SECTION = "base"
  13
  14 DEPENDS = "openssl libxml2 xmlsec1 systemd libzip json-c security-manager libcap-native af-binder"
  15 DEPENDS_class-native = "openssl libxml2 xmlsec1 libzip"
  16
  17 afm_name    = "afm"
  18 afm_confdir = "${sysconfdir}/${afm_name}"
  19 afm_datadir = "${datadir}/${afm_name}"
  20 afb_binding_dir = "${libdir}/afb"
  21
  22 EXTRA_OECMAKE_class-native  = "\
  23         -DUSE_LIBZIP=1 \
  24         -DUSE_SIMULATION=1 \
  25         -DUSE_SDK=1 \
  26         -Dafm_name=${afm_name} \
  27         -Dafm_confdir=${afm_confdir} \
  28         -Dafm_datadir=${afm_datadir} \
  29 "
  30
  31 EXTRA_OECMAKE = "\
  32         -DUSE_LIBZIP=1 \
  33         -DUSE_SIMULATION=0 \
  34         -DUSE_SDK=0 \
  35         -Dafm_name=${afm_name} \
  36         -Dafm_confdir=${afm_confdir} \
  37         -Dafm_datadir=${afm_datadir} \
  38         -DUNITDIR_USER=${systemd_user_unitdir} \
  39         -DUNITDIR_SYSTEM=${systemd_system_unitdir} \
  40 "
  41
  42 USERADD_PACKAGES = "${PN}"
  43 USERADD_PARAM_${PN} = "-g ${afm_name} -d ${afm_datadir} -r ${afm_name}"
  44 GROUPADD_PARAM_${PN} = "-r ${afm_name}"
  45
  46 SYSTEMD_SERVICE_${PN} = "afm-system-daemon.service"
  47 SYSTEMD_AUTO_ENABLE = "enable"
  48
  49 FILES_${PN} += "\
  50         ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '${systemd_user_unitdir}/afm-user-daemon.service', '', d)} \
  51 "
  52
  53 RDEPENDS_${PN}_append_smack = " smack-userspace"
  54 DEPENDS_append_smack = " smack-userspace-native"
  55
  56 # short hacks here
  57 SRC_URI += "\
  58         file://Hack-to-allow-the-debugging.patch \
  59         file://add-qt-wayland-shell-integration.patch \
  60 "
  61
  62 do_install_append() {
  63     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  64         mkdir -p ${D}${sysconfdir}/systemd/user/default.target.wants
  65         ln -sf ${systemd_user_unitdir}/afm-user-daemon.service ${D}${sysconfdir}/systemd/user/default.target.wants
  66     fi
  67 }
  68
  69 do_install_append_smack () {
  70     install -d ${D}/${sysconfdir}/smack/accesses.d
  71     cat > ${D}/${sysconfdir}/smack/accesses.d/default-access-domains-no-user <<EOF
  72 System User::App-Shared rwxat
  73 System User::Home       rwxat
  74 EOF
  75     chmod 0644 ${D}/${sysconfdir}/smack/accesses.d/default-access-domains-no-user
  76     install -d ${D}/${sysconfdir}/skel/app-data
  77     chsmack -a 'User::Home' -t -D ${D}/${sysconfdir}/skel
  78     chsmack -a 'User::App-Shared' -D ${D}/${sysconfdir}/skel/app-data
  79 }
  80
  81 pkg_postinst_${PN}() {
  82     mkdir -p $D${afm_datadir}/applications $D${afm_datadir}/icons
  83     setcap cap_mac_override,cap_dac_override=ep $D${bindir}/afm-system-daemon
  84     setcap cap_mac_override,cap_mac_admin,cap_setgid=ep $D${bindir}/afm-user-daemon
  85 }
  86
  87 pkg_postinst_${PN}_smack() {
  88     mkdir -p $D${afm_datadir}/applications $D${afm_datadir}/icons
  89     chown ${afm_name}:${afm_name} $D${afm_datadir} $D${afm_datadir}/applications $D${afm_datadir}/icons
  90     chsmack -a 'System::Shared' -t $D${afm_datadir} $D${afm_datadir}/applications $D${afm_datadir}/icons
  91     setcap cap_mac_override,cap_dac_override=ep $D${bindir}/afm-system-daemon
  92     setcap cap_mac_override,cap_mac_admin,cap_setgid=ep $D${bindir}/afm-user-daemon
  93 }
  94
  95 PACKAGES =+ "${PN}-binding ${PN}-binding-dbg"
  96 FILES_${PN}-binding = " ${afb_binding_dir}/afm-main-binding.so "
  97 FILES_${PN}-binding-dbg = " ${afb_binding_dir}/.debug/afm-main-binding.so "
  98
  99 PACKAGES =+ "${PN}-tools ${PN}-tools-dbg"
 100 FILES_${PN}-tools = "${bindir}/wgtpkg-*"
 101 FILES_${PN}-tools-dbg = "${bindir}/.debug/wgtpkg-*"
 102