meta-app-framework/recipes-core/af-binder/af-binder_1.0.bb

   1 SUMMARY = "HTTP REST interface to automotive backends for HTML5 UI support"
   2 DESCRIPTION = "Automotive-Framework-Binder Daemon provides a HTTP REST \
   3 interface to various automotive-oriented plugins (sound, radio...), \
   4 allowing HTML5 UIs to send platform-specific requests in a secure way."
   5 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/src/app-framework-binder"
   6
   7 LICENSE = "Apache-2.0"
   8 LIC_FILES_CHKSUM = "file://LICENSE-2.0.txt;md5=3b83ef96387f14655fc854ddc3c6bd57"
   9
  10 DEPENDS = "file json-c libmicrohttpd systemd util-linux"
  11 DEPENDS += "alsa-lib glib-2.0 gssdp gupnp gupnp-av pulseaudio"
  12
  13 SRC_URI_git = "git://gerrit.automotivelinux.org/gerrit/src/app-framework-binder;protocol=https;branch=1.0"
  14 SRC_URI_files = ""
  15 SRC_URI = "${SRC_URI_git} \
  16            ${SRC_URI_files} \
  17           "
  18
  19 SRCREV = "897aa6a130eab1eb716fcc13e650fb5833a7ce32"
  20 S = "${WORKDIR}/git"
  21
  22 inherit cmake pkgconfig
  23
  24 FILES_${PN} += "${datadir}"
  25
  26 #############################################
  27 # setup meta package
  28 #############################################
  29 PACKAGES += "${PN}-meta"
  30 ALLOW_EMPTY_${PN}-meta = "1"
  31
  32 #############################################
  33 # setup sample plugin packages
  34 #############################################
  35 PACKAGES_DYNAMIC = "${PN}-plugin-*"
  36
  37 python populate_packages_prepend () {
  38     afb_libdir = d.expand('${libdir}/afb')
  39     postinst = d.getVar('plugin_postinst', True)
  40     pkgs = []
  41     pkgs_dbg = []
  42
  43     pkgs += do_split_packages(d, afb_libdir, '(.*)-api\.so$', d.expand('${PN}-plugin-%s'), 'AFB plugin for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
  44     pkgs += do_split_packages(d, afb_libdir, '(.*(?!-api))\.so$', d.expand('${PN}-plugin-%s'), 'AFB plugin for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
  45
  46     pkgs_dbg += do_split_packages(d, oe.path.join(afb_libdir, ".debug"), '(.*)-api\.so$', d.expand('${PN}-plugin-%s-dbg'), 'AFB plugin for %s, debug info', postinst=postinst, extra_depends=d.expand('${PN}'))
  47     pkgs_dbg += do_split_packages(d, oe.path.join(afb_libdir, ".debug"), '(.*(?!-api))\.so$', d.expand('${PN}-plugin-%s-dbg'), 'AFB plugin for %s, debug info', postinst=postinst, extra_depends=d.expand('${PN}'))
  48
  49     metapkg = d.getVar('PN', True) + '-meta'
  50     d.setVar('RDEPENDS_' + metapkg, ' '.join(pkgs))
  51 }
  52
  53 #############################################
  54 # setup libafbwsc package
  55 #############################################
  56 PACKAGES =+ "libafbwsc libafbwsc-dev libafbwsc-dbg"
  57
  58 FILES_libafbwsc = "\
  59         ${libdir}/libafbwsc.so.* \
  60 "
  61 FILES_libafbwsc-dev = "\
  62         ${includedir}/afb/afb-wsj1.h \
  63         ${includedir}/afb/afb-ws-client.h \
  64         ${bindir}/afb-client-demo \
  65         ${libdir}/libafbwsc.so \
  66         ${libdir}/pkgconfig/libafbwsc.pc \
  67 "
  68 FILES_libafbwsc-dbg = "\
  69         ${libdir}/.debug/libafbwsc.so.* \
  70         ${bindir}/.debug/afb-client-demo \
  71 "
  72 RDEPENDS_libafbwsc-dbg += "${PN}-dbg libafbwsc-dev"
  73