meta-agl-ic-container/recipes-platform/images/agl-lxc-multi-partition-image.inc

   1 # Integration type support for multi partition with host and guest image.
   2
   3 require recipes-platform/images/agl-lxc-multiconfig-build.inc
   4
   5 # Install out of tree build image support
   6 OUT_OF_TREE_CONTAINER_IMAGE_DEPLOY_DIR ??= ""
   7
   8 OUT_OF_TREE_CONTAINER_IMAGES ??= " \
   9     agl-ivi-demo-qt \
  10     agl-ivi-demo-flutter \
  11 "
  12
  13 OUT_OF_TREE_CONTAINER_CONFIGS ??= " \
  14     cm-config-agl-qt-ivi-demo \
  15     cm-config-agl-flutter-ivi-demo \
  16 "
  17
  18 CONTAINER_EXCHANGE_DEMO_UI ??= "momiweb momikey"
  19
  20 CONTAINER_MULTI_DEMO ??= " \
  21     ${OUT_OF_TREE_CONTAINER_CONFIGS} \
  22     ${CONTAINER_EXCHANGE_DEMO_UI} \
  23 "
  24
  25 # Handle modification of IMAGE_LINK_NAME done by ULCB builds with Kingfisher support
  26 MACHINE_SUFFIX = "${@bb.utils.contains('AGL_FEATURES', 'kingfisher', '-kf', '', d)}"
  27
  28 install_container_images() {
  29     for c in ${CONTAINER_IMAGES}; do
  30         config=${c%:*}
  31         image=${c#*:}
  32         name=${image#guest-image-}
  33         rm -f "${DEPLOY_DIR_IMAGE}/${image}.ext4"
  34         src="${TOPDIR}/tmp-${config}/deploy/images/${MACHINE}/${image}-${MACHINE}${MACHINE_SUFFIX}${IMAGE_NAME_SUFFIX}.ext4"
  35         bbnote "Installing ${src}"
  36         ln -s ${src} "${DEPLOY_DIR_IMAGE}/${image}.ext4"
  37     done
  38
  39     if ${@oe.utils.conditional('OUT_OF_TREE_CONTAINER_IMAGE_DEPLOY_DIR', '', 'false', 'true', d)}; then
  40         er=0
  41         for image in ${OUT_OF_TREE_CONTAINER_IMAGES}; do
  42             rm -f "${DEPLOY_DIR_IMAGE}/${image}.ext4"
  43             src="${OUT_OF_TREE_CONTAINER_IMAGE_DEPLOY_DIR}/images/${MACHINE}/${image}-${MACHINE}${MACHINE_SUFFIX}${IMAGE_NAME_SUFFIX}.ext4"
  44             if [ ! -e ${src} ]; then
  45                 bberror "File not found at ${src}."
  46                 er=1
  47             else
  48                 bbnote "Installing ${src}"
  49             fi
  50             ln -s ${src} "${DEPLOY_DIR_IMAGE}/${image}.ext4"
  51         done
  52
  53         if [ $er -eq 1 ]; then
  54             bbfatal "AGL Demo IVI images install error.  Please check OUT_OF_TREE_CONTAINER_IMAGE_DEPLOY_DIR setting and IVI side build status."
  55         fi
  56     fi
  57 }
  58
  59 ROOTFS_POSTPROCESS_COMMAND += "install_container_images; "
  60
  61 IMAGE_INSTALL:append = " \
  62     ${@oe.utils.conditional('OUT_OF_TREE_CONTAINER_IMAGE_DEPLOY_DIR', '', '', '${CONTAINER_MULTI_DEMO}', d)} \
  63 "
  64
  65 WKS_FILES:prepend = " \
  66     ${@oe.utils.conditional('OUT_OF_TREE_CONTAINER_IMAGE_DEPLOY_DIR', '', 'agl-ic-container-noloader.wks ', 'agl-ic-container-noloader-demo.wks ', d)} \
  67 "