meta-agl-ic-container/recipes-container/container-manager/container-manager_git.bb

   1 SUMMARY = "AGL Container Manager"
   2 DESCRIPTION = "AGL Container Manager for AGL Instrument Cluster."
   3 AUTHOR = "Naoto Yamaguchi/ AGL Instrument Cluster Expert Group"
   4 HOMEPAGE = "https://github.com/AGLExport/container-manager"
   5 BUGTRACKER = "https://github.com/AGLExport/container-manager/issues"
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=89aea4e17d99a7cacdbeed46a0096b10"
   8
   9 DEPENDS = "systemd libmnl cjson lxc util-linux"
  10
  11 PV = "0.1.0+rev${SRCPV}"
  12
  13 SRC_URI = " \
  14     git://github.com/AGLExport/container-manager.git;branch=staging2;protocol=https \
  15     file://container-manager.service \
  16     file://container-manager.json \
  17     "
  18 SRCREV = "e516cfeca7859a74a47155ab77d4b1610cae6617"
  19
  20 S = "${WORKDIR}/git"
  21
  22 inherit autotools pkgconfig systemd features_check
  23
  24 REQUIRED_DISTRO_FEATURES = "systemd"
  25
  26 SYSTEMD_PACKAGES = "${PN}"
  27 SYSTEMD_SERVICE:${PN} = "container-manager.service"
  28 SYSTEMD_AUTO_ENABLE:${PN} = "enable"
  29
  30 do_install:append() {
  31     install -d ${D}/opt/container/conf/
  32     install -d ${D}/opt/container/guests/
  33
  34     install -d ${D}${systemd_system_unitdir}
  35     install -m 0644 ${WORKDIR}/container-manager.service ${D}${systemd_system_unitdir}/
  36
  37     install -d ${D}${sysconfdir}
  38     install -m 0644 ${WORKDIR}/container-manager.json ${D}${sysconfdir}/
  39 }
  40
  41 FILES:${PN} += " \
  42     ${systemd_system_unitdir}/* \
  43     ${sysconfdir}/* \
  44     /opt/container/conf \
  45     /opt/container/guests \
  46     "