meta-agl-core/recipes-graphics/wayland/weston-ini-conf.bb

   1 SUMMARY = "Configuration file for the Weston and AGL Wayland compositors"
   2 LICENSE = "MIT"
   3 LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
   4
   5 SRC_URI = " \
   6         file://core.cfg \
   7         file://shell.cfg \
   8         file://hdmi-a-1-0.cfg \
   9         file://hdmi-a-1-90.cfg \
  10         file://hdmi-a-1-180.cfg \
  11         file://hdmi-a-1-270.cfg \
  12         file://remote-output.cfg \
  13         file://transmitter-output.cfg.in \
  14         file://virtual-0.cfg \
  15         file://virtual-90.cfg \
  16         file://virtual-180.cfg \
  17         file://virtual-270.cfg \
  18 "
  19
  20 S = "${WORKDIR}"
  21
  22 inherit update-alternatives
  23
  24 # Default primary display/orientation fragment
  25 WESTON_DISPLAYS ?= "hdmi-a-1-90"
  26
  27 # Configuration fragments to use in weston.ini.*
  28 # Note that some may be replaced/removed when building the landscape
  29 # configuration.
  30 WESTON_FRAGMENTS = "core shell ${WESTON_DISPLAYS}"
  31
  32 # On-target weston.ini directory
  33 weston_ini_dir = "${sysconfdir}/xdg/weston"
  34
  35 # Options for the user to change in local.conf
  36 # e.g. TRANSMITTER_OUTPUT_MODE = "1080x1488"
  37 TRANSMITTER_OUTPUT_MODE ??= "640x720@30"
  38 TRANSMITTER_OUTPUT_HOST ??= "192.168.10.3"
  39 TRANSMITTER_OUTPUT_PORT ??= "5005"
  40
  41 do_configure() {
  42     sed -e "s#mode=.*#mode=${TRANSMITTER_OUTPUT_MODE}#" \
  43         -e "s#host=.*#host=${TRANSMITTER_OUTPUT_HOST}#" \
  44         -e "s#port=.*#port=${TRANSMITTER_OUTPUT_PORT}#" \
  45         ${WORKDIR}/transmitter-output.cfg.in  > ${WORKDIR}/transmitter-output.cfg
  46 }
  47
  48 do_compile() {
  49     # Put all of our cfg files together for a default portrait
  50     # orientation configuration
  51     rm -f ${WORKDIR}/weston.ini.default
  52     for F in ${WESTON_FRAGMENTS}; do
  53         cat ${WORKDIR}/${F}.cfg >> ${WORKDIR}/weston.ini.default
  54         echo >> ${WORKDIR}/weston.ini.default
  55     done
  56     sed -i -e '$ d' ${WORKDIR}/weston.ini.default
  57
  58     cat ${WORKDIR}/weston.ini.default > ${WORKDIR}/weston.ini.default-no-activate
  59     sed -i -e 's#\[core\]#[core]\nactivate-by-default=false#' ${WORKDIR}/weston.ini.default-no-activate
  60
  61     # Do it again, but filter fragments to configure for landscape
  62     # and a corresponding landscape-inverted that is 180 degrees
  63     # rotated.
  64     rm -f ${WORKDIR}/weston.ini.landscape
  65     for F in ${WESTON_FRAGMENTS}; do
  66         INVF=$F
  67         if echo $F | grep '^hdmi-a-1-\(90\|270\)$'; then
  68             F="hdmi-a-1-0"
  69             INVF="hdmi-a-1-180"
  70         elif echo $F | grep '^virtual-90$'; then
  71             F="virtual-0"
  72             INVF="virtual-180"
  73         fi
  74         cat ${WORKDIR}/${F}.cfg >> ${WORKDIR}/weston.ini.landscape
  75         cat ${WORKDIR}/${INVF}.cfg >> ${WORKDIR}/weston.ini.landscape-inverted
  76         echo >> ${WORKDIR}/weston.ini.landscape
  77         echo >> ${WORKDIR}/weston.ini.landscape-inverted
  78     done
  79     sed -i -e '$ d' ${WORKDIR}/weston.ini.landscape
  80     sed -i -e '$ d' ${WORKDIR}/weston.ini.landscape-inverted
  81
  82     cat ${WORKDIR}/weston.ini.landscape > ${WORKDIR}/weston.ini.landscape-no-activate
  83     sed -i -e 's#\[core\]#[core]\nactivate-by-default=false#' ${WORKDIR}/weston.ini.landscape-no-activate
  84 }
  85
  86 do_install:append() {
  87     install -d ${D}${weston_ini_dir}
  88     install -m 0644 ${WORKDIR}/weston.ini.default ${D}${weston_ini_dir}/
  89     install -m 0644 ${WORKDIR}/weston.ini.default-no-activate ${D}${weston_ini_dir}/
  90     install -m 0644 ${WORKDIR}/weston.ini.landscape-no-activate ${D}${weston_ini_dir}/
  91     install -m 0644 ${WORKDIR}/weston.ini.landscape ${D}${weston_ini_dir}/
  92     install -m 0644 ${WORKDIR}/weston.ini.landscape-inverted ${D}${weston_ini_dir}/
  93 }
  94
  95 PACKAGE_ARCH = "${MACHINE_ARCH}"
  96
  97 # Use the alternative mechanism to handle multiple packages providing
  98 # weston.ini.  This seems simpler than other possible approaches.
  99 # Note that for now the generated packages are being marked as
 100 # incompatible with each other for simplicity, that can be changed if
 101 # a usecase where switching between alternatives at runtime is desirable
 102 # appears.
 103
 104 ALTERNATIVE_LINK_NAME[weston.ini] = "${weston_ini_dir}/weston.ini"
 105
 106 RDEPENDS:${PN} = "weston-init"
 107 RPROVIDES:${PN} = "weston-ini"
 108 RCONFLICTS:${PN} = "${PN}-landscape"
 109 ALTERNATIVE:${PN} = "weston.ini"
 110 ALTERNATIVE_TARGET_${PN} = "${weston_ini_dir}/weston.ini.default"
 111
 112 PACKAGE_BEFORE_PN += "${PN}-landscape"
 113
 114 FILES:${PN}-landscape = "${weston_ini_dir}/weston.ini.landscape"
 115
 116 RDEPENDS:${PN}-landscape = "weston-init"
 117 RPROVIDES:${PN}-landscape = "weston-ini"
 118 RCONFLICTS:${PN}-landscape = "${PN}"
 119 ALTERNATIVE:${PN}-landscape = "weston.ini"
 120 ALTERNATIVE_TARGET_${PN}-landscape = "${weston_ini_dir}/weston.ini.landscape"
 121
 122 PACKAGE_BEFORE_PN += "${PN}-landscape-inverted"
 123
 124 FILES:${PN}-landscape-inverted = "${weston_ini_dir}/weston.ini.landscape-inverted"
 125
 126 RDEPENDS:${PN}-landscape-inverted = "weston-init"
 127 RPROVIDES:${PN}-landscape-inverted = "weston-ini"
 128 RCONFLICTS:${PN}-landscape-inverted = "${PN}"
 129 ALTERNATIVE:${PN}-landscape-inverted = "weston.ini"
 130 ALTERNATIVE_TARGET_${PN}-landscape-inverted = "${weston_ini_dir}/weston.ini.landscape-inverted"
 131
 132 # no activation by default
 133 PACKAGE_BEFORE_PN += "${PN}-no-activate"
 134
 135 FILES:${PN}-no-activate = "${weston_ini_dir}/weston.ini.default-no-activate"
 136
 137 RDEPENDS:${PN}-no-activate = "weston-init"
 138 RPROVIDES:${PN}-no-activate = "weston-ini"
 139 RCONFLICTS:${PN}-no-activate = "${PN}"
 140 ALTERNATIVE:${PN}-no-activate = "weston.ini"
 141 ALTERNATIVE_TARGET_${PN}-no-activate = "${weston_ini_dir}/weston.ini.default-no-activate"
 142
 143 # landscape, no activation by default
 144 PACKAGE_BEFORE_PN += "${PN}-landscape-no-activate"
 145
 146 FILES:${PN}-landscape-no-activate = "${weston_ini_dir}/weston.ini.landscape-no-activate"
 147
 148 RDEPENDS:${PN}-landscape-no-activate = "weston-init"
 149 RPROVIDES:${PN}-landscape-no-activate = "weston-ini"
 150 RCONFLICTS:${PN}-landscape-no-activate = "${PN}"
 151 ALTERNATIVE:${PN}-landscape-no-activate = "weston.ini"
 152 ALTERNATIVE_TARGET_${PN}-landscape-no-activate = "${weston_ini_dir}/weston.ini.landscape-no-activate"
 153
 154
 155 # This is a settings-only package, we do not need a development package
 156 # (and its fixed dependency to ${PN} being installed)
 157 PACKAGES:remove = "${PN}-dev ${PN}-staticdev"