meta-agl-ic-container/recipes-platform/images/agl-lxc-multi-partition-image.inc

   1 # Integration type support for multi partition with host and guest image.
   2
   3 require recipes-platform/images/agl-lxc-multiconfig-build.inc
   4
   5 # Install out of tree build image support
   6 OUT_OF_TREE_CONTAINER_IMAGE_DEPLOY_DIR ??= "non"
   7
   8 OUT_OF_TREE_CONTAINER_IMAGES ??= " \
   9     agl-ivi-demo-platform \
  10     agl-ivi-demo-platform-flutter \
  11     agl-ivi-demo-platform-html5 \
  12 "
  13
  14 OUT_OF_TREE_CONTAINER_CONFIGS ??= " \
  15     cm-config-agl-qt-ivi-demo \
  16     cm-config-agl-flutter-ivi-demo \
  17     cm-config-agl-html5-ivi-demo \
  18 "
  19
  20 # Handle modification of IMAGE_LINK_NAME done by ULCB builds with Kingfisher support
  21 MACHINE_SUFFIX = "${@bb.utils.contains('AGL_FEATURES', 'kingfisher', '-kf', '', d)}"
  22
  23 install_container_images() {
  24     for c in ${CONTAINER_IMAGES}; do
  25         config=${c%:*}
  26         image=${c#*:}
  27         name=${image#guest-image-}
  28         rm -f "${DEPLOY_DIR_IMAGE}/${image}.ext4"
  29         src="${TOPDIR}/tmp-${config}/deploy/images/${MACHINE}/${image}-${MACHINE}${MACHINE_SUFFIX}.ext4"
  30         bbnote "Installing ${src}"
  31         ln -s ${src} "${DEPLOY_DIR_IMAGE}/${image}.ext4"
  32     done
  33
  34     if ${@bb.utils.contains('OUT_OF_TREE_CONTAINER_IMAGE_DEPLOY_DIR', 'non', 'false', 'true', d)}; then
  35         for image in ${OUT_OF_TREE_CONTAINER_IMAGES}; do
  36             rm -f "${DEPLOY_DIR_IMAGE}/${image}.ext4"
  37             src="${OUT_OF_TREE_CONTAINER_IMAGE_DEPLOY_DIR}/images/${MACHINE}/${image}-${MACHINE}${MACHINE_SUFFIX}.ext4"
  38             bbnote "Installing ${src}"
  39             ln -s ${src} "${DEPLOY_DIR_IMAGE}/${image}.ext4"
  40         done
  41     fi
  42 }
  43
  44 ROOTFS_POSTPROCESS_COMMAND += "install_container_images; "
  45
  46 IMAGE_INSTALL:append = " \
  47     ${@bb.utils.contains('OUT_OF_TREE_CONTAINER_IMAGE_DEPLOY_DIR', 'non', '', '${OUT_OF_TREE_CONTAINER_CONFIGS} momiweb', d)} \
  48 "
  49
  50 WKS_FILES:prepend = " \
  51     ${@bb.utils.contains('OUT_OF_TREE_CONTAINER_IMAGE_DEPLOY_DIR', 'non', 'agl-ic-container-noloader.wks ', 'agl-ic-container-noloader-demo.wks ', d)} \
  52 "