meta-agl-drm-lease/recipes-graphics/drm-lease-manager/drm-lease-manager_git.bb

   1 LICENSE = "Apache-2.0"
   2 LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
   3
   4 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/drm-lease-manager;protocol=https;branch=${AGL_BRANCH} \
   5            file://drm-lease-manager.service \
   6            file://run-ptest \
   7            "
   8
   9 PV = "0.1+git${SRCPV}"
  10 SRCREV = "88cbd73ba10a589734cf126b64e74a6f42a5d5a7"
  11
  12 S = "${WORKDIR}/git"
  13
  14 inherit meson pkgconfig
  15 inherit systemd
  16 inherit ptest
  17
  18 DEPENDS = "libdrm libcheck fff tomlc99"
  19
  20 do_install:append() {
  21     install -d ${D}/${systemd_unitdir}/system
  22     install -m 0644 ${WORKDIR}/drm-lease-manager.service ${D}/${systemd_unitdir}/system
  23     rm -rf ${D}/${localstatedir}
  24 }
  25
  26 SYSTEMD_SERVICE:${PN} = "drm-lease-manager.service"
  27 RDEPENDS:${PN} = "drm-lease-manager-init"
  28
  29 PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
  30 PACKAGECONFIG[systemd] = "-Denable-systemd=true,-Denable-systemd=false,systemd"
  31
  32 EXTRA_OEMESON += "${@bb.utils.contains('PTEST_ENABLED', '1', '-Denable-tests=true', '', d)}"
  33 RDEPENDS:${PN}-ptest = "libcheck"
  34
  35 do_install_ptest() {
  36     install ${B}/libdlmclient/test/libdlmclient-test ${D}${PTEST_PATH}
  37     install ${B}/drm-lease-manager/test/lease-server-test ${D}${PTEST_PATH}
  38     install ${B}/drm-lease-manager/test/lease-manager-test ${D}${PTEST_PATH}
  39 }
  40
  41 PACKAGES =+ "libdlmclient"
  42 FILES:libdlmclient = "${libdir}/libdlmclient${SOLIBS}"