meta-agl-kvm-demo/recipes-platform/images/agl-kvm-demo.bb

   1 SUMMARY = "AGL KVM+QEMU demo image"
   2 LICENSE = "MIT"
   3
   4 require recipes-platform/images/agl-image-compositor.bb
   5 require recipes-platform/images/agl-demo-features.inc
   6
   7 IMAGE_FEATURES += "splash package-management ssh-server-openssh"
   8
   9 IMAGE_FEATURES += " \
  10     ${@bb.utils.contains("DISTRO_FEATURES", "agl-devel", "can-test-tools" , "", d)} \
  11 "
  12
  13 # Add packages for KVM+QEMU demo platform here
  14 IMAGE_INSTALL += " \
  15     packagegroup-agl-core-connectivity \
  16     kernel-image \
  17     agl-compositor \
  18     weston-ini-conf-kvm \
  19     output-udev-conf \
  20     native-shell-client \
  21     qemu \
  22     ${QEMU_GUEST_CONFIGS} \
  23     util-linux-taskset \
  24     screen \
  25     simple-can-simulator \
  26     alsa-utils \
  27 "
  28
  29 # Potential size reduction options
  30 #IMAGE_LINGUAS = " "
  31 #NO_RECOMMENDATIONS = "1"
  32
  33 GUEST_MACHINE ?= "virtio-${TUNE_ARCH}"
  34
  35 GUEST_VM1_IMAGE ?= "agl-ivi-demo-flutter-guest"
  36 GUEST_VM2_IMAGE ?= "agl-cluster-demo-flutter-guest"
  37
  38 GUEST_IMAGES ?= "agl-kvm-guest:${GUEST_VM1_IMAGE} agl-kvm-guest:${GUEST_VM2_IMAGE}"
  39
  40 QEMU_GUEST_CONFIGS ?= ""
  41
  42 python __anonymous() {
  43     for c in (d.getVar('GUEST_IMAGES') or "").split():
  44         (mc, image) = c.split(':')
  45         dependency = 'mc::' + mc + ':' + image + ':do_image_complete'
  46         d.appendVarFlag('do_rootfs', 'mcdepends', ' ' + dependency)
  47
  48         # Assume there is a qemu-config-X package for guest image X
  49         d.appendVar('QEMU_GUEST_CONFIGS', ' ' + 'qemu-config-' + image)
  50 }
  51
  52 install_guest_images() {
  53     for c in ${GUEST_IMAGES}; do
  54         config=${c%:*}
  55         image=${c#*:}
  56         name=${image}
  57         rm -rf  ${IMAGE_ROOTFS}/var/lib/machines/${name}
  58         install -m 0755 -d ${IMAGE_ROOTFS}/var/lib/machines/${name}
  59         src="${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/${image}-${GUEST_MACHINE}.ext4"
  60         bbnote "Installing ${src}"
  61         install -m 0600 ${src} ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  62         # Placeholder until booting from kernel in VM image is worked out
  63         install -m 0600 ${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/Image-${GUEST_MACHINE}.bin ${IMAGE_ROOTFS}/var/lib/machines/${name}/
  64     done
  65 }
  66
  67 ROOTFS_POSTPROCESS_COMMAND += "install_guest_images; "
  68
  69 IMAGE_ROOTFS_EXTRA_SPACE:append = "${@bb.utils.contains("DISTRO_FEATURES", "systemd", " + 4096", "" ,d)}"