meta-agl-core/recipes-graphics/wayland/agl-compositor_git.bb

   1 SUMMARY = "Reference Wayland compositor for AGL"
   2 DESCRIPTION = "The AGL compositor is a reference Wayland server for Automotive \
   3 Grade Linux, using libweston as a base to provide a graphical environment for \
   4 the automotive environment."
   5
   6 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/q/project:src%252Fagl-compositor"
   7 SECTION = "x11"
   8 LICENSE = "MIT"
   9 LIC_FILES_CHKSUM = "file://COPYING;md5=fac6abe0003c4d142ff8fa1f18316df0"
  10
  11 DEPENDS = "wayland wayland-protocols wayland-native weston grpc grpc-native \
  12            ${@bb.utils.contains('AGL_FEATURES', 'waltham-remoting', 'waltham waltham-transmitter-plugin', '', d)}"
  13
  14 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/agl-compositor.git;protocol=https;branch=${AGL_BRANCH}"
  15 SRCREV = "7ef34e0c465a7596f87866e88bc5a9eed2ca7c05"
  16 AGL_BRANCH:aglnext = "next"
  17 SRCREV:aglnext = "${AUTOREV}"
  18
  19 PV = "0.0.10+git${SRCPV}"
  20 S = "${WORKDIR}/git"
  21
  22 PACKAGECONFIG ?= ""
  23 PACKAGECONFIG[policy-rba] = "-Dpolicy-default=rba,,librba,librba rba-config"
  24 PACKAGECONFIG[policy-deny-all] = "-Dpolicy-default=deny-all,,"
  25
  26 inherit meson pkgconfig python3native
  27
  28 FILES:${PN} = " \
  29     ${bindir}/agl-compositor \
  30     ${bindir}/agl-screenshooter \
  31     ${libdir}/agl-compositor/libexec_compositor.so.0 \
  32     ${libdir}/agl-compositor/libexec_compositor.so.0.0.0 \
  33     ${libdir}/agl-compositor/agl-shell-grpc-server \
  34 "
  35
  36 RDEPENDS:${PN} += " \
  37     agl-compositor-init \
  38     xkeyboard-config \
  39     ${@bb.utils.filter('DISTRO_FEATURES', 'polkit', d)} \
  40     ${@bb.utils.contains('AGL_FEATURES', 'waltham-remoting', 'waltham waltham-transmitter-plugin', '', d)} \
  41 "
  42
  43 FILES:${PN}-dev += " \
  44     ${datadir}/agl-compositor/protocols/agl-shell.xml \
  45     ${datadir}/agl-compositor/protocols/agl-shell-desktop.xml \
  46     ${libdir}/agl-compositor/libexec_compositor.so \
  47 "