meta-agl-distro/conf/distro/poky-agl.conf

   1 require conf/distro/poky.conf
   2
   3 # AGL specific derivations
   4 DISTRO = "poky-agl"
   5 DISTRO_NAME = "Automotive Grade Linux"
   6
   7
   8 # Release flags
   9 DISTRO_CODENAME = "flounder"
  10 AGL_BRANCH = "flounder"
  11 AGLVERSION = "6.0.1"
  12 # switch  devel/release
  13 #AGLRELEASETYPE ?= "agldevelopment"
  14 AGLRELEASETYPE ?= "aglrelease"
  15 OVERRIDES .= ":${AGLRELEASETYPE}"
  16 #
  17
  18 #for development
  19 DISTRO_VERSION_agldevelopment := "${AGLVERSION}+snapshot-${DATE}"
  20 AGL_APP_REVISION_agldevelopment = "${AUTOREV}"
  21 AGL_DEFAULT_REVISION_agldevelopment = "${AUTOREV}"
  22
  23 #for release
  24 DISTRO_VERSION_aglrelease := "${AGLVERSION}"
  25 DISTRO_BRANCH_VERSION_TAG = "flounder/${@'${DISTRO_VERSION}'.replace('+snapshot-${DATE}','')}"
  26 AGL_APP_REVISION_aglrelease := "refs/tags/${DISTRO_BRANCH_VERSION_TAG}"
  27 AGL_DEFAULT_REVISION_aglrelease := "refs/tags/${DISTRO_BRANCH_VERSION_TAG}"
  28
  29
  30 # SDK
  31 SDK_VENDOR = "-aglsdk"
  32 SDK_VERSION := "${@'${DISTRO_VERSION}'.replace('snapshot-${DATE}','snapshot')}"
  33
  34 # SDKPATH is the folder where the SDK is going to be installed
  35 # Due to an issue with the qt5 environment (see SPEC-1667),
  36 # we add DEFAULTTUNE to the SDKPATH to mitigate the issue.
  37 SDKPATH = "/opt/agl-sdk/${SDK_VERSION}-${DEFAULTTUNE}"
  38
  39
  40 MAINTAINER = "AGL <automotive-discussions@lists.linuxfoundation.org>"
  41
  42 TARGET_VENDOR = "-agl"
  43
  44 # Override these in poky based distros
  45 AGL_DEFAULT_DISTRO_FEATURES = "largefile systemd opengl wayland pam bluetooth bluez5"
  46 POKY_DEFAULT_DISTRO_FEATURES := "${AGL_DEFAULT_DISTRO_FEATURES}"
  47 OVERRIDES .= ":${DISTRO_CODENAME}"
  48
  49 QEMU_TARGETS ?= "arm aarch64 i386 x86_64"
  50 # Other QEMU_TARGETS "mips mips64 mips64el ppc sh4"
  51
  52 PREMIRRORS ??= "\
  53 bzr://.*/.*   https://download.automotivelinux.org/AGL/mirror/ \n \
  54 cvs://.*/.*   https://download.automotivelinux.org/AGL/mirror/ \n \
  55 git://.*/.*   https://download.automotivelinux.org/AGL/mirror/ \n \
  56 gitsm://.*/.* https://download.automotivelinux.org/AGL/mirror/ \n \
  57 hg://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  58 osc://.*/.*   https://download.automotivelinux.org/AGL/mirror/ \n \
  59 p4://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  60 svn://.*/.*   https://download.automotivelinux.org/AGL/mirror/ \n"
  61
  62 MIRRORS =+ "\
  63 ftp://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  64 http://.*/.*     https://download.automotivelinux.org/AGL/mirror/ \n \
  65 https://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n"
  66
  67 # The CONNECTIVITY_CHECK_URI's are used to test whether we can succesfully
  68 # fetch from the network (and warn you if not). To disable the test set
  69 # the variable to be empty.
  70 # Git example url: git://git.yoctoproject.org/yocto-firewall-test;protocol=git;rev=HEAD
  71 CONNECTIVITY_CHECK_URIS ?= ""
  72
  73 PREFERRED_PROVIDER_udev ?= "systemd"
  74 PREFERRED_PROVIDER_udev-utils ?= "systemd"
  75
  76 VIRTUAL-RUNTIME_init_manager = "systemd"
  77 VIRTUAL-RUNTIME_initscripts = ""
  78
  79 # network manager to use (possible values: systemd, connman)
  80 VIRTUAL-RUNTIME_net_manager = "connman"
  81
  82 DISTRO_FEATURES_APPEND = " "
  83 DISTRO_FEATURES_remove = "x11"
  84 DISTRO_FEATURES_BACKFILL_CONSIDERED = "sysvinit"
  85
  86 PREFERRED_VERSION_wayland-ivi-extension ?= "2.0.%"
  87
  88 # Prefer GStreamer 1.10.x by default
  89 PREFERRED_VERSION_gstreamer1.0              ?= "1.12.%"
  90 PREFERRED_VERSION_gstreamer1.0-plugins-bad  ?= "1.12.%"
  91 PREFERRED_VERSION_gstreamer1.0-plugins-base ?= "1.12.%"
  92 PREFERRED_VERSION_gstreamer1.0-plugins-good ?= "1.12.%"
  93 PREFERRED_VERSION_gstreamer1.0-plugins-ugly ?= "1.12.%"
  94 PREFERRED_VERSION_gstreamer1.0-libav        ?= "1.12.%"
  95 PREFERRED_VERSION_gstreamer1.0-omx          ?= "1.12.%"
  96
  97 # Prefer libjpeg-turbo
  98 PREFERRED_PROVIDER_jpeg = "libjpeg-turbo"
  99
 100 # using multiple BSP layers causes dangling bbappends in meta-agl-bsp
 101 # turn it into a warning
 102 #BB_DANGLINGAPPENDS_WARNONLY = "1"
 103
 104 # enforce security-related compiler flags by default
 105 require conf/distro/include/security_flags.inc
 106 # required overrides, upstreamed but not merged yet:
 107 # http://lists.openembedded.org/pipermail/openembedded-devel/2016-June/107727.html
 108 SECURITY_CFLAGS_pn-llvm3.3 = ""
 109 SECURITY_LDFLAGS_remove_pn-llvm3.3 = "-fstack-protector-strong"
 110 SECURITY_STRINGFORMAT_pn-gpm = ""
 111 SECURITY_CFLAGS_pn-libdbus-c++ = ""
 112 SECURITY_LDFLAGS_pn-libdbus-c++ = ""
 113
 114 # more than 2 targets fail to compile these with the SECURITY compiler flags:
 115 # Bug tracked as SPEC-593
 116 SECURITY_CFLAGS_pn-mozjs = ""
 117 SECURITY_LDFLAGS_pn-mozjs = ""
 118 SECURITY_CFLAGS_pn-gpm = ""
 119 SECURITY_LDFLAGS_pn-gpm = ""
 120 SECURITY_CFLAGS_pn-libatasmart = ""
 121 SECURITY_LDFLAGS_pn-libatasmart = ""
 122
 123 # Not yet upstreamed; should be submitted.
 124 SECURITY_CFLAGS_pn-qtwebengine = "${SECURITY_NO_PIE_CFLAGS}"
 125
 126 #Redefined USER_CLASSES
 127 #Disable prelink. It is unmaintained and likely will go away.
 128 #default: USER_CLASSES ?= "buildstats image-mklibs image-prelink"
 129 USER_CLASSES = "buildstats image-mklibs"
 130
 131 # AGL uses 4 optimization levels
 132 # 2 for ARM 32bit
 133 #   - a high and a medium setting for the CCARGS
 134 #   - the high setting is default (needs >= cortex-a15)
 135 #   - the medium setting is enabled with: DISTRO_FEATURES_append = " agl-medium-arm-compiler "
 136 # 1 for ARM 64bit / AARCH64
 137 # 1 for x86-64
 138 require conf/distro/include/${TARGET_ARCH}-tune.inc
 139
 140 # Generic qemu and qemuboot (runqemu) enhancements
 141 # check qemuboot.bbclass
 142 # - use 2G RAM by default
 143 QB_MEM ?= "-m 2048"
 144 # use pulseaudio on the host side - off as qemu-native is built with alsa
 145 #QB_AUDIO_DRV = "pa"
 146 # expose a virtual 'hda' sound card to the guest (arm/aarch64/x86-64)
 147 QB_AUDIO_OPT = "-soundhw hda"
 148
 149 # Board templates can add extra IMAGE_FSTYPES through this.
 150 # It is added (late) through the AGL image recipes.
 151 AGL_EXTRA_IMAGE_FSTYPES ??= ""
 152 AGL_EXTRA_INITRAMFS_FSTYPES ??= ""
 153 #
 154 # Default IMAGE FSTYPES compressed tarball + ext4.xz
 155 AGL_DEFAULT_IMAGE_FSTYPES ?= "tar.xz ${@bb.utils.contains('DISTRO_FEATURES', 'AGLCI', 'ext4.xz', 'ext4', d)}"
 156 AGL_DEFAULT_INITRAMFS_FSTYPES ?= "ext4.gz"
 157
 158 # DEFAULT IMAGE_FSTYPES for AGL (no - BSPs should not set this)
 159 #
 160 IMAGE_FSTYPES := "${AGL_DEFAULT_IMAGE_FSTYPES} ${AGL_EXTRA_IMAGE_FSTYPES}"
 161 INITRAMFS_FSTYPES := "${AGL_DEFAULT_INITRAMFS_FSTYPES} ${AGL_EXTRA_INITRAMFS_FSTYPES}"
 162 #
 163 # THE FUTURE is 'wic'
 164 # IMAGE_FSTYPES_append = " wic"
 165
 166 # enable the packagemanagement
 167 IMAGE_FEATURES =+ "package-management"
 168 PACKAGE_FEED_URIS = "http://192.168.7.1:8000/tmp/deploy/"
 169 PACKAGE_FEED_BASE_PATHS = "rpm"
 170 PACKAGE_FEED_ARCHS = ""
 171 #${PACKAGE_ARCHS}"
 172
 173
 174 # Fix for rpm metadata clash between nativesdk-cmake and nativesdk-qtbase-tools
 175 # (revalidate after 2017-10-15, 2018-06-12: still required)
 176 DIRFILES_pn-nativesdk-cmake = "1"
 177
 178 # For https://jira.automotivelinux.org/browse/SPEC-1629 :
 179 # We exclude the conflicting vars from the sstate task hash.
 180 # This needs to be verified.
 181 do_package_write_rpm[vardepsexclude] += "ARCHIVER_TOPDIR PF"
 182
 183 # For https://jira.automotivelinux.org/browse/SPEC-1677
 184 # Some issues appear, with the yocto version of valgrind, on aarch64.
 185 # (valgrind exits due to an unhandled instruction')
 186 PREFERRED_VERSION_valgrind ?= "git"