meta-agl-core/recipes-graphics/wayland/agl-compositor_git.bb

   1 SUMMARY = "Reference Wayland compositor for AGL"
   2 DESCRIPTION = "The AGL compositor is a reference Wayland server for Automotive \
   3 Grade Linux, using libweston as a base to provide a graphical environment for \
   4 the automotive environment."
   5
   6 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/q/project:src%252Fagl-compositor"
   7 SECTION = "x11"
   8 LICENSE = "MIT"
   9 LIC_FILES_CHKSUM = "file://COPYING;md5=fac6abe0003c4d142ff8fa1f18316df0"
  10
  11 DEPENDS = "wayland wayland-protocols wayland-native weston"
  12
  13 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/agl-compositor.git;protocol=https;branch=${AGL_BRANCH}"
  14 SRCREV = "a68408367cf5e254d981e1d43ba261b9aade6166"
  15 AGL_BRANCH:aglnext = "next"
  16 SRCREV:aglnext = "${AUTOREV}"
  17
  18 PV = "0.0.10+git${SRCPV}"
  19 S = "${WORKDIR}/git"
  20
  21 PACKAGECONFIG ?= ""
  22 PACKAGECONFIG[policy-rba] = "-Dpolicy-default=rba,,librba,librba rba-config"
  23 PACKAGECONFIG[policy-deny-all] = "-Dpolicy-default=deny-all,,"
  24 PACKAGECONFIG[grpc-proxy] = "-Dgrpc-proxy=true,-Dgrpc-proxy=false,grpc grpc-native,grpc agl-shell-grpc-server"
  25
  26 inherit meson pkgconfig python3native
  27
  28 # Reuse include file from upstream weston since we have the same requirements
  29 require recipes-graphics/wayland/required-distro-features.inc
  30
  31 PACKAGES =+ "agl-shell-grpc-server"
  32
  33 FILES:${PN} = " \
  34     ${bindir}/agl-compositor \
  35     ${bindir}/agl-screenshooter \
  36     ${libdir}/agl-compositor/libexec_compositor.so.0 \
  37     ${libdir}/agl-compositor/libexec_compositor.so.0.0.21 \
  38 "
  39
  40 FILES:agl-shell-grpc-server = " \
  41     ${libdir}/agl-compositor/agl-shell-grpc-server \
  42 "
  43
  44 RDEPENDS:${PN} += " \
  45     agl-compositor-init \
  46     xkeyboard-config \
  47 "
  48
  49 FILES:${PN}-dev += " \
  50     ${datadir}/agl-compositor/protocols/agl-shell.xml \
  51     ${datadir}/agl-compositor/protocols/agl-shell-desktop.xml \
  52     ${libdir}/agl-compositor/libexec_compositor.so \
  53 "