meta-agl-core/conf/distro/poky-agl.conf

   1 require conf/distro/poky.conf
   2
   3 # AGL specific derivations
   4 DISTRO = "poky-agl"
   5 DISTRO_NAME = "Automotive Grade Linux"
   6
   7
   8 # Release flags
   9 DISTRO_CODENAME = "lamprey"
  10 AGL_BRANCH = "master"
  11 AGLVERSION = "11.91.0"
  12 # switch  devel/release
  13 #AGLRELEASETYPE ?= "agldevelopment"
  14 AGLRELEASETYPE ?= "aglrelease"
  15 OVERRIDES .= ":${AGLRELEASETYPE}"
  16 #
  17
  18 #for development
  19 DISTRO_VERSION_agldevelopment := "${AGLVERSION}+snapshot-${DATE}"
  20 AGL_APP_REVISION_agldevelopment = "${AUTOREV}"
  21 AGL_DEFAULT_REVISION_agldevelopment = "${AUTOREV}"
  22
  23 #for release
  24 DISTRO_VERSION_aglrelease := "${AGLVERSION}"
  25 DISTRO_BRANCH_VERSION_TAG = "${DISTRO_CODENAME}/${@'${DISTRO_VERSION}'.replace('+snapshot-${DATE}','')}"
  26 AGL_APP_REVISION_aglrelease := "refs/tags/${DISTRO_BRANCH_VERSION_TAG}"
  27 AGL_DEFAULT_REVISION_aglrelease := "refs/tags/${DISTRO_BRANCH_VERSION_TAG}"
  28
  29 # reproducible builds:
  30 # enable the flag
  31 BUILD_REPRODUCIBLE_BINARIES = "1"
  32 # Set the desired timestamps
  33 export SOURCE_DATE_EPOCH = "1593400000"
  34 REPRODUCIBLE_TIMESTAMP_ROOTFS = "1593400000"
  35 # inherit the class
  36 INHERIT += "reproducible_build"
  37
  38
  39 # SDK
  40 SDK_VENDOR = "-aglsdk"
  41
  42 # SDKPATH is the folder where the SDK is going to be installed
  43 # Due to an issue with the qt5 environment (see SPEC-1667),
  44 # we add DEFAULTTUNE to the SDKPATH to mitigate the issue.
  45 SDKPATH = "/opt/agl-sdk/${SDK_VERSION}-${DEFAULTTUNE}"
  46
  47
  48 MAINTAINER = "AGL https://lists.automotivelinux.org/g/agl-dev-community"
  49
  50 TARGET_VENDOR = "-agl"
  51
  52 # Override these in poky based distros
  53 AGL_DEFAULT_DISTRO_FEATURES = "largefile opengl wayland pam bluetooth bluez5 3g polkit"
  54 POKY_DEFAULT_DISTRO_FEATURES := "${AGL_DEFAULT_DISTRO_FEATURES}"
  55 OVERRIDES .= ":${DISTRO_CODENAME}"
  56
  57 DISTRO_FEATURES_remove = "x11"
  58 DISTRO_FEATURES_BACKFILL_CONSIDERED = "pulseaudio"
  59
  60 INIT_MANAGER = "systemd"
  61 # Override default of "systemd-compat-units"
  62 VIRTUAL-RUNTIME_initscripts = ""
  63
  64 # network manager to use (possible values: systemd, connman)
  65 VIRTUAL-RUNTIME_net_manager = "connman"
  66
  67
  68 QEMU_TARGETS ?= "arm aarch64 i386 x86_64 riscv64"
  69 # Other QEMU_TARGETS "mips mips64 mips64el ppc sh4"
  70
  71 MIRRORS =+ "\
  72 bzr://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  73 cvs://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  74 git://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  75 gitsm://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  76 hg://.*/.*       https://download.automotivelinux.org/AGL/mirror/ \n \
  77 osc://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  78 p4://.*/.*       https://download.automotivelinux.org/AGL/mirror/ \n \
  79 svn://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  80 bzr://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  81 cvs://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  82 git://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  83 gitsm://.*/.*    http://download.automotivelinux.org/AGL/mirror/  \n \
  84 hg://.*/.*       http://download.automotivelinux.org/AGL/mirror/  \n \
  85 osc://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  86 p4://.*/.*       http://download.automotivelinux.org/AGL/mirror/  \n \
  87 svn://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  88                  \
  89 ftp://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  90 http://.*/.*     https://download.automotivelinux.org/AGL/mirror/ \n \
  91 https://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  92 ftp://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  93 http://.*/.*     http://download.automotivelinux.org/AGL/mirror/  \n \
  94 https://.*/.*    http://download.automotivelinux.org/AGL/mirror/  \n \
  95 "
  96
  97 # The CONNECTIVITY_CHECK_URI's are used to test whether we can succesfully
  98 # fetch from the network (and warn you if not). To disable the test set
  99 # the variable to be empty.
 100 # Git example url: git://git.yoctoproject.org/yocto-firewall-test;protocol=git;rev=HEAD
 101 CONNECTIVITY_CHECK_URIS ?= ""
 102
 103 # using multiple BSP layers causes dangling bbappends in meta-agl-bsp
 104 # turn it into a warning
 105 #BB_DANGLINGAPPENDS_WARNONLY = "1"
 106
 107 # Not yet upstreamed; should be submitted.
 108 SECURITY_CFLAGS_pn-qtwebengine = "${SECURITY_NO_PIE_CFLAGS}"
 109
 110 #Redefined USER_CLASSES
 111 #Disable prelink. It is unmaintained and likely will go away.
 112 #default: USER_CLASSES ?= "buildstats image-mklibs image-prelink"
 113 USER_CLASSES = "buildstats image-mklibs"
 114
 115 # AGL uses 4 optimization levels
 116 # 2 for ARM 32bit
 117 #   - a high and a medium setting for the CCARGS
 118 #   - the high setting is default (needs >= cortex-a15)
 119 #   - the medium setting is enabled with: DISTRO_FEATURES_append = " agl-medium-arm-compiler "
 120 # 1 for ARM 64bit / AARCH64
 121 # 1 for x86-64
 122 # 1 for RISC-V 64-bit
 123 require conf/distro/include/${TARGET_ARCH}-tune.inc
 124
 125 # Generic qemu and qemuboot (runqemu) enhancements
 126 # check qemuboot.bbclass
 127 # - use 2G RAM by default
 128 QB_MEM ?= "-m 2048"
 129 # use pulseaudio on the host side - off as qemu-native is built with alsa
 130 #QB_AUDIO_DRV = "pa"
 131 # expose a virtual 'hda' sound card to the guest (arm/aarch64/x86-64)
 132 QB_AUDIO_OPT = "-soundhw hda"
 133
 134 # Board templates can add extra IMAGE_FSTYPES through this.
 135 # It is added (late) through the AGL image recipes.
 136 AGL_EXTRA_IMAGE_FSTYPES ??= ""
 137 AGL_EXTRA_INITRAMFS_FSTYPES ??= ""
 138 #
 139 # Default IMAGE FSTYPES wic.xz
 140 AGL_DEFAULT_IMAGE_FSTYPES ?= "wic.xz wic.bmap wic.xz.sha256sum"
 141 AGL_DEFAULT_IMAGE_FSTYPES_qemuall ?= "${@bb.utils.contains('DISTRO_FEATURES', 'AGLCI', 'ext4.xz', 'ext4', d)}"
 142 AGL_DEFAULT_IMAGE_FSTYPES_append_netboot = " ${@bb.utils.contains('DISTRO_FEATURES', 'AGLCI', 'ext4.xz', 'ext4', d)}"
 143 AGL_DEFAULT_INITRAMFS_FSTYPES ?= "ext4.gz"
 144
 145 # DEFAULT IMAGE_FSTYPES for AGL (no - BSPs should not set this)
 146 #
 147 IMAGE_FSTYPES = "${AGL_DEFAULT_IMAGE_FSTYPES} ${AGL_EXTRA_IMAGE_FSTYPES}"
 148 INITRAMFS_FSTYPES = "${AGL_DEFAULT_INITRAMFS_FSTYPES} ${AGL_EXTRA_INITRAMFS_FSTYPES}"
 149 #
 150 # THE FUTURE is 'wic'
 151 # IMAGE_FSTYPES_append = " wic"
 152
 153 # enable the packagemanagement
 154 IMAGE_FEATURES =+ "package-management"
 155 PACKAGE_FEED_URIS = "http://192.168.7.1:8000/tmp/deploy/"
 156 PACKAGE_FEED_BASE_PATHS = "rpm"
 157 PACKAGE_FEED_ARCHS = ""
 158 #${PACKAGE_ARCHS}"
 159
 160 # Complementary package definitions for agl-test-wgt and agl-devel-wgt
 161 # image features
 162 COMPLEMENTARY_GLOB[agl-test-wgt] = '*-test'
 163 COMPLEMENTARY_GLOB[agl-devel-wgt] = '*-coverage *-debug'
 164
 165 # Fix for rpm metadata clash between nativesdk-cmake and nativesdk-qtbase-tools
 166 # (revalidate after 2017-10-15, 2018-06-12: still required)
 167 DIRFILES_pn-nativesdk-cmake = "1"
 168
 169 # For https://jira.automotivelinux.org/browse/SPEC-1629 :
 170 # We exclude the conflicting vars from the sstate task hash.
 171 # This needs to be verified.
 172 do_package_write_rpm[vardepsexclude] += "ARCHIVER_TOPDIR PF"
 173
 174 # Set preferred provider to new navi application
 175 PREFERRED_RPROVIDER_virtual/navigation ?= "ondemandnavi"
 176
 177 # Set preferred provider for low-can device mapping configuration
 178 PREFERRED_RPROVIDER_virtual/low-can-dev-mapping ?= "dev-mapping"
 179
 180 # Mask upstream meta-security bbappend that interferes with non-linux-yocto
 181 # kernels due to the bug of having two wildcards, which bitbake does not
 182 # support. Not having it is not an issue, since there is also explicit
 183 # enabling of required security features done by meta-agl/meta-security.
 184 BBMASK += "meta-security/recipes-kernel/linux/linux-%_5.%.bbappend"
 185
 186 # Workaround for https://jira.automotivelinux.org/browse/SPEC-3621
 187 # TLDR: do_image_wic will modify the target's /etc/fstab while
 188 # do_image_tar and do_image_ext4 can run in parallel
 189 # This needs to be fixed upstream:
 190 # See https://bugzilla.yoctoproject.org/show_bug.cgi?id=13994
 191 INHERIT += "image_types_wic_workaround"