meta-agl-distro/conf/distro/poky-agl.conf

   1 require conf/distro/poky.conf
   2
   3 # AGL specific derivations
   4 DISTRO = "poky-agl"
   5 DISTRO_NAME = "Automotive Grade Linux"
   6
   7
   8 # Release flags
   9 DISTRO_CODENAME = "jellyfish"
  10 AGL_BRANCH = "master"
  11 AGLVERSION = "9.90.0"
  12 # switch  devel/release
  13 AGLRELEASETYPE ?= "agldevelopment"
  14 #AGLRELEASETYPE ?= "aglrelease"
  15 OVERRIDES .= ":${AGLRELEASETYPE}"
  16 #
  17
  18 #for development
  19 DISTRO_VERSION_agldevelopment := "${AGLVERSION}+snapshot-${DATE}"
  20 AGL_APP_REVISION_agldevelopment = "${AUTOREV}"
  21 AGL_DEFAULT_REVISION_agldevelopment = "${AUTOREV}"
  22
  23 #for release
  24 DISTRO_VERSION_aglrelease := "${AGLVERSION}"
  25 DISTRO_BRANCH_VERSION_TAG = "${DISTRO_CODENAME}/${@'${DISTRO_VERSION}'.replace('+snapshot-${DATE}','')}"
  26 AGL_APP_REVISION_aglrelease := "refs/tags/${DISTRO_BRANCH_VERSION_TAG}"
  27 AGL_DEFAULT_REVISION_aglrelease := "refs/tags/${DISTRO_BRANCH_VERSION_TAG}"
  28
  29 # reproducible builds:
  30 # enable the flag
  31 BUILD_REPRODUCIBLE_BINARIES = "1"
  32 # Set the desired timestamps
  33 export SOURCE_DATE_EPOCH = "1583798400"
  34 REPRODUCIBLE_TIMESTAMP_ROOTFS = "1583798400"
  35 # inherit the class
  36 INHERIT += "reproducible_build"
  37
  38
  39 # SDK
  40 SDK_VENDOR = "-aglsdk"
  41 SDK_VERSION := "${@'${DISTRO_VERSION}'.replace('snapshot-${DATE}','snapshot')}"
  42
  43 # SDKPATH is the folder where the SDK is going to be installed
  44 # Due to an issue with the qt5 environment (see SPEC-1667),
  45 # we add DEFAULTTUNE to the SDKPATH to mitigate the issue.
  46 SDKPATH = "/opt/agl-sdk/${SDK_VERSION}-${DEFAULTTUNE}"
  47
  48
  49 MAINTAINER = "AGL <automotive-discussions@lists.linuxfoundation.org>"
  50
  51 TARGET_VENDOR = "-agl"
  52
  53 # Override these in poky based distros
  54 AGL_DEFAULT_DISTRO_FEATURES = "largefile systemd opengl wayland pam bluetooth bluez5 3g polkit"
  55 POKY_DEFAULT_DISTRO_FEATURES := "${AGL_DEFAULT_DISTRO_FEATURES}"
  56 OVERRIDES .= ":${DISTRO_CODENAME}"
  57
  58 QEMU_TARGETS ?= "arm aarch64 i386 x86_64"
  59 # Other QEMU_TARGETS "mips mips64 mips64el ppc sh4"
  60
  61 MIRRORS =+ "\
  62 bzr://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  63 cvs://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  64 git://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  65 gitsm://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  66 hg://.*/.*       https://download.automotivelinux.org/AGL/mirror/ \n \
  67 osc://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  68 p4://.*/.*       https://download.automotivelinux.org/AGL/mirror/ \n \
  69 svn://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  70 bzr://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  71 cvs://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  72 git://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  73 gitsm://.*/.*    http://download.automotivelinux.org/AGL/mirror/  \n \
  74 hg://.*/.*       http://download.automotivelinux.org/AGL/mirror/  \n \
  75 osc://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  76 p4://.*/.*       http://download.automotivelinux.org/AGL/mirror/  \n \
  77 svn://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  78                  \
  79 ftp://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  80 http://.*/.*     https://download.automotivelinux.org/AGL/mirror/ \n \
  81 https://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  82 ftp://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  83 http://.*/.*     http://download.automotivelinux.org/AGL/mirror/  \n \
  84 https://.*/.*    http://download.automotivelinux.org/AGL/mirror/  \n \
  85 "
  86
  87 # The CONNECTIVITY_CHECK_URI's are used to test whether we can succesfully
  88 # fetch from the network (and warn you if not). To disable the test set
  89 # the variable to be empty.
  90 # Git example url: git://git.yoctoproject.org/yocto-firewall-test;protocol=git;rev=HEAD
  91 CONNECTIVITY_CHECK_URIS ?= ""
  92
  93 PREFERRED_PROVIDER_udev ?= "systemd"
  94 PREFERRED_PROVIDER_udev-utils ?= "systemd"
  95
  96 VIRTUAL-RUNTIME_init_manager = "systemd"
  97 VIRTUAL-RUNTIME_initscripts = ""
  98
  99 # network manager to use (possible values: systemd, connman)
 100 VIRTUAL-RUNTIME_net_manager = "connman"
 101
 102 DISTRO_FEATURES_APPEND = " "
 103 DISTRO_FEATURES_remove = "x11"
 104 DISTRO_FEATURES_BACKFILL_CONSIDERED = "sysvinit pulseaudio"
 105
 106 # Prefer linux-yocto 4.19 LTS version by default
 107 PREFERRED_VERSION_linux-yocto = "4.19%"
 108
 109 # Prefer GStreamer 1.14.x by default
 110 PREFERRED_VERSION_gstreamer1.0              ?= "1.16.%"
 111 PREFERRED_VERSION_gstreamer1.0-plugins-bad  ?= "1.16.%"
 112 PREFERRED_VERSION_gstreamer1.0-plugins-base ?= "1.16.%"
 113 PREFERRED_VERSION_gstreamer1.0-plugins-good ?= "1.16.%"
 114 PREFERRED_VERSION_gstreamer1.0-plugins-ugly ?= "1.16.%"
 115 PREFERRED_VERSION_gstreamer1.0-libav        ?= "1.16.%"
 116 PREFERRED_VERSION_gstreamer1.0-omx          ?= "1.16.%"
 117
 118 # Prefer libjpeg-turbo
 119 PREFERRED_PROVIDER_jpeg = "libjpeg-turbo"
 120
 121 # using multiple BSP layers causes dangling bbappends in meta-agl-bsp
 122 # turn it into a warning
 123 #BB_DANGLINGAPPENDS_WARNONLY = "1"
 124
 125 # Not yet upstreamed; should be submitted.
 126 SECURITY_CFLAGS_pn-qtwebengine = "${SECURITY_NO_PIE_CFLAGS}"
 127
 128 #Redefined USER_CLASSES
 129 #Disable prelink. It is unmaintained and likely will go away.
 130 #default: USER_CLASSES ?= "buildstats image-mklibs image-prelink"
 131 USER_CLASSES = "buildstats image-mklibs"
 132
 133 # AGL uses 4 optimization levels
 134 # 2 for ARM 32bit
 135 #   - a high and a medium setting for the CCARGS
 136 #   - the high setting is default (needs >= cortex-a15)
 137 #   - the medium setting is enabled with: DISTRO_FEATURES_append = " agl-medium-arm-compiler "
 138 # 1 for ARM 64bit / AARCH64
 139 # 1 for x86-64
 140 require conf/distro/include/${TARGET_ARCH}-tune.inc
 141
 142 # Generic qemu and qemuboot (runqemu) enhancements
 143 # check qemuboot.bbclass
 144 # - use 2G RAM by default
 145 QB_MEM ?= "-m 2048"
 146 # use pulseaudio on the host side - off as qemu-native is built with alsa
 147 #QB_AUDIO_DRV = "pa"
 148 # expose a virtual 'hda' sound card to the guest (arm/aarch64/x86-64)
 149 QB_AUDIO_OPT = "-soundhw hda"
 150
 151 # Board templates can add extra IMAGE_FSTYPES through this.
 152 # It is added (late) through the AGL image recipes.
 153 AGL_EXTRA_IMAGE_FSTYPES ??= ""
 154 AGL_EXTRA_INITRAMFS_FSTYPES ??= ""
 155 #
 156 # Default IMAGE FSTYPES wic.xz
 157 AGL_DEFAULT_IMAGE_FSTYPES ?= "wic.xz wic.bmap wic.xz.sha256sum"
 158 AGL_DEFAULT_IMAGE_FSTYPES_qemuall ?= "${@bb.utils.contains('DISTRO_FEATURES', 'AGLCI', 'ext4.xz', 'ext4', d)}"
 159 AGL_DEFAULT_IMAGE_FSTYPES_append_netboot = " ${@bb.utils.contains('DISTRO_FEATURES', 'AGLCI', 'ext4.xz', 'ext4', d)}"
 160 AGL_DEFAULT_INITRAMFS_FSTYPES ?= "ext4.gz"
 161
 162 # DEFAULT IMAGE_FSTYPES for AGL (no - BSPs should not set this)
 163 #
 164 IMAGE_FSTYPES := "${AGL_DEFAULT_IMAGE_FSTYPES} ${AGL_EXTRA_IMAGE_FSTYPES}"
 165 INITRAMFS_FSTYPES := "${AGL_DEFAULT_INITRAMFS_FSTYPES} ${AGL_EXTRA_INITRAMFS_FSTYPES}"
 166 #
 167 # THE FUTURE is 'wic'
 168 # IMAGE_FSTYPES_append = " wic"
 169
 170 # enable the packagemanagement
 171 IMAGE_FEATURES =+ "package-management"
 172 PACKAGE_FEED_URIS = "http://192.168.7.1:8000/tmp/deploy/"
 173 PACKAGE_FEED_BASE_PATHS = "rpm"
 174 PACKAGE_FEED_ARCHS = ""
 175 #${PACKAGE_ARCHS}"
 176
 177
 178 # Fix for rpm metadata clash between nativesdk-cmake and nativesdk-qtbase-tools
 179 # (revalidate after 2017-10-15, 2018-06-12: still required)
 180 DIRFILES_pn-nativesdk-cmake = "1"
 181
 182 # For https://jira.automotivelinux.org/browse/SPEC-1629 :
 183 # We exclude the conflicting vars from the sstate task hash.
 184 # This needs to be verified.
 185 do_package_write_rpm[vardepsexclude] += "ARCHIVER_TOPDIR PF"
 186
 187 # Set preferred provider to new navi application
 188 PREFERRED_RPROVIDER_virtual/navigation ?= "ondemandnavi"
 189
 190 # Set preferred provider for low-can device mapping configuration
 191 PREFERRED_RPROVIDER_virtual/low-can-dev-mapping ?= "dev-mapping"
 192
 193 # Mask upstream meta-security bbappend that interferes with non-linux-yocto
 194 # kernels due to the bug of having two wildcards, which bitbake does not
 195 # support. Not having it is not an issue, since there is also explicit
 196 # enabling of required security features done by meta-agl/meta-security.
 197 BBMASK += "meta-security/recipes-kernel/linux/linux-%_5.%.bbappend"