meta-app-framework/recipes-core/af-binder/af-binder_1.0.bb

   1 SUMMARY = "HTTP REST interface to automotive backends for HTML5 UI support"
   2 DESCRIPTION = "Automotive-Framework-Binder Daemon provides a HTTP REST \
   3 interface to various automotive-oriented bindings (sound, radio...), \
   4 allowing HTML5 UIs to send platform-specific requests in a secure way."
   5 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/src/app-framework-binder"
   6
   7 LICENSE = "Apache-2.0"
   8 LIC_FILES_CHKSUM = "file://LICENSE-2.0.txt;md5=3b83ef96387f14655fc854ddc3c6bd57"
   9
  10 DEPENDS = "file json-c libmicrohttpd systemd util-linux"
  11 DEPENDS += "alsa-lib glib-2.0 gssdp gupnp gupnp-av pulseaudio"
  12
  13 SRC_URI_git = "git://gerrit.automotivelinux.org/gerrit/src/app-framework-binder;protocol=https;branch=master"
  14 SRC_URI_files = ""
  15 SRC_URI = "${SRC_URI_git} \
  16            ${SRC_URI_files} \
  17           "
  18
  19 SRCREV = "bca90021828565bddb8624e8f6370bf4959cbfbf"
  20 S = "${WORKDIR}/git"
  21
  22 inherit cmake pkgconfig
  23
  24 FILES_${PN} += "${datadir}"
  25
  26 pkg_postinst_${PN}() {
  27         mkdir -p "$D${libdir}/afb"
  28 }
  29
  30 #############################################
  31 # setup meta package
  32 #############################################
  33 PACKAGES += "${PN}-meta"
  34 ALLOW_EMPTY_${PN}-meta = "1"
  35
  36 #############################################
  37 # setup sample binding packages
  38 #############################################
  39 PACKAGES_DYNAMIC = "${PN}-binding-*"
  40
  41 python populate_packages_prepend () {
  42     afb_libdir = d.expand('${libdir}/afb')
  43     postinst = d.getVar('binding_postinst', True)
  44     pkgs = []
  45     pkgs_dbg = []
  46
  47     pkgs += do_split_packages(d, afb_libdir, '(.*)-api\.so$', d.expand('${PN}-binding-%s'), 'AFB binding for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
  48     pkgs += do_split_packages(d, afb_libdir, '(.*(?!-api))\.so$', d.expand('${PN}-binding-%s'), 'AFB binding for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
  49
  50     pkgs_dbg += do_split_packages(d, oe.path.join(afb_libdir, ".debug"), '(.*)-api\.so$', d.expand('${PN}-binding-%s-dbg'), 'AFB binding for %s, debug info', postinst=postinst, extra_depends=d.expand('${PN}'))
  51     pkgs_dbg += do_split_packages(d, oe.path.join(afb_libdir, ".debug"), '(.*(?!-api))\.so$', d.expand('${PN}-binding-%s-dbg'), 'AFB binding for %s, debug info', postinst=postinst, extra_depends=d.expand('${PN}'))
  52
  53     metapkg = d.getVar('PN', True) + '-meta'
  54     d.setVar('RDEPENDS_' + metapkg, ' '.join(pkgs))
  55 }
  56
  57 #############################################
  58 # setup libafbwsc package
  59 #############################################
  60 PACKAGES =+ "libafbwsc libafbwsc-dev libafbwsc-dbg"
  61
  62 FILES_libafbwsc = "\
  63         ${libdir}/libafbwsc.so.* \
  64 "
  65 FILES_libafbwsc-dev = "\
  66         ${includedir}/afb/afb-wsj1.h \
  67         ${includedir}/afb/afb-ws-client.h \
  68         ${bindir}/afb-client-demo \
  69         ${libdir}/libafbwsc.so \
  70         ${libdir}/pkgconfig/libafbwsc.pc \
  71 "
  72 FILES_libafbwsc-dbg = "\
  73         ${libdir}/.debug/libafbwsc.so.* \
  74         ${bindir}/.debug/afb-client-demo \
  75 "
  76 RDEPENDS_libafbwsc-dbg += "${PN}-dbg libafbwsc-dev"
  77
  78 RDEPENDS_${PN}-dev += "libafbwsc-dev"
  79