meta-agl-profile-core/recipes-support/curl/curl_7.66.0.bb

   1 SUMMARY = "Command line tool and library for client-side URL transfers"
   2 HOMEPAGE = "http://curl.haxx.se/"
   3 BUGTRACKER = "http://curl.haxx.se/mail/list.cgi?list=curl-tracker"
   4 SECTION = "console/network"
   5 LICENSE = "MIT"
   6 LIC_FILES_CHKSUM = "file://COPYING;md5=be5d9e1419c4363f4b32037a2d3b7ffa"
   7
   8 SRC_URI = "http://curl.haxx.se/download/curl-${PV}.tar.bz2 \
   9            file://0001-replace-krb5-config-with-pkg-config.patch \
  10 "
  11
  12 SRC_URI[md5sum] = "c238aa394e3aa47ca4fcb0491774149f"
  13 SRC_URI[sha256sum] = "6618234e0235c420a21f4cb4c2dd0badde76e6139668739085a70c4e2fe7a141"
  14
  15 CVE_PRODUCT = "curl libcurl"
  16 inherit autotools pkgconfig binconfig multilib_header
  17
  18 PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)} gnutls libidn proxy threaded-resolver verbose zlib"
  19 PACKAGECONFIG_class-native = "ipv6 proxy ssl threaded-resolver verbose zlib"
  20 PACKAGECONFIG_class-nativesdk = "ipv6 proxy ssl threaded-resolver verbose zlib"
  21
  22 # 'ares' and 'threaded-resolver' are mutually exclusive
  23 PACKAGECONFIG[ares] = "--enable-ares,--disable-ares,c-ares"
  24 PACKAGECONFIG[brotli] = "--with-brotli,--without-brotli,brotli"
  25 PACKAGECONFIG[builtinmanual] = "--enable-manual,--disable-manual"
  26 PACKAGECONFIG[dict] = "--enable-dict,--disable-dict,"
  27 PACKAGECONFIG[gnutls] = "--with-gnutls,--without-gnutls,gnutls"
  28 PACKAGECONFIG[gopher] = "--enable-gopher,--disable-gopher,"
  29 PACKAGECONFIG[imap] = "--enable-imap,--disable-imap,"
  30 PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6,"
  31 PACKAGECONFIG[krb5] = "--with-gssapi,--without-gssapi,krb5"
  32 PACKAGECONFIG[ldap] = "--enable-ldap,--disable-ldap,"
  33 PACKAGECONFIG[ldaps] = "--enable-ldaps,--disable-ldaps,"
  34 PACKAGECONFIG[libidn] = "--with-libidn2,--without-libidn2,libidn2"
  35 PACKAGECONFIG[libssh2] = "--with-libssh2,--without-libssh2,libssh2"
  36 PACKAGECONFIG[mbedtls] = "--with-mbedtls=${STAGING_DIR_TARGET},--without-mbedtls,mbedtls"
  37 PACKAGECONFIG[nghttp2] = "--with-nghttp2,--without-nghttp2,nghttp2"
  38 PACKAGECONFIG[pop3] = "--enable-pop3,--disable-pop3,"
  39 PACKAGECONFIG[proxy] = "--enable-proxy,--disable-proxy,"
  40 PACKAGECONFIG[rtmpdump] = "--with-librtmp,--without-librtmp,rtmpdump"
  41 PACKAGECONFIG[rtsp] = "--enable-rtsp,--disable-rtsp,"
  42 PACKAGECONFIG[smb] = "--enable-smb,--disable-smb,"
  43 PACKAGECONFIG[smtp] = "--enable-smtp,--disable-smtp,"
  44 PACKAGECONFIG[ssl] = "--with-ssl --with-random=/dev/urandom,--without-ssl,openssl"
  45 PACKAGECONFIG[nss] = "--with-nss,--without-nss,nss"
  46 PACKAGECONFIG[telnet] = "--enable-telnet,--disable-telnet,"
  47 PACKAGECONFIG[tftp] = "--enable-tftp,--disable-tftp,"
  48 PACKAGECONFIG[threaded-resolver] = "--enable-threaded-resolver,--disable-threaded-resolver"
  49 PACKAGECONFIG[verbose] = "--enable-verbose,--disable-verbose"
  50 PACKAGECONFIG[zlib] = "--with-zlib=${STAGING_LIBDIR}/../,--without-zlib,zlib"
  51
  52 EXTRA_OECONF = " \
  53     --disable-libcurl-option \
  54     --disable-ntlm-wb \
  55     --enable-crypto-auth \
  56     --with-ca-bundle=${sysconfdir}/ssl/certs/ca-certificates.crt \
  57     --without-libmetalink \
  58     --without-libpsl \
  59 "
  60
  61 do_install_append_class-target() {
  62         # cleanup buildpaths from curl-config
  63         sed -i \
  64             -e 's,--sysroot=${STAGING_DIR_TARGET},,g' \
  65             -e 's,--with-libtool-sysroot=${STAGING_DIR_TARGET},,g' \
  66             -e 's|${DEBUG_PREFIX_MAP}||g' \
  67             ${D}${bindir}/curl-config
  68 }
  69
  70 PACKAGES =+ "lib${BPN}"
  71
  72 FILES_lib${BPN} = "${libdir}/lib*.so.*"
  73 RRECOMMENDS_lib${BPN} += "ca-certificates"
  74
  75 FILES_${PN} += "${datadir}/zsh"
  76
  77 inherit multilib_script
  78 MULTILIB_SCRIPTS = "${PN}-dev:${bindir}/curl-config"
  79
  80 BBCLASSEXTEND = "native nativesdk"