meta-agl-ic-container/recipes-demo/cluster-refgui/cluster-refgui_git.bb

   1 DESCRIPTION = "AGL Cluster Reference GUI"
   2 LICENSE = "Apache-2.0"
   3 LIC_FILES_CHKSUM = "file://LICENSE;md5=5335066555b14d832335aa4660d6c376"
   4
   5 DEPENDS = " \
   6     qttools-native \
   7     qtmultimedia \
   8     cluster-service \
   9 "
  10
  11 BRANCH = "master"
  12 SRC_URI = "git://git.automotivelinux.org/src/cluster-refgui;protocol=https;branch=${BRANCH} \
  13            file://cluster.service \
  14            file://cluster \
  15 "
  16 SRCREV = "a16c6201be94a57eb8151a91699084d99694877c"
  17
  18 S = "${WORKDIR}/git"
  19
  20 inherit cmake cmake_qt5 systemd pkgconfig
  21
  22 # NOTE:
  23 # The app currently assumes the mp4 video file is in the same
  24 # directory, so changing this to ${bindir} to better match FHS
  25 # requires code changes.
  26 APP_DIR = "/opt/apps"
  27 EXTRA_OECMAKE = "-DAPPS_INST_DIR=${APP_DIR}"
  28
  29 SYSTEMD_SERVICE:${PN} = "cluster.service"
  30
  31 do_install:append() {
  32     install -d ${D}${systemd_unitdir}/system
  33     install -m 0644 ${WORKDIR}/cluster.service ${D}${systemd_unitdir}/system/
  34
  35     install -m 0755 -d ${D}${sysconfdir}/default/
  36     install -m 0755 ${WORKDIR}/cluster ${D}${sysconfdir}/default/
  37 }
  38
  39 FILES:${PN} += "${APP_DIR}/"
  40
  41 RDEPENDS:${PN} = " \
  42     qtbase \
  43     qtdeclarative \
  44     qt3d \
  45     qtgraphicaleffects \
  46     qtmultimedia \
  47     qtquickcontrols \
  48     qtquickcontrols2 \
  49     qtwayland \
  50 "