meta-agl-drm-lease/recipes-graphics/drm-lease-manager/drm-lease-manager_git.bb

   1 LICENSE = "Apache-2.0"
   2 LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
   3
   4 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/drm-lease-manager;protocol=https;branch=${AGL_BRANCH} \
   5            file://drm-lease-manager.service \
   6            file://run-ptest \
   7            "
   8
   9 PV = "0.1+git${SRCPV}"
  10 SRCREV = "43feb8701361e43ef43460ae16b3837e97b174ed"
  11
  12 S = "${WORKDIR}/git"
  13
  14 inherit meson
  15 inherit systemd
  16 inherit ptest
  17
  18 DEPENDS = "libdrm libcheck fff"
  19
  20 do_install:append() {
  21     install -d ${D}/${systemd_unitdir}/system
  22     install -m 0644 ${WORKDIR}/drm-lease-manager.service ${D}/${systemd_unitdir}/system
  23     rm -rf ${D}/${localstatedir}
  24 }
  25
  26 SYSTEMD_SERVICE:${PN} = "drm-lease-manager.service"
  27
  28 EXTRA_OEMESON += "${@bb.utils.contains('PTEST_ENABLED', '1', '-Denable-tests=true', '', d)}"
  29 RDEPENDS:${PN}-ptest = "libcheck"
  30
  31 do_install_ptest() {
  32     install ${B}/libdlmclient/test/libdlmclient-test ${D}${PTEST_PATH}
  33     install ${B}/drm-lease-manager/test/lease-server-test ${D}${PTEST_PATH}
  34     install ${B}/drm-lease-manager/test/lease-manager-test ${D}${PTEST_PATH}
  35 }
  36
  37 PACKAGES =+ "libdlmclient"
  38 FILES:libdlmclient = "${libdir}/libdlmclient${SOLIBS}"