meta-agl-test/recipes-external/tar/tar_1.34.bbappend

   1 # Add ptest support
   2
   3 # backport of yocto begin
   4 FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
   5
   6 # add for ptest support
   7 SRC_URI += " \
   8     file://run-ptest \
   9     file://0001-tests-fix-TESTSUITE_AT.patch \
  10     file://0002-tests-check-for-recently-fixed-bug.patch \
  11     file://0003-Exclude-VCS-directory-with-writing-from-an-archive.patch \
  12 "
  13
  14 inherit ptest
  15
  16 do_compile_ptest() {
  17     oe_runmake -C ${B}/gnu/ check
  18     oe_runmake -C ${B}/lib/ check
  19     oe_runmake -C ${B}/rmt/ check
  20     oe_runmake -C ${B}/src/ check
  21     rm -rf ${S}/tests/testsuite
  22     oe_runmake -C ${B}/tests/ testsuite
  23     oe_runmake -C ${B}/tests/ genfile checkseekhole ckmtime
  24 }
  25
  26 do_install_ptest() {
  27     install -d ${D}${PTEST_PATH}/tests/
  28     install --mode=755 ${B}/tests/atconfig ${D}${PTEST_PATH}/tests/
  29     sed -i "/abs_/d" ${D}${PTEST_PATH}/tests/atconfig
  30     echo "abs_builddir=${PTEST_PATH}/tests/" >> ${D}${PTEST_PATH}/tests/atconfig
  31     install --mode=755 ${B}/tests/atlocal ${D}${PTEST_PATH}/tests/
  32     sed -i "/PATH=/d" ${D}${PTEST_PATH}/tests/atlocal
  33     install --mode=755 ${B}/tests/genfile ${D}${PTEST_PATH}/tests/
  34     install --mode=755 ${B}/tests/checkseekhole ${D}${PTEST_PATH}/tests/
  35     install --mode=755 ${B}/tests/ckmtime ${D}${PTEST_PATH}/tests/
  36     install --mode=755 ${S}/tests/testsuite ${D}${PTEST_PATH}/tests/
  37     sed -i "s#@PTEST_PATH@#${PTEST_PATH}#g" ${D}${PTEST_PATH}/run-ptest
  38 }
  39 # backport of yocto end
  40
  41 # add for agl-test-framework
  42 do_install_ptest:append() {
  43     sed -i "s/\$at_am_msg: \$at_desc/\$at_am_msg: \$at_desc_line/g" ${D}${PTEST_PATH}/tests/testsuite
  44 }