meta-agl-profile-graphical/recipes-graphics/wayland/weston_8.0.%.bbappend

   1 FILESEXTRAPATHS_append := ":${THISDIR}/${PN}"
   2
   3 # NOTE:
   4 #    file://0003-compositor-drm-introduce-drm_get_dmafd_from_view.patch
   5 #    has been removed until someone more familiar with weston internals
   6 #    and waltham can take a look and update it.
   7 SRC_URI_append = "\
   8     file://0001-Allow-regular-users-to-launch-Weston_7.0.0.patch \
   9     file://0002-ivi-shell-Fix-crash-due-no-transmitter-screen.patch \
  10     file://0001-libweston-Expose-weston_output_damage-in-libweston.patch \
  11     file://0004-main-change-remoting-initialization-timing.patch \
  12     file://smack-weston \
  13     "
  14
  15 EXTRA_OEMESON_append = " -Denable-user-start=true"
  16
  17 # Workaround for incorrect upstream definition
  18 PACKAGECONFIG[remoting] = "-Dremoting=true,-Dremoting=false,gstreamer1.0 gstreamer1.0-plugins-base"
  19 PACKAGECONFIG_append = "${@bb.utils.contains('DISTRO_FEATURES', 'weston-remoting', ' remoting', '', d)}"
  20
  21 do_install_append() {
  22     if ${@bb.utils.contains('DISTRO_FEATURES', 'smack', 'true', 'false', d)}; then
  23         # Install SMACK rules
  24         install -D -m 0644 ${WORKDIR}/smack-weston ${D}${sysconfdir}/smack/accesses.d/weston
  25     fi
  26 }
  27
  28 FILES_${PN} += "\
  29     ${sysconfdir}/smack/accesses.d/* \
  30 "