meta-agl-distro/conf/distro/poky-agl.conf

   1 require conf/distro/poky.conf
   2
   3 # AGL specific derivations
   4 DISTRO = "poky-agl"
   5 DISTRO_NAME = "Automotive Grade Linux"
   6 DISTRO_VERSION = "4.0.0"
   7 DISTRO_CODENAME = "dab"
   8 DISTRO_BRANCH_VERSION_TAG = "dab/4.0.0"
   9 SDK_VENDOR = "-aglsdk"
  10 SDK_VERSION := "${@'${DISTRO_VERSION}'.replace('snapshot-${DATE}','snapshot')}"
  11
  12 MAINTAINER = "AGL <automotive-discussions@lists.linuxfoundation.org>"
  13
  14 TARGET_VENDOR = "-agl"
  15
  16 # Override these in poky based distros
  17 AGL_DEFAULT_DISTRO_FEATURES = "largefile systemd opengl wayland pam bluetooth bluez5"
  18 POKY_DEFAULT_DISTRO_FEATURES := "${AGL_DEFAULT_DISTRO_FEATURES}"
  19 OVERRIDES .= ":${DISTRO_CODENAME}"
  20
  21 QEMU_TARGETS ?= "arm aarch64 i386 x86_64"
  22 # Other QEMU_TARGETS "mips mips64 mips64el ppc sh4"
  23
  24 PREMIRRORS ??= "\
  25 bzr://.*/.*   https://download.automotivelinux.org/AGL/mirror/ \n \
  26 cvs://.*/.*   https://download.automotivelinux.org/AGL/mirror/ \n \
  27 git://.*/.*   https://download.automotivelinux.org/AGL/mirror/ \n \
  28 gitsm://.*/.* https://download.automotivelinux.org/AGL/mirror/ \n \
  29 hg://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  30 osc://.*/.*   https://download.automotivelinux.org/AGL/mirror/ \n \
  31 p4://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  32 svn://.*/.*   https://download.automotivelinux.org/AGL/mirror/ \n"
  33
  34 MIRRORS =+ "\
  35 ftp://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  36 http://.*/.*     https://download.automotivelinux.org/AGL/mirror/ \n \
  37 https://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n"
  38
  39 # The CONNECTIVITY_CHECK_URI's are used to test whether we can succesfully
  40 # fetch from the network (and warn you if not). To disable the test set
  41 # the variable to be empty.
  42 # Git example url: git://git.yoctoproject.org/yocto-firewall-test;protocol=git;rev=HEAD
  43 CONNECTIVITY_CHECK_URIS ?= ""
  44
  45 PREFERRED_PROVIDER_udev ?= "systemd"
  46 PREFERRED_PROVIDER_udev-utils ?= "systemd"
  47
  48 VIRTUAL-RUNTIME_init_manager = "systemd"
  49 VIRTUAL-RUNTIME_initscripts = ""
  50
  51 # network manager to use (possible values: systemd, connman)
  52 VIRTUAL-RUNTIME_net_manager = "connman"
  53
  54 DISTRO_FEATURES_APPEND = " "
  55 DISTRO_FEATURES_remove = "x11"
  56 DISTRO_FEATURES_BACKFILL_CONSIDERED = "sysvinit"
  57
  58
  59 # Prefer GStreamer 1.8.x by default
  60 PREFERRED_VERSION_gstreamer1.0              ?= "1.8.%"
  61 PREFERRED_VERSION_gstreamer1.0-plugins-bad  ?= "1.8.%"
  62 PREFERRED_VERSION_gstreamer1.0-plugins-base ?= "1.8.%"
  63 PREFERRED_VERSION_gstreamer1.0-plugins-good ?= "1.8.%"
  64 PREFERRED_VERSION_gstreamer1.0-plugins-ugly ?= "1.8.%"
  65 PREFERRED_VERSION_gstreamer1.0-libav        ?= "1.8.%"
  66 PREFERRED_VERSION_gstreamer1.0-omx          ?= "1.2.%"
  67
  68 # Prefer libjpeg-turbo
  69 PREFERRED_PROVIDER_jpeg = "libjpeg-turbo"
  70
  71 # using multiple BSP layers causes dangling bbappends in meta-agl-bsp
  72 # turn it into a warning
  73 #BB_DANGLINGAPPENDS_WARNONLY = "1"
  74
  75 # enforce security-related compiler flags by default
  76 require conf/distro/include/security_flags.inc
  77 # required overrides, upstreamed but not merged yet:
  78 # http://lists.openembedded.org/pipermail/openembedded-devel/2016-June/107727.html
  79 SECURITY_CFLAGS_pn-llvm3.3 = ""
  80 SECURITY_LDFLAGS_remove_pn-llvm3.3 = "-fstack-protector-strong"
  81 SECURITY_STRINGFORMAT_pn-gpm = ""
  82 SECURITY_CFLAGS_pn-libdbus-c++ = ""
  83 SECURITY_LDFLAGS_pn-libdbus-c++ = ""
  84
  85 # more than 2 targets fail to compile these with the SECURITY compiler flags:
  86 # Bug tracked as SPEC-593
  87 SECURITY_CFLAGS_pn-mozjs = ""
  88 SECURITY_LDFLAGS_pn-mozjs = ""
  89 SECURITY_CFLAGS_pn-gpm = ""
  90 SECURITY_LDFLAGS_pn-gpm = ""
  91 SECURITY_CFLAGS_pn-libatasmart = ""
  92 SECURITY_LDFLAGS_pn-libatasmart = ""
  93
  94 # Not yet upstreamed; should be submitted.
  95 SECURITY_CFLAGS_pn-qtwebengine = "${SECURITY_NO_PIE_CFLAGS}"
  96
  97 #Redefined USER_CLASSES
  98 #Disable prelink. It is unmaintained and likely will go away.
  99 #default: USER_CLASSES ?= "buildstats image-mklibs image-prelink"
 100 USER_CLASSES = "buildstats image-mklibs"
 101
 102 # AGL uses 4 optimization levels
 103 # 2 for ARM 32bit
 104 #   - a high and a medium setting for the CCARGS
 105 #   - the high setting is default (needs >= cortex-a15)
 106 #   - the medium setting is enabled with: DISTRO_FEATURES_append = " agl-medium-arm-compiler "
 107 # 1 for ARM 64bit / AARCH64
 108 # 1 for x86-64
 109 require conf/distro/include/${TARGET_ARCH}-tune.inc
 110
 111 # Generic qemu and qemuboot (runqemu) enhancements
 112 # check qemuboot.bbclass
 113 # - use 2G RAM by default
 114 QB_MEM ?= "-m 2048"
 115 # use pulseaudio on the host side - off as qemu-native is built with alsa
 116 #QB_AUDIO_DRV = "pa"
 117 # expose a virtual 'hda' sound card to the guest (arm/aarch64/x86-64)
 118 QB_AUDIO_OPT = "-soundhw hda"
 119
 120 # Board templates can add extra IMAGE_FSTYPES through this.
 121 # It is added (late) through the AGL image recipes.
 122 AGL_EXTRA_IMAGE_FSTYPES ??= ""
 123 AGL_EXTRA_INITRAMFS_FSTYPES ??= ""
 124 #
 125 # Default IMAGE FSTYPES compressed tarball + ext4.xz
 126 AGL_DEFAULT_IMAGE_FSTYPES ?= "tar.xz ${@bb.utils.contains('DISTRO_FEATURES', 'AGLCI', 'ext4.xz', 'ext4', d)}"
 127 AGL_DEFAULT_INITRAMFS_FSTYPES ?= "ext4.gz"
 128
 129 # DEFAULT IMAGE_FSTYPES for AGL (no - BSPs should not set this)
 130 #
 131 IMAGE_FSTYPES := "${AGL_DEFAULT_IMAGE_FSTYPES} ${AGL_EXTRA_IMAGE_FSTYPES}"
 132 INITRAMFS_FSTYPES := "${AGL_DEFAULT_INITRAMFS_FSTYPES} ${AGL_EXTRA_INITRAMFS_FSTYPES}"
 133 #
 134 # THE FUTURE is 'wic'
 135 # IMAGE_FSTYPES_append = " wic"