meta-app-framework/recipes-core/af-main/af-main_1.0.bb

   1 require af-main_${PV}.inc
   2
   3 # NOTE: using libcap-native and setcap in install doesn't work
   4 # NOTE: there is no SYSTEMD_USER_SERVICE_...
   5 # NOTE: maybe setting afm_name to agl-framework is cleaner but has implications
   6 # NOTE: there is a hack of security for using groups and dbus (to be checked)
   7 # NOTE: using ZIP programs creates directories with mode 777 (very bad)
   8
   9 inherit cmake pkgconfig useradd systemd
  10 BBCLASSEXTEND = "native"
  11
  12 SECTION = "base"
  13
  14 DEPENDS = "openssl libxml2 xmlsec1 systemd libzip json-c systemd security-manager af-binder"
  15 DEPENDS_class-native = "openssl libxml2 xmlsec1 libzip json-c"
  16
  17 PACKAGE_WRITE_DEPS_append_smack = " smack-userspace-native libcap-native"
  18
  19 EXTRA_OECMAKE_class-native  = "\
  20         -DUSE_LIBZIP=1 \
  21         -DUSE_SIMULATION=1 \
  22         -DUSE_SDK=1 \
  23         -Dafm_name=${afm_name} \
  24         -Dafm_confdir=${afm_confdir} \
  25         -Dafm_datadir=${afm_datadir} \
  26 "
  27
  28 EXTRA_OECMAKE = "\
  29         -DUSE_LIBZIP=1 \
  30         -DUSE_SIMULATION=0 \
  31         -DUSE_SDK=0 \
  32         -Dafm_name=${afm_name} \
  33         -Dafm_confdir=${afm_confdir} \
  34         -Dafm_datadir=${afm_datadir} \
  35         -Dsystemd_units_root=${systemd_units_root} \
  36         -DUNITDIR_USER=${systemd_user_unitdir} \
  37         -DUNITDIR_SYSTEM=${systemd_system_unitdir} \
  38 "
  39
  40 EXTRA_OECMAKE_append_agl-devel = " -DAGL_DEVEL=1"
  41
  42 USERADD_PACKAGES = "${PN}"
  43 USERADD_PARAM_${PN} = "-g ${afm_name} -d ${afm_datadir} -r ${afm_name}"
  44 GROUPADD_PARAM_${PN} = "-r ${afm_name}"
  45
  46 SYSTEMD_SERVICE_${PN} = "afm-system-daemon.service"
  47 SYSTEMD_AUTO_ENABLE = "enable"
  48
  49 FILES_${PN} += "\
  50         ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '${systemd_user_unitdir}/afm-user-daemon.service', '', d)} \
  51 "
  52 RDEPENDS_${PN}_append_smack = " smack-userspace bash"
  53 DEPENDS_append_smack = " smack-userspace-native"
  54
  55 # short hacks here
  56 SRC_URI += "\
  57         file://Hack-to-allow-the-debugging.patch \
  58 "
  59
  60 # tools used to install wgt at first boot
  61 SRC_URI += "\
  62         file://afm-install \
  63 "
  64
  65 do_install_append_class-target() {
  66     install -d ${D}${bindir}
  67     install -d -m 0775 ${D}${systemd_units_root}/system
  68     install -d -m 0775 ${D}${systemd_units_root}/user
  69     install -d -m 0775 ${D}${systemd_units_root}/system/default.target.wants
  70     install -d -m 0775 ${D}${systemd_units_root}/user/default.target.wants
  71     install -d -m 0775 ${D}${systemd_units_root}/system/sockets.target.wants
  72     install -d -m 0775 ${D}${systemd_units_root}/user/sockets.target.wants
  73     install -d ${D}${afm_datadir}/applications
  74     install -d ${D}${afm_datadir}/icons
  75     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  76         mkdir -p ${D}${sysconfdir}/systemd/system/default.target.wants
  77         mkdir -p ${D}${sysconfdir}/systemd/user/default.target.wants
  78         ln -sf ${systemd_user_unitdir}/afm-user-daemon.service ${D}${sysconfdir}/systemd/user/default.target.wants
  79     fi
  80     install -m 0755 ${WORKDIR}/afm-install ${D}${bindir}
  81     echo "QT_WAYLAND_SHELL_INTEGRATION=ivi-shell" > ${D}${afm_confdir}/unit.env.d/qt-for-ivi-shell
  82 }
  83
  84 do_install_append_porter() {
  85     echo "LD_PRELOAD=/usr/lib/libEGL.so" > ${D}${afm_confdir}/unit.env.d/preload-libEGL
  86 }
  87
  88 pkg_postinst_${PN}() {
  89     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  90         for SYS in "system" "user";do
  91            for DEST in "sockets.target.wants" "default.target.wants" ".";do
  92               chgrp ${afm_name} $D${systemd_units_root}/${SYS}/${DEST};
  93            done
  94         done
  95     fi
  96     for DEST in "applications" "icons" ".";do
  97         chown ${afm_name}:${afm_name} $D${afm_datadir}/${DEST};
  98     done
  99     setcap cap_mac_override,cap_dac_override=ep $D${bindir}/afm-system-daemon
 100 }
 101
 102 pkg_postinst_${PN}_smack() {
 103     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
 104         for SYS in "system" "user";do
 105            for DEST in "sockets.target.wants" "default.target.wants" ".";do
 106               chgrp ${afm_name} $D${systemd_units_root}/${SYS}/${DEST};
 107               chsmack -a 'System::Shared' -t $D${systemd_units_root}/${SYS}/${DEST};
 108            done
 109         done
 110     fi
 111     for DEST in "applications" "icons" ".";do
 112         chown ${afm_name}:${afm_name} $D${afm_datadir}/${DEST};
 113         chsmack -a 'System::Shared' -t $D${afm_datadir}/${DEST};
 114     done
 115     setcap cap_mac_override,cap_dac_override=ep $D${bindir}/afm-system-daemon
 116 }
 117 FILES_${PN} += " ${systemd_units_root} "
 118
 119 PACKAGES =+ "${PN}-binding ${PN}-binding-dbg"
 120 FILES_${PN}-binding = " ${afb_binding_dir}/afm-main-binding.so "
 121 FILES_${PN}-binding-dbg = " ${afb_binding_dir}/.debug/afm-main-binding.so "
 122
 123 PACKAGES =+ "${PN}-tools ${PN}-tools-dbg"
 124 FILES_${PN}-tools = "${bindir}/wgtpkg-*"
 125 FILES_${PN}-tools-dbg = "${bindir}/.debug/wgtpkg-*"