meta-app-framework/recipes-core/af-binder/af-binder_1.0.bb

   1 require af-binder_${PV}.inc
   2
   3 DEPENDS = "file json-c libmicrohttpd systemd util-linux openssl cynara"
   4
   5 inherit cmake pkgconfig
   6
   7 EXTRA_OECMAKE_append_agl-devel = " -DAGL_DEVEL=ON -DINCLUDE_MONITORING=ON"
   8
   9 pkg_postinst_${PN}() {
  10         mkdir -p "$D${libdir}/afb"
  11 }
  12
  13 #############################################
  14 # setup package
  15 #############################################
  16 PACKAGES =+ "${PN}-tools ${PN}-devtools ${PN}-meta"
  17
  18 FILES_${PN} += "${datadir}"
  19
  20 FILES_${PN}_append_agl-devel = " ${libdir}/afb/monitoring"
  21
  22 ALLOW_EMPTY_${PN}-meta = "1"
  23
  24 FILES_${PN}-tools = "\
  25         ${bindir}/afb-client-demo \
  26 "
  27
  28 FILES_${PN}-devtools = "\
  29         ${bindir}/afb-exprefs \
  30         ${bindir}/afb-json2c \
  31         ${bindir}/afb-genskel \
  32 "
  33
  34 RDEPENDS_${PN}-dev += "libafbwsc-dev"
  35
  36 #############################################
  37 # setup sample binding packages
  38 #############################################
  39 PACKAGES_DYNAMIC = "${PN}-binding-*"
  40
  41 python populate_packages_prepend () {
  42     afb_libdir = d.expand('${libdir}/afb')
  43     postinst = d.getVar('binding_postinst', True)
  44     pkgs = []
  45     pkgs_dbg = []
  46
  47     pkgs += do_split_packages(d, afb_libdir, '(.*)-api\.so$', d.expand('${PN}-binding-%s'), 'AFB binding for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
  48     pkgs += do_split_packages(d, afb_libdir, '(.*(?!-api))\.so$', d.expand('${PN}-binding-%s'), 'AFB binding for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
  49
  50     pkgs_dbg += do_split_packages(d, oe.path.join(afb_libdir, ".debug"), '(.*)-api\.so$', d.expand('${PN}-binding-%s-dbg'), 'AFB binding for %s, debug info', postinst=postinst, extra_depends=d.expand('${PN}'))
  51     pkgs_dbg += do_split_packages(d, oe.path.join(afb_libdir, ".debug"), '(.*(?!-api))\.so$', d.expand('${PN}-binding-%s-dbg'), 'AFB binding for %s, debug info', postinst=postinst, extra_depends=d.expand('${PN}'))
  52
  53     metapkg = d.getVar('PN', True) + '-meta'
  54     d.setVar('RDEPENDS_' + metapkg, ' '.join(pkgs))
  55 }
  56
  57 #############################################
  58 # setup libafbwsc package
  59 #############################################
  60 PACKAGES =+ "libafbwsc libafbwsc-dev libafbwsc-dbg"
  61
  62 FILES_libafbwsc = "\
  63         ${libdir}/libafbwsc.so.* \
  64 "
  65 FILES_libafbwsc-dev = "\
  66         ${includedir}/afb/afb-wsj1.h \
  67         ${includedir}/afb/afb-ws-client.h \
  68         ${libdir}/libafbwsc.so \
  69         ${libdir}/pkgconfig/libafbwsc.pc \
  70 "
  71 FILES_libafbwsc-dbg = "\
  72         ${libdir}/.debug/libafbwsc.so.* \
  73         ${bindir}/.debug/afb-client-demo \
  74 "
  75 RDEPENDS_libafbwsc-dbg += "${PN}-dbg libafbwsc-dev"
  76
  77