meta-agl-core/conf/distro/poky-agl.conf

   1 require conf/distro/poky.conf
   2
   3 # AGL specific derivations
   4 DISTRO = "poky-agl"
   5 DISTRO_NAME = "Automotive Grade Linux"
   6
   7
   8 # Release flags
   9 DISTRO_CODENAME = "needlefish"
  10 AGL_BRANCH = "master"
  11 AGLVERSION = "13.90.0"
  12 # switch  devel/release
  13 AGLRELEASETYPE ?= "agldevelopment"
  14 #AGLRELEASETYPE ?= "aglrelease"
  15 OVERRIDES .= ":${AGLRELEASETYPE}"
  16 #
  17
  18 #for development
  19 DISTRO_VERSION:agldevelopment := "${AGLVERSION}+snapshot-${METADATA_REVISION}"
  20 AGL_APP_REVISION:agldevelopment = "${AUTOREV}"
  21 AGL_DEFAULT_REVISION:agldevelopment = "${AUTOREV}"
  22
  23 #for release
  24 DISTRO_VERSION:aglrelease := "${AGLVERSION}"
  25 DISTRO_BRANCH_VERSION_TAG = "${DISTRO_CODENAME}/${@'${DISTRO_VERSION}'.replace('+snapshot-${METADATA_REVISION}','')}"
  26 AGL_APP_REVISION:aglrelease := "refs/tags/${DISTRO_BRANCH_VERSION_TAG}"
  27 AGL_DEFAULT_REVISION:aglrelease := "refs/tags/${DISTRO_BRANCH_VERSION_TAG}"
  28
  29 #for next branch development
  30 OVERRIDES .= ":aglnext"
  31
  32 # reproducible builds:
  33 # Set the desired timestamps
  34 export SOURCE_DATE_EPOCH = "1593400000"
  35 REPRODUCIBLE_TIMESTAMP_ROOTFS = "1593400000"
  36
  37
  38 # SDK
  39 SDK_VENDOR = "-aglsdk"
  40
  41 # SDKPATHINSTALL is the folder where the SDK is going to be installed
  42 # Due to an issue with the qt5 environment (see SPEC-1667),
  43 # we add DEFAULTTUNE to the SDKPATH to mitigate the issue.
  44 SDKPATHINSTALL = "/opt/agl-sdk/${SDK_VERSION}-${DEFAULTTUNE}"
  45
  46
  47 MAINTAINER = "AGL https://lists.automotivelinux.org/g/agl-dev-community"
  48
  49 TARGET_VENDOR = "-agl"
  50
  51 # Override these in poky based distros
  52 AGL_DEFAULT_DISTRO_FEATURES = "largefile opengl wayland pam bluetooth bluez5 3g polkit"
  53 POKY_DEFAULT_DISTRO_FEATURES := "${AGL_DEFAULT_DISTRO_FEATURES}"
  54 OVERRIDES .= ":${DISTRO_CODENAME}"
  55
  56 DISTRO_FEATURES:remove = "x11"
  57 DISTRO_FEATURES_BACKFILL_CONSIDERED = "pulseaudio"
  58
  59 INIT_MANAGER = "systemd"
  60 # Override default of "systemd-compat-units"
  61 VIRTUAL-RUNTIME_initscripts = ""
  62 # Override default of "busybox-syslog"
  63 VIRTUAL-RUNTIME_base-utils-syslog = ""
  64
  65 # network manager to use (possible values: systemd, connman)
  66 VIRTUAL-RUNTIME_net_manager = "connman"
  67
  68
  69 QEMU_TARGETS ?= "arm aarch64 i386 x86_64 riscv64"
  70 # Other QEMU_TARGETS "mips mips64 mips64el ppc sh4"
  71
  72 MIRRORS =+ "\
  73 bzr://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  74 cvs://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  75 git://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  76 gitsm://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  77 hg://.*/.*       https://download.automotivelinux.org/AGL/mirror/ \n \
  78 osc://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  79 p4://.*/.*       https://download.automotivelinux.org/AGL/mirror/ \n \
  80 svn://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  81 bzr://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  82 cvs://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  83 git://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  84 gitsm://.*/.*    http://download.automotivelinux.org/AGL/mirror/  \n \
  85 hg://.*/.*       http://download.automotivelinux.org/AGL/mirror/  \n \
  86 osc://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  87 p4://.*/.*       http://download.automotivelinux.org/AGL/mirror/  \n \
  88 svn://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  89                  \
  90 ftp://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  91 http://.*/.*     https://download.automotivelinux.org/AGL/mirror/ \n \
  92 https://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  93 ftp://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  94 http://.*/.*     http://download.automotivelinux.org/AGL/mirror/  \n \
  95 https://.*/.*    http://download.automotivelinux.org/AGL/mirror/  \n \
  96 "
  97
  98 # The CONNECTIVITY_CHECK_URI's are used to test whether we can succesfully
  99 # fetch from the network (and warn you if not). To disable the test set
 100 # the variable to be empty.
 101 # Git example url: git://git.yoctoproject.org/yocto-firewall-test;protocol=git;rev=HEAD
 102 CONNECTIVITY_CHECK_URIS ?= ""
 103
 104 # using multiple BSP layers causes dangling bbappends in meta-agl-bsp
 105 # turn it into a warning
 106 #BB_DANGLINGAPPENDS_WARNONLY = "1"
 107
 108 # Not yet upstreamed; should be submitted.
 109 SECURITY_CFLAGS:pn-qtwebengine = "${SECURITY_NO_PIE_CFLAGS}"
 110
 111 #Redefined USER_CLASSES
 112 #Disable prelink. It is unmaintained and likely will go away.
 113 #default: USER_CLASSES ?= "buildstats image-prelink"
 114 USER_CLASSES = "buildstats"
 115
 116 # AGL uses 4 optimization levels
 117 # 2 for ARM 32bit
 118 #   - a high and a medium setting for the CCARGS
 119 #   - the high setting is default (needs >= cortex-a15)
 120 #   - the medium setting is enabled with: DISTRO_FEATURES:append = " agl-medium-arm-compiler "
 121 # 1 for ARM 64bit / AARCH64
 122 # 1 for x86-64
 123 # 1 for RISC-V 64-bit
 124 require conf/distro/include/${TARGET_ARCH}-tune.inc
 125
 126 # Generic qemu and qemuboot (runqemu) enhancements
 127 # check qemuboot.bbclass
 128 # - use 2G RAM by default
 129 QB_MEM ?= "-m 2048"
 130 # use pulseaudio on the host side - off as qemu-native is built with alsa
 131 #QB_AUDIO_DRV = "pa"
 132 # expose a virtual 'hda' sound card to the guest (arm/aarch64/x86-64)
 133 QB_AUDIO_OPT = "-device intel-hda -device hda-duplex -audiodev alsa,id=agl"
 134
 135 # Board templates can add extra IMAGE_FSTYPES through this.
 136 # It is added (late) through the AGL image recipes.
 137 AGL_EXTRA_IMAGE_FSTYPES ??= ""
 138 AGL_EXTRA_INITRAMFS_FSTYPES ??= ""
 139 #
 140 # Default IMAGE FSTYPES wic.xz
 141 AGL_DEFAULT_IMAGE_FSTYPES ?= "wic.xz wic.bmap wic.xz.sha256sum"
 142 AGL_DEFAULT_IMAGE_FSTYPES:qemuall ?= "${@bb.utils.contains('DISTRO_FEATURES', 'AGLCI', 'ext4.xz', 'ext4', d)}"
 143 AGL_DEFAULT_IMAGE_FSTYPES:append:netboot = " ${@bb.utils.contains('DISTRO_FEATURES', 'AGLCI', 'ext4.xz', 'ext4', d)}"
 144 AGL_DEFAULT_INITRAMFS_FSTYPES ?= "ext4.gz"
 145
 146 # DEFAULT IMAGE_FSTYPES for AGL (no - BSPs should not set this)
 147 #
 148 IMAGE_FSTYPES = "${AGL_DEFAULT_IMAGE_FSTYPES} ${AGL_EXTRA_IMAGE_FSTYPES}"
 149 INITRAMFS_FSTYPES = "${AGL_DEFAULT_INITRAMFS_FSTYPES} ${AGL_EXTRA_INITRAMFS_FSTYPES}"
 150 #
 151
 152 # Fix for rpm metadata clash between nativesdk-cmake and nativesdk-qtbase-tools
 153 # (revalidate after 2017-10-15, 2018-06-12: still required)
 154 DIRFILES:pn-nativesdk-cmake = "1"
 155
 156 # For https://jira.automotivelinux.org/browse/SPEC-1629 :
 157 # We exclude the conflicting vars from the sstate task hash.
 158 # This needs to be verified.
 159 do_package_write_rpm[vardepsexclude] += "ARCHIVER_TOPDIR PF"
 160