meta-agl-ic-container/recipes-container/lxc/lxc_%.bbappend

   1 FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
   2
   3 SRC_URI += " \
   4     file://0001-Remove-container-automatic-rebooting.patch \
   5     file://lxc.service \
   6     file://lxc-net.service \
   7     "
   8
   9 PACKAGECONFIG:remove = "templates"
  10
  11 do_install:append () {
  12     for service in lxc.service lxc-net.service; do
  13         install -D -m 0644 ${WORKDIR}/$service ${D}${systemd_system_unitdir}/$service
  14         sed -i -e 's,@LIBEXECDIR@,${libexecdir},g' ${D}${systemd_system_unitdir}/$service
  15     done
  16 }
  17
  18 # Divide lxc autostart from main package.
  19 SYSTEMD_PACKAGES = "${PN}-autostart ${PN}-networking"
  20 SYSTEMD_SERVICE:${PN} = ""
  21 SYSTEMD_SERVICE:${PN}-autostart = "lxc.service"
  22 SYSTEMD_AUTO_ENABLE:${PN}-autostart = "enable"
  23
  24 PACKAGES =+ "${PN}-autostart"
  25
  26 FILES:${PN}-autostart += " \
  27     ${sysconfdir}/default/lxc \
  28     ${sysconfdir}/default/volatiles/99_lxc \
  29 "
  30 FILES:${PN}-doc += " \
  31     ${datadir}/doc/lxc/examples \
  32 "
  33 FILES:${PN}-networking += " \
  34     ${sysconfdir}/dnsmasq.d \
  35 "
  36
  37 # NOTE:
  38 # This needs to be replaced with a rework of the upstream packaging
  39 # to do a proper split of core from the template support.
  40 RDEPENDS:${PN} = ""