meta-agl-core/recipes-graphics/wayland/agl-compositor_git.bb

   1 SUMMARY = "Reference Wayland compositor for AGL"
   2 DESCRIPTION = "The AGL compositor is a reference Wayland server for Automotive \
   3 Grade Linux, using libweston as a base to provide a graphical environment for \
   4 the automotive environment."
   5
   6 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/q/project:src%252Fagl-compositor"
   7 SECTION = "x11"
   8 LICENSE = "MIT"
   9 LIC_FILES_CHKSUM = "file://COPYING;md5=fac6abe0003c4d142ff8fa1f18316df0"
  10
  11 DEPENDS = "wayland wayland-protocols wayland-native weston"
  12
  13 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/agl-compositor.git;protocol=https;branch=${AGL_BRANCH}"
  14 SRCREV = "01171e9abf8a132aa872bf2880e11a464a8ce3cc"
  15 AGL_BRANCH:aglnext = "next"
  16 SRCREV:aglnext = "${AUTOREV}"
  17
  18 PV = "0.0.10+git${SRCPV}"
  19 S = "${WORKDIR}/git"
  20
  21 PACKAGECONFIG ?= ""
  22 PACKAGECONFIG[policy-rba] = "-Dpolicy-default=rba,,librba,librba rba-config"
  23 PACKAGECONFIG[policy-deny-all] = "-Dpolicy-default=deny-all,,"
  24 PACKAGECONFIG[grpc-proxy] = "-Dgrpc-proxy=true,-Dgrpc-proxy=false,grpc grpc-native,grpc agl-shell-grpc-server"
  25
  26 inherit meson pkgconfig python3native
  27
  28 PACKAGES =+ "agl-shell-grpc-server"
  29
  30 FILES:${PN} = " \
  31     ${bindir}/agl-compositor \
  32     ${bindir}/agl-screenshooter \
  33     ${libdir}/agl-compositor/libexec_compositor.so.0 \
  34     ${libdir}/agl-compositor/libexec_compositor.so.0.0.21 \
  35 "
  36
  37 FILES:agl-shell-grpc-server = " \
  38     ${libdir}/agl-compositor/agl-shell-grpc-server \
  39 "
  40
  41 RDEPENDS:${PN} += " \
  42     agl-compositor-init \
  43     xkeyboard-config \
  44     ${@bb.utils.filter('DISTRO_FEATURES', 'polkit', d)} \
  45 "
  46
  47 FILES:${PN}-dev += " \
  48     ${datadir}/agl-compositor/protocols/agl-shell.xml \
  49     ${datadir}/agl-compositor/protocols/agl-shell-desktop.xml \
  50     ${libdir}/agl-compositor/libexec_compositor.so \
  51 "