meta-agl-lxc/recipes-demo/refgui/refgui_git.bb

   1 DESCRIPTION = "AGL Cluster Reference GUI"
   2 LICENSE = "MIT"
   3 LIC_FILES_CHKSUM = "file://LICENSE;md5=d2e73358b6893b535d5dfc7e89dc9d67"
   4
   5 DEPENDS = " \
   6     qttools-native \
   7     qtmultimedia \
   8 "
   9
  10 BRANCH = "main"
  11 SRC_URI = "git://github.com/agl-ic-eg/refgui;protocol=https;branch=${BRANCH} \
  12            file://cluster.service \
  13 "
  14 SRCREV = "e52dd81073154838e7f417e33debc8f6794fc683"
  15
  16 S = "${WORKDIR}/git"
  17
  18 inherit cmake cmake_qt5 systemd
  19
  20 # NOTE:
  21 # The app currently assumes the mp4 video file is in the same
  22 # directory, so changing this to ${bindir} to better match FHS
  23 # requires code changes.
  24 APP_DIR = "/opt/apps"
  25 EXTRA_OECMAKE = "-DAPPS_INST_DIR=${APP_DIR}"
  26
  27 SYSTEMD_SERVICE:${PN} = "cluster.service"
  28
  29 do_install:append() {
  30     install -d ${D}${systemd_unitdir}/system
  31     install -m 0644 ${WORKDIR}/cluster.service ${D}${systemd_unitdir}/system/
  32 }
  33
  34 FILES:${PN} += "${APP_DIR}/"
  35
  36 RDEPENDS:${PN} = " \
  37     qtbase \
  38     qtdeclarative \
  39     qt3d \
  40     qtgraphicaleffects \
  41     qtmultimedia \
  42     qtquickcontrols \
  43     qtquickcontrols2 \
  44     qtwayland \
  45 "