meta-app-framework/recipes-core/af-main/af-main_1.0.bb

   1 require af-main_${PV}.inc
   2
   3 # NOTE: using libcap-native and setcap in install doesn't work
   4 # NOTE: there is no SYSTEMD_USER_SERVICE_...
   5 # NOTE: maybe setting afm_name to agl-framework is cleaner but has implications
   6 # NOTE: there is a hack of security for using groups and dbus (to be checked)
   7 # NOTE: using ZIP programs creates directories with mode 777 (very bad)
   8
   9 inherit cmake pkgconfig useradd systemd
  10
  11 SECTION = "base"
  12
  13 DEPENDS = "openssl libxml2 xmlsec1 systemd libzip json-c security-manager libcap-native af-binder"
  14
  15 afm_name    = "afm"
  16 afm_confdir = "${sysconfdir}/${afm_name}"
  17 afm_datadir = "${datadir}/${afm_name}"
  18 afb_binding_dir = "${libdir}/afb"
  19
  20 EXTRA_OECMAKE = "\
  21         -DUSE_LIBZIP=1 \
  22         -DUSE_SIMULATION=0 \
  23         -DUSE_SDK=0 \
  24         -Dafm_name=${afm_name} \
  25         -Dafm_confdir=${afm_confdir} \
  26         -Dafm_datadir=${afm_datadir} \
  27         -DUNITDIR_USER=${systemd_user_unitdir} \
  28         -DUNITDIR_SYSTEM=${systemd_system_unitdir} \
  29 "
  30
  31 USERADD_PACKAGES = "${PN}"
  32 USERADD_PARAM_${PN} = "-g ${afm_name} -d ${afm_datadir} -r ${afm_name}"
  33 GROUPADD_PARAM_${PN} = "-r ${afm_name}"
  34
  35 SYSTEMD_SERVICE_${PN} = "afm-system-daemon.service"
  36 SYSTEMD_AUTO_ENABLE = "enable"
  37
  38 FILES_${PN} += "\
  39         ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '${systemd_user_unitdir}/afm-user-daemon.service', '', d)} \
  40 "
  41
  42 RDEPENDS_${PN}_append_smack = " smack-userspace"
  43 DEPENDS_append_smack = " smack-userspace-native"
  44
  45 # short hacks here
  46 SRC_URI += "\
  47         file://Hack-to-allow-the-debugging.patch \
  48         file://add-qt-wayland-shell-integration.patch \
  49 "
  50
  51 do_install_append() {
  52     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  53         mkdir -p ${D}${sysconfdir}/systemd/user/default.target.wants
  54         ln -sf ${systemd_user_unitdir}/afm-user-daemon.service ${D}${sysconfdir}/systemd/user/default.target.wants
  55     fi
  56 }
  57
  58 do_install_append_smack () {
  59     install -d ${D}/${sysconfdir}/smack/accesses.d
  60     cat > ${D}/${sysconfdir}/smack/accesses.d/default-access-domains-no-user <<EOF
  61 System User::App-Shared rwxat
  62 System User::Home       rwxat
  63 EOF
  64     chmod 0644 ${D}/${sysconfdir}/smack/accesses.d/default-access-domains-no-user
  65     install -d ${D}/${sysconfdir}/skel/app-data
  66     chsmack -a 'User::Home' -t -D ${D}/${sysconfdir}/skel
  67     chsmack -a 'User::App-Shared' -D ${D}/${sysconfdir}/skel/app-data
  68 }
  69
  70 pkg_postinst_${PN}() {
  71     mkdir -p $D${afm_datadir}/applications $D${afm_datadir}/icons
  72     setcap cap_mac_override,cap_dac_override=ep $D${bindir}/afm-system-daemon
  73     setcap cap_mac_override,cap_mac_admin,cap_setgid=ep $D${bindir}/afm-user-daemon
  74 }
  75
  76 pkg_postinst_${PN}_smack() {
  77     mkdir -p $D${afm_datadir}/applications $D${afm_datadir}/icons
  78     chown ${afm_name}:${afm_name} $D${afm_datadir} $D${afm_datadir}/applications $D${afm_datadir}/icons
  79     chsmack -a 'System::Shared' -t $D${afm_datadir} $D${afm_datadir}/applications $D${afm_datadir}/icons
  80     setcap cap_mac_override,cap_dac_override=ep $D${bindir}/afm-system-daemon
  81     setcap cap_mac_override,cap_mac_admin,cap_setgid=ep $D${bindir}/afm-user-daemon
  82 }
  83
  84 PACKAGES =+ "${PN}-binding ${PN}-binding-dbg"
  85 FILES_${PN}-binding = " ${afb_binding_dir}/afm-main-binding.so "
  86 FILES_${PN}-binding-dbg = " ${afb_binding_dir}/.debug/afm-main-binding.so "
  87
  88 PACKAGES =+ "${PN}-tools ${PN}-tools-dbg"
  89 FILES_${PN}-tools = "${bindir}/wgtpkg-*"
  90 FILES_${PN}-tools-dbg = "${bindir}/.debug/wgtpkg-*"
  91