meta-agl-ic-container/recipes-demo/mominavi/mominavi_git.bb

   1 SUMMARY     = "Momiyama navigation example based on mapbox."
   2 DESCRIPTION = "The mominavi is a navigation example based on mapbox. It's based on aglqtnavigation. \
   3                The mominavi is not require agl-appfw."
   4 LICENSE = "GPL-3.0-only"
   5 LIC_FILES_CHKSUM = "file://LICENSE;md5=d32239bcb673463ab874e80d47fae504"
   6
   7 DEPENDS = " \
   8     qtbase \
   9     qtquickcontrols2 \
  10     qtlocation \
  11     qtgraphicaleffects \
  12     qtsvg \
  13     qtwebsockets \
  14     "
  15
  16 PV = "1.0.0"
  17
  18 SRC_URI = "git://git.automotivelinux.org/apps/mominavi;protocol=https;branch=${AGL_BRANCH} \
  19            file://mominavi.service \
  20            file://mominavi \
  21           "
  22 SRCREV = "10c3f7996d4bbe04d237baff2ef16573bc9eb9ed"
  23
  24 S = "${WORKDIR}/git"
  25
  26 inherit qmake5 systemd
  27
  28 MOMIMAP_MAPBOX_ACCESS_TOKEN ??= "YOU_NEED_TO_SET_IT_IN_LOCAL_CONF"
  29 MOMIMAP_MAPBOX_STYLE ??= "mapbox://styles/wata2ki/ckoy853ue11a117nss0uxut76"
  30 MOMIMAP_INITIAL_LATITUDE ??= "36.129"
  31 MOMIMAP_INITIAL_LONGITUDE ??= "-115.1533"
  32 QT_INSTALL_PREFIX = "/usr"
  33
  34 do_configure:prepend() {
  35         if [ "${MOMIMAP_MAPBOX_ACCESS_TOKEN}" = "YOU_NEED_TO_SET_IT_IN_LOCAL_CONF" ]; then
  36                 bbwarn "WARNING: You should set MapBox development key to MOMIMAP_MAPBOX_ACCESS_TOKEN variable in local.conf."
  37         fi
  38 }
  39 do_install:append() {
  40     install -d ${D}/${systemd_unitdir}/system
  41     install -m 0644 ${WORKDIR}/mominavi.service ${D}/${systemd_unitdir}/system
  42
  43     install -m 0755 -d ${D}${sysconfdir}/default/
  44     install -m 0755 ${WORKDIR}/mominavi ${D}${sysconfdir}/default/
  45
  46     echo 'MOMIMAP_MAPBOX_ACCESS_TOKEN=${MOMIMAP_MAPBOX_ACCESS_TOKEN}' >> ${D}${sysconfdir}/default/mominavi
  47     echo 'MOMIMAP_MAPBOX_STYLE=${MOMIMAP_MAPBOX_STYLE}' >> ${D}${sysconfdir}/default/mominavi
  48     echo 'MOMIMAP_INITIAL_LATITUDE=${MOMIMAP_INITIAL_LATITUDE}' >> ${D}${sysconfdir}/default/mominavi
  49     echo 'MOMIMAP_INITIAL_LONGITUDE=${MOMIMAP_INITIAL_LONGITUDE}' >> ${D}${sysconfdir}/default/mominavi
  50 }
  51
  52 FILES:${PN} += " \
  53     ${systemd_unitdir} \
  54     ${sysconfdir}/*/* \
  55     "
  56 SYSTEMD_PACKAGES = "${PN}"
  57 SYSTEMD_SERVICE:${PN} = "mominavi.service"
  58
  59 RDEPENDS:${PN} = " \
  60     qtsvg qtsvg-plugins qtsvg-qmlplugins \
  61     qtwebsockets qtwebsockets-plugins qtwebsockets-qmlplugins \
  62     qtlocation qtlocation-plugins qtlocation-qmlplugins \
  63     "