meta-agl-test/recipes-external/tar/tar_1.35.bbappend

   1 # Add ptest support
   2
   3 # backport of yocto begin
   4 FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
   5
   6 # add for ptest support
   7 SRC_URI += " \
   8     file://run-ptest \
   9     file://0001-tests-fix-TESTSUITE_AT.patch \
  10     file://0002-tests-check-for-recently-fixed-bug.patch \
  11     file://0003-Exclude-VCS-directory-with-writing-from-an-archive.patch \
  12     file://0004-disable-sparse05.patch \
  13 "
  14
  15 inherit ptest
  16
  17 do_compile_ptest() {
  18     oe_runmake -C ${B}/gnu/ check
  19     oe_runmake -C ${B}/lib/ check
  20     oe_runmake -C ${B}/rmt/ check
  21     oe_runmake -C ${B}/src/ check
  22     rm -rf ${S}/tests/testsuite
  23     oe_runmake -C ${B}/tests/ testsuite
  24     oe_runmake -C ${B}/tests/ genfile checkseekhole ckmtime
  25 }
  26
  27 do_install_ptest() {
  28     install -d ${D}${PTEST_PATH}/tests/
  29     install --mode=755 ${B}/tests/atconfig ${D}${PTEST_PATH}/tests/
  30     sed -i "/abs_/d" ${D}${PTEST_PATH}/tests/atconfig
  31     echo "abs_builddir=${PTEST_PATH}/tests/" >> ${D}${PTEST_PATH}/tests/atconfig
  32     install --mode=755 ${B}/tests/atlocal ${D}${PTEST_PATH}/tests/
  33     sed -i "/PATH=/d" ${D}${PTEST_PATH}/tests/atlocal
  34     install --mode=755 ${B}/tests/genfile ${D}${PTEST_PATH}/tests/
  35     install --mode=755 ${B}/tests/checkseekhole ${D}${PTEST_PATH}/tests/
  36     install --mode=755 ${B}/tests/ckmtime ${D}${PTEST_PATH}/tests/
  37     install --mode=755 ${S}/tests/testsuite ${D}${PTEST_PATH}/tests/
  38     sed -i "s#@PTEST_PATH@#${PTEST_PATH}#g" ${D}${PTEST_PATH}/run-ptest
  39 }
  40 # backport of yocto end