meta-agl-jailhouse/recipes-extended/jailhouse/jailhouse_git.bb

   1 SUMMARY = "Linux-based partitioning hypervisor"
   2 DESCRIPTION = "Jailhouse is a partitioning Hypervisor based on Linux. It is able to run bare-metal applications or (adapted) \
   3 operating systems besides Linux. For this purpose, it configures CPU and device virtualization features of the hardware \
   4 platform in a way that none of these domains, called 'cells' here, can interfere with each other in an unacceptable way."
   5 HOMEPAGE = "https://github.com/siemens/jailhouse"
   6 SECTION = "jailhouse"
   7 LICENSE = "GPL-2.0 & BSD-2-Clause"
   8
   9 LIC_FILES_CHKSUM = " \
  10     file://COPYING;md5=9fa7f895f96bde2d47fd5b7d95b6ba4d \
  11 "
  12
  13 SRCREV = "4ce7658dddfd5a1682a379d5ac46657e93fe1ff0"
  14 PV = "0.12+git${SRCPV}"
  15
  16 SRC_URI = "git://github.com/siemens/jailhouse"
  17
  18 DEPENDS = "virtual/kernel dtc-native python3-mako-native make-native"
  19
  20 require jailhouse-arch.inc
  21 inherit module python3native bash-completion setuptools3
  22
  23 S = "${WORKDIR}/git"
  24 B = "${S}"
  25
  26 JH_DATADIR ?= "${datadir}/jailhouse"
  27 JH_EXEC_DIR ?= "${libexecdir}/jailhouse"
  28 CELL_DIR ?= "${JH_DATADIR}/cells"
  29 INMATES_DIR ?= "${JH_DATADIR}/inmates"
  30 DTS_DIR ?= "${JH_DATADIR}/cells/dts"
  31
  32 JH_CELL_FILES ?= "*.cell"
  33
  34 EXTRA_OEMAKE = "ARCH=${JH_ARCH} CROSS_COMPILE=${TARGET_PREFIX} CC="${CC}" KDIR=${STAGING_KERNEL_BUILDDIR}"
  35
  36 do_configure() {
  37         sed -i '1s|^#!/usr/bin/env python$|#!/usr/bin/env python3|' ${B}/tools/${BPN}-*
  38 }
  39
  40 do_compile() {
  41         oe_runmake
  42 }
  43
  44 do_install() {
  45         # Install pyjailhouse python modules needed by the tools
  46         distutils3_do_install
  47
  48         # We want to install the python tools, but we do not want to use pip...
  49         # At least with v0.10, we can work around this with
  50         # 'PIP=":" PYTHON_PIP_USEABLE=yes'
  51         oe_runmake PIP=: PYTHON=python3 PYTHON_PIP_USEABLE=yes DESTDIR=${D} install
  52
  53         install -d ${D}${CELL_DIR}
  54         install -m 0644 ${B}/configs/${JH_ARCH}/${JH_CELL_FILES} ${D}${CELL_DIR}/
  55
  56         install -d ${D}${INMATES_DIR}
  57         install -m 0644 ${B}/inmates/demos/${JH_ARCH}/*.bin ${D}${INMATES_DIR}
  58
  59         if [ ${JH_ARCH}  != "x86" ]; then
  60                 install -d ${D}${DTS_DIR}
  61                 install -m 0644 ${B}/configs/${JH_ARCH}/dts/*.dtb ${D}${DTS_DIR}
  62         fi
  63 }
  64
  65 PACKAGE_BEFORE_PN = "kernel-module-jailhouse pyjailhouse ${PN}-tools ${PN}-demos"
  66 FILES_${PN} = "${base_libdir}/firmware ${libexecdir} ${sbindir} ${JH_DATADIR}"
  67 FILES_pyjailhouse = "${PYTHON_SITEPACKAGES_DIR}"
  68 FILES_${PN}-tools = "${libexecdir}/${BPN}/${BPN}-* ${JH_DATADIR}/*.tmpl"
  69 FILES_${PN}-demos = "${JH_DATADIR}/ ${sbindir}/ivshmem-demo"
  70
  71 RDEPENDS_${PN}-tools = "pyjailhouse python3-mmap python3-math python3-datetime python3-curses python3-compression python3-mako"
  72 RDEPENDS_pyjailhouse = "python3-core python3-ctypes python3-fcntl"
  73 RDEPENDS_${PN}-demos = "jailhouse"
  74
  75 RRECOMMENDS_${PN} = "${PN}-tools"
  76
  77 KERNEL_MODULE_AUTOLOAD += "jailhouse"