meta-agl-core/recipes-graphics/wayland/agl-compositor_git.bb

   1 SUMMARY = "Reference Wayland compositor for AGL"
   2 DESCRIPTION = "The AGL compositor is a reference Wayland server for Automotive \
   3 Grade Linux, using libweston as a base to provide a graphical environment for \
   4 the automotive environment."
   5
   6 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/q/project:src%252Fagl-compositor"
   7 SECTION = "x11"
   8 LICENSE = "MIT"
   9 LIC_FILES_CHKSUM = "file://COPYING;md5=fac6abe0003c4d142ff8fa1f18316df0"
  10
  11 DEPENDS = "wayland wayland-protocols wayland-native weston grpc grpc-native \
  12            ${@bb.utils.contains('AGL_FEATURES', 'waltham-remoting', 'waltham waltham-transmitter-plugin', '', d)}"
  13
  14 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/agl-compositor.git;protocol=https;branch=${AGL_BRANCH}"
  15 SRCREV = "2288d78df24b9c8101fac29be1343c5591d81165"
  16
  17 AGL_BRANCH:aglnext = "next"
  18 SRCREV:aglnext = "${AUTOREV}"
  19
  20 PV = "0.0.10+git${SRCPV}"
  21 S = "${WORKDIR}/git"
  22
  23 PACKAGECONFIG ?= ""
  24 PACKAGECONFIG[policy-rba] = "-Dpolicy-default=rba,,librba,librba rba-config"
  25 PACKAGECONFIG[policy-deny-all] = "-Dpolicy-default=deny-all,,"
  26
  27 inherit meson pkgconfig python3native
  28
  29 FILES:${PN} = " \
  30     ${bindir}/agl-compositor \
  31     ${bindir}/agl-screenshooter \
  32     ${libdir}/agl-compositor/libexec_compositor.so.0 \
  33     ${libdir}/agl-compositor/libexec_compositor.so.0.0.21 \
  34     ${libdir}/agl-compositor/agl-shell-grpc-server \
  35 "
  36
  37 RDEPENDS:${PN} += " \
  38     agl-compositor-init \
  39     xkeyboard-config \
  40     ${@bb.utils.filter('DISTRO_FEATURES', 'polkit', d)} \
  41     ${@bb.utils.contains('AGL_FEATURES', 'waltham-remoting', 'waltham waltham-transmitter-plugin', '', d)} \
  42 "
  43
  44 FILES:${PN}-dev += " \
  45     ${datadir}/agl-compositor/protocols/agl-shell.xml \
  46     ${datadir}/agl-compositor/protocols/agl-shell-desktop.xml \
  47     ${libdir}/agl-compositor/libexec_compositor.so \
  48 "