meta-agl-test/recipes-core/kbd/kbd_2.4.0.bbappend

   1 # Add ptest support
   2 # backport of yocto
   3 #
   4 FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
   5
   6 SRC_URI += " \
   7     file://run-ptest \
   8 "
   9
  10 inherit ptest
  11
  12 do_compile_ptest() {
  13     # update DATADIR in Makefile
  14     sed -i 's,-DDATADIR=.*,-DDATADIR=\\\"${PTEST_PATH}/tests\\\" \\,g' ${B}/tests/libkeymap/Makefile
  15     sed -i 's,-DDATADIR=.*,-DDATADIR=\\\"${PTEST_PATH}/tests\\\" \\,g' ${B}/tests/helpers/Makefile
  16     sed -i 's,-DDATADIR=.*,-DDATADIR=\\\"${PTEST_PATH}/tests\\\" \\,g' ${B}/tests/libkbdfile/Makefile
  17
  18     # unset -D_TIME_BITS=64 in Makefile
  19     sed -i 's,-D_TIME_BITS=64,,g' ${B}/tests/libtswrap/Makefile
  20
  21     # recompile tests
  22     oe_runmake -C ${B}/tests/ clean
  23     oe_runmake -C ${B}/tests/
  24 }
  25
  26 do_install_ptest() {
  27     # install files from build directory
  28     install -d ${D}${PTEST_PATH}/tests/
  29     install --mode=755 ${B}/tests/atconfig ${D}${PTEST_PATH}/tests/
  30     install --mode=755 ${B}/tests/testsuite ${D}${PTEST_PATH}/tests/
  31     install -d ${D}${PTEST_PATH}/tests/libkeymap/
  32     find ${B}/tests/libkeymap/ -type f -not -name "*.o" -not -name "Makefile" \
  33         -exec install --mode=755 {} ${D}${PTEST_PATH}/tests/libkeymap/ \;
  34     install -d ${D}${PTEST_PATH}/tests/helpers/
  35     find ${B}/tests/helpers/ -type f -not -name "*.o" -not -name "Makefile" \
  36         -exec install --mode=755 {} ${D}${PTEST_PATH}/tests/helpers/ \;
  37     install -d ${D}${PTEST_PATH}/tests/libkbdfile/
  38     find ${B}/tests/libkbdfile/ -type f -not -name "*.o" -not -name "Makefile" \
  39         -exec install --mode=755 {} ${D}${PTEST_PATH}/tests/libkbdfile/ \;
  40     install -d ${D}${PTEST_PATH}/src/
  41     install --mode=755 ${B}/src/loadkeys ${D}${PTEST_PATH}/src/
  42
  43     # install files from src/data directory
  44     install -d ${D}${PTEST_PATH}/data/keymaps/i386/qwerty/
  45     install ${S}/data/keymaps/i386/qwerty/defkeymap.map ${D}${PTEST_PATH}/data/keymaps/i386/qwerty/
  46
  47     # install files from src/tests/data directory
  48     install -d ${D}${PTEST_PATH}/tests/data/
  49     install -d ${D}${PTEST_PATH}/tests/data/libkeymap/
  50     install ${S}/tests/data/libkeymap/* ${D}${PTEST_PATH}/tests/data/libkeymap/
  51     install -d ${D}${PTEST_PATH}/tests/data/alt-is-meta/
  52     install ${S}/tests/data/alt-is-meta/* ${D}${PTEST_PATH}/tests/data/alt-is-meta/
  53     install -d ${D}${PTEST_PATH}/tests/data/bkeymap-2.0.4/
  54     install ${S}/tests/data/bkeymap-2.0.4/* ${D}${PTEST_PATH}/tests/data/bkeymap-2.0.4/
  55     install -d ${D}${PTEST_PATH}/tests/data/dumpkeys-mktable/
  56     install ${S}/tests/data/dumpkeys-mktable/* ${D}${PTEST_PATH}/tests/data/dumpkeys-mktable/
  57     install -d ${D}${PTEST_PATH}/tests/data/dumpkeys-fulltable/
  58     install ${S}/tests/data/dumpkeys-fulltable/* ${D}${PTEST_PATH}/tests/data/dumpkeys-fulltable/
  59     install -d ${D}${PTEST_PATH}/tests/data/findfile/test_1/consolefonts/
  60     install ${S}/tests/data/findfile/test_1/consolefonts/* ${D}${PTEST_PATH}/tests/data/findfile/test_1/consolefonts/
  61     install -d ${D}${PTEST_PATH}/tests/data/findfile/test_0/keymaps/include/
  62     install ${S}/tests/data/findfile/test_0/keymaps/test0.map ${D}${PTEST_PATH}/tests/data/findfile/test_0/keymaps/
  63     install ${S}/tests/data/findfile/test_0/keymaps/include/* ${D}${PTEST_PATH}/tests/data/findfile/test_0/keymaps/include/
  64     install -d ${D}${PTEST_PATH}/tests/data/findfile/test_0/keymaps/i386/include/
  65     install ${S}/tests/data/findfile/test_0/keymaps/i386/include/* ${D}${PTEST_PATH}/tests/data/findfile/test_0/keymaps/i386/include/
  66     install -d ${D}${PTEST_PATH}/tests/data/findfile/test_0/keymaps/i386/qwerty/
  67     install ${S}/tests/data/findfile/test_0/keymaps/i386/qwerty/* ${D}${PTEST_PATH}/tests/data/findfile/test_0/keymaps/i386/qwerty/
  68     install -d ${D}${PTEST_PATH}/tests/data/findfile/test_0/keymaps/i386/qwertz/
  69     install ${S}/tests/data/findfile/test_0/keymaps/i386/qwertz/* ${D}${PTEST_PATH}/tests/data/findfile/test_0/keymaps/i386/qwertz/
  70
  71
  72     # update PTEST_PATH in run-ptest
  73     sed -i "s#@PTEST_PATH@#${PTEST_PATH}#g" ${D}${PTEST_PATH}/run-ptest
  74     sed -i -e 's,${B},${PTEST_PATH},g' -e 's,/\.\./kbd-2.4.0,,g' ${D}${PTEST_PATH}/tests/atconfig
  75 }
  76