meta-agl-distro/conf/distro/poky-agl.conf

   1 require conf/distro/poky.conf
   2
   3 # AGL specific derivations
   4 DISTRO = "poky-agl"
   5 DISTRO_NAME = "Automotive Grade Linux"
   6 DISTRO_VERSION = "5.99.3+snapshot-${DATE}"
   7 #DISTRO_VERSION := "5.99.4"
   8 DISTRO_CODENAME = "flounder"
   9 DISTRO_BRANCH_VERSION_TAG := "flounder/${@'${DISTRO_VERSION}'.replace('+snapshot-${DATE}','')}"
  10 SDK_VENDOR = "-aglsdk"
  11 SDK_VERSION := "${@'${DISTRO_VERSION}'.replace('snapshot-${DATE}','snapshot')}"
  12
  13 # SDKPATH is the folder where the SDK is going to be installed
  14 # Due to an issue with the qt5 environment (see SPEC-1667),
  15 # we add DEFAULTTUNE to the SDKPATH to mitigate the issue.
  16 SDKPATH = "/opt/agl-sdk/${DISTRO_VERSION}-${DEFAULTTUNE}"
  17
  18 AGL_BRANCH = "master"
  19
  20 #for development
  21 AGL_APP_REVISION = "${AUTOREV}"
  22 AGL_DEFAULT_REVISION = "${AUTOREV}"
  23 #for release
  24 #AGL_APP_REVISION := "refs/tags/${DISTRO_BRANCH_VERSION_TAG}"
  25 #AGL_DEFAULT_REVISION := "refs/tags/${DISTRO_BRANCH_VERSION_TAG}"
  26
  27
  28 MAINTAINER = "AGL <automotive-discussions@lists.linuxfoundation.org>"
  29
  30 TARGET_VENDOR = "-agl"
  31
  32 # Override these in poky based distros
  33 AGL_DEFAULT_DISTRO_FEATURES = "largefile systemd opengl wayland pam bluetooth bluez5"
  34 POKY_DEFAULT_DISTRO_FEATURES := "${AGL_DEFAULT_DISTRO_FEATURES}"
  35 OVERRIDES .= ":${DISTRO_CODENAME}"
  36
  37 QEMU_TARGETS ?= "arm aarch64 i386 x86_64"
  38 # Other QEMU_TARGETS "mips mips64 mips64el ppc sh4"
  39
  40 PREMIRRORS ??= "\
  41 bzr://.*/.*   https://download.automotivelinux.org/AGL/mirror/ \n \
  42 cvs://.*/.*   https://download.automotivelinux.org/AGL/mirror/ \n \
  43 git://.*/.*   https://download.automotivelinux.org/AGL/mirror/ \n \
  44 gitsm://.*/.* https://download.automotivelinux.org/AGL/mirror/ \n \
  45 hg://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  46 osc://.*/.*   https://download.automotivelinux.org/AGL/mirror/ \n \
  47 p4://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  48 svn://.*/.*   https://download.automotivelinux.org/AGL/mirror/ \n"
  49
  50 MIRRORS =+ "\
  51 ftp://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  52 http://.*/.*     https://download.automotivelinux.org/AGL/mirror/ \n \
  53 https://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n"
  54
  55 # The CONNECTIVITY_CHECK_URI's are used to test whether we can succesfully
  56 # fetch from the network (and warn you if not). To disable the test set
  57 # the variable to be empty.
  58 # Git example url: git://git.yoctoproject.org/yocto-firewall-test;protocol=git;rev=HEAD
  59 CONNECTIVITY_CHECK_URIS ?= ""
  60
  61 PREFERRED_PROVIDER_udev ?= "systemd"
  62 PREFERRED_PROVIDER_udev-utils ?= "systemd"
  63
  64 VIRTUAL-RUNTIME_init_manager = "systemd"
  65 VIRTUAL-RUNTIME_initscripts = ""
  66
  67 # network manager to use (possible values: systemd, connman)
  68 VIRTUAL-RUNTIME_net_manager = "connman"
  69
  70 DISTRO_FEATURES_APPEND = " "
  71 DISTRO_FEATURES_remove = "x11"
  72 DISTRO_FEATURES_BACKFILL_CONSIDERED = "sysvinit"
  73
  74 PREFERRED_VERSION_wayland-ivi-extension ?= "2.0.%"
  75
  76 # Prefer GStreamer 1.10.x by default
  77 PREFERRED_VERSION_gstreamer1.0              ?= "1.12.%"
  78 PREFERRED_VERSION_gstreamer1.0-plugins-bad  ?= "1.12.%"
  79 PREFERRED_VERSION_gstreamer1.0-plugins-base ?= "1.12.%"
  80 PREFERRED_VERSION_gstreamer1.0-plugins-good ?= "1.12.%"
  81 PREFERRED_VERSION_gstreamer1.0-plugins-ugly ?= "1.12.%"
  82 PREFERRED_VERSION_gstreamer1.0-libav        ?= "1.12.%"
  83 PREFERRED_VERSION_gstreamer1.0-omx          ?= "1.12.%"
  84
  85 # Prefer libjpeg-turbo
  86 PREFERRED_PROVIDER_jpeg = "libjpeg-turbo"
  87
  88 # using multiple BSP layers causes dangling bbappends in meta-agl-bsp
  89 # turn it into a warning
  90 #BB_DANGLINGAPPENDS_WARNONLY = "1"
  91
  92 # enforce security-related compiler flags by default
  93 require conf/distro/include/security_flags.inc
  94 # required overrides, upstreamed but not merged yet:
  95 # http://lists.openembedded.org/pipermail/openembedded-devel/2016-June/107727.html
  96 SECURITY_CFLAGS_pn-llvm3.3 = ""
  97 SECURITY_LDFLAGS_remove_pn-llvm3.3 = "-fstack-protector-strong"
  98 SECURITY_STRINGFORMAT_pn-gpm = ""
  99 SECURITY_CFLAGS_pn-libdbus-c++ = ""
 100 SECURITY_LDFLAGS_pn-libdbus-c++ = ""
 101
 102 # more than 2 targets fail to compile these with the SECURITY compiler flags:
 103 # Bug tracked as SPEC-593
 104 SECURITY_CFLAGS_pn-mozjs = ""
 105 SECURITY_LDFLAGS_pn-mozjs = ""
 106 SECURITY_CFLAGS_pn-gpm = ""
 107 SECURITY_LDFLAGS_pn-gpm = ""
 108 SECURITY_CFLAGS_pn-libatasmart = ""
 109 SECURITY_LDFLAGS_pn-libatasmart = ""
 110
 111 # Not yet upstreamed; should be submitted.
 112 SECURITY_CFLAGS_pn-qtwebengine = "${SECURITY_NO_PIE_CFLAGS}"
 113
 114 #Redefined USER_CLASSES
 115 #Disable prelink. It is unmaintained and likely will go away.
 116 #default: USER_CLASSES ?= "buildstats image-mklibs image-prelink"
 117 USER_CLASSES = "buildstats image-mklibs"
 118
 119 # AGL uses 4 optimization levels
 120 # 2 for ARM 32bit
 121 #   - a high and a medium setting for the CCARGS
 122 #   - the high setting is default (needs >= cortex-a15)
 123 #   - the medium setting is enabled with: DISTRO_FEATURES_append = " agl-medium-arm-compiler "
 124 # 1 for ARM 64bit / AARCH64
 125 # 1 for x86-64
 126 require conf/distro/include/${TARGET_ARCH}-tune.inc
 127
 128 # Generic qemu and qemuboot (runqemu) enhancements
 129 # check qemuboot.bbclass
 130 # - use 2G RAM by default
 131 QB_MEM ?= "-m 2048"
 132 # use pulseaudio on the host side - off as qemu-native is built with alsa
 133 #QB_AUDIO_DRV = "pa"
 134 # expose a virtual 'hda' sound card to the guest (arm/aarch64/x86-64)
 135 QB_AUDIO_OPT = "-soundhw hda"
 136
 137 # Board templates can add extra IMAGE_FSTYPES through this.
 138 # It is added (late) through the AGL image recipes.
 139 AGL_EXTRA_IMAGE_FSTYPES ??= ""
 140 AGL_EXTRA_INITRAMFS_FSTYPES ??= ""
 141 #
 142 # Default IMAGE FSTYPES compressed tarball + ext4.xz
 143 AGL_DEFAULT_IMAGE_FSTYPES ?= "tar.xz ${@bb.utils.contains('DISTRO_FEATURES', 'AGLCI', 'ext4.xz', 'ext4', d)}"
 144 AGL_DEFAULT_INITRAMFS_FSTYPES ?= "ext4.gz"
 145
 146 # DEFAULT IMAGE_FSTYPES for AGL (no - BSPs should not set this)
 147 #
 148 IMAGE_FSTYPES := "${AGL_DEFAULT_IMAGE_FSTYPES} ${AGL_EXTRA_IMAGE_FSTYPES}"
 149 INITRAMFS_FSTYPES := "${AGL_DEFAULT_INITRAMFS_FSTYPES} ${AGL_EXTRA_INITRAMFS_FSTYPES}"
 150 #
 151 # THE FUTURE is 'wic'
 152 # IMAGE_FSTYPES_append = " wic"
 153
 154 # enable the packagemanagement
 155 IMAGE_FEATURES =+ "package-management"
 156 PACKAGE_FEED_URIS = "http://192.168.7.1:8000/tmp/deploy/"
 157 PACKAGE_FEED_BASE_PATHS = "rpm"
 158 PACKAGE_FEED_ARCHS = ""
 159 #${PACKAGE_ARCHS}"
 160
 161
 162 # Fix for rpm metadata clash between nativesdk-cmake and nativesdk-qtbase-tools
 163 # (revalidate after 2017-10-15, 2018-06-12: still required)
 164 DIRFILES_pn-nativesdk-cmake = "1"
 165
 166 # For https://jira.automotivelinux.org/browse/SPEC-1629 :
 167 # We exclude the conflicting vars from the sstate task hash.
 168 # This needs to be verified.
 169 do_package_write_rpm[vardepsexclude] += "ARCHIVER_TOPDIR PF"
 170
 171 # For https://jira.automotivelinux.org/browse/SPEC-1677
 172 # Some issues appear, with the yocto version of valgrind, on aarch64.
 173 # (valgrind exits due to an unhandled instruction')
 174 PREFERRED_VERSION_valgrind ?= "git"