meta-agl-core/conf/distro/poky-agl.conf

   1 require conf/distro/poky.conf
   2
   3 # Insert overrides "agldefaulttune" and "forcedefaulttune" before forcevariable
   4 OVERRIDES = "${TARGET_OS}:${TRANSLATED_TARGET_ARCH}:pn-${PN}:${MACHINEOVERRIDES}:${DISTROOVERRIDES}:${CLASSOVERRIDE}${LIBCOVERRIDE}:agldefaulttune:forcedefaulttune:forcevariable"
   5
   6 # AGL specific derivations
   7 DISTRO = "poky-agl"
   8 DISTRO_NAME = "Automotive Grade Linux"
   9
  10
  11 # Release flags
  12 DISTRO_CODENAME = "ricefish"
  13 AGL_BRANCH = "master"
  14 AGLVERSION = "17.90.0"
  15
  16 # switch  devel/release
  17 #AGLRELEASETYPE ?= "agldevelopment"
  18 AGLRELEASETYPE := "aglrelease"
  19
  20 OVERRIDES .= ":${AGLRELEASETYPE}"
  21
  22 #for development
  23 DISTRO_VERSION:agldevelopment := "${AGLVERSION}+snapshot-${METADATA_REVISION}"
  24
  25 #for release
  26 DISTRO_VERSION:aglrelease := "${AGLVERSION}"
  27 DISTRO_BRANCH_VERSION_TAG = "${DISTRO_CODENAME}/${@'${DISTRO_VERSION}'.replace('+snapshot-${METADATA_REVISION}','')}"
  28
  29 #for next branch development
  30 OVERRIDES .= ":aglnext"
  31
  32 # reproducible builds:
  33 # Set the desired timestamps
  34 # E.g. update for (major) releases
  35 export SOURCE_DATE_EPOCH = "1706800000"
  36 REPRODUCIBLE_TIMESTAMP_ROOTFS = "1706800000"
  37
  38
  39 # SDK
  40 SDK_VENDOR = "-aglsdk"
  41
  42 # SDKPATHINSTALL is the folder where the SDK is going to be installed
  43 # Due to an issue with the qt5 environment (see SPEC-1667),
  44 # we add DEFAULTTUNE to the SDKPATH to mitigate the issue.
  45 SDKPATHINSTALL = "/opt/agl-sdk/${SDK_VERSION}-${DEFAULTTUNE}"
  46
  47
  48 MAINTAINER = "AGL https://lists.automotivelinux.org/g/agl-dev-community"
  49
  50 TARGET_VENDOR = "-agl"
  51
  52 # Override these in poky based distros
  53 AGL_DEFAULT_DISTRO_FEATURES = "usrmerge largefile opengl wayland pam bluetooth bluez5 3g polkit"
  54 POKY_DEFAULT_DISTRO_FEATURES := "${AGL_DEFAULT_DISTRO_FEATURES}"
  55 OVERRIDES .= ":${DISTRO_CODENAME}"
  56
  57 DISTRO_FEATURES:remove = "x11"
  58 DISTRO_FEATURES_BACKFILL_CONSIDERED = "pulseaudio"
  59
  60 INIT_MANAGER = "systemd"
  61 # Override default of "systemd-compat-units"
  62 VIRTUAL-RUNTIME_initscripts = ""
  63 # Override default of "busybox-syslog"
  64 VIRTUAL-RUNTIME_base-utils-syslog = ""
  65
  66 # network manager to use (possible values: systemd, connman)
  67 VIRTUAL-RUNTIME_net_manager = "connman"
  68
  69
  70 QEMU_TARGETS ?= "arm aarch64 i386 x86_64 riscv64"
  71 # Other QEMU_TARGETS "mips mips64 mips64el ppc sh4"
  72
  73 MIRRORS =+ "\
  74 bzr://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  75 cvs://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  76 git://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  77 gitsm://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  78 hg://.*/.*       https://download.automotivelinux.org/AGL/mirror/ \n \
  79 osc://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  80 p4://.*/.*       https://download.automotivelinux.org/AGL/mirror/ \n \
  81 svn://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  82 bzr://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  83 cvs://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  84 git://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  85 gitsm://.*/.*    http://download.automotivelinux.org/AGL/mirror/  \n \
  86 hg://.*/.*       http://download.automotivelinux.org/AGL/mirror/  \n \
  87 osc://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  88 p4://.*/.*       http://download.automotivelinux.org/AGL/mirror/  \n \
  89 svn://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  90                  \
  91 ftp://.*/.*      https://download.automotivelinux.org/AGL/mirror/ \n \
  92 http://.*/.*     https://download.automotivelinux.org/AGL/mirror/ \n \
  93 https://.*/.*    https://download.automotivelinux.org/AGL/mirror/ \n \
  94 ftp://.*/.*      http://download.automotivelinux.org/AGL/mirror/  \n \
  95 http://.*/.*     http://download.automotivelinux.org/AGL/mirror/  \n \
  96 https://.*/.*    http://download.automotivelinux.org/AGL/mirror/  \n \
  97 "
  98
  99 # The CONNECTIVITY_CHECK_URI's are used to test whether we can succesfully
 100 # fetch from the network (and warn you if not). To disable the test set
 101 # the variable to be empty.
 102 # Git example url: git://git.yoctoproject.org/yocto-firewall-test;protocol=git;rev=HEAD
 103 CONNECTIVITY_CHECK_URIS ?= ""
 104
 105 # using multiple BSP layers causes dangling bbappends in meta-agl-bsp
 106 # turn it into a warning
 107 #BB_DANGLINGAPPENDS_WARNONLY = "1"
 108
 109 # Not yet upstreamed; should be submitted.
 110 SECURITY_CFLAGS:pn-qtwebengine = "${SECURITY_NO_PIE_CFLAGS}"
 111
 112 # AGL uses 4 optimization levels
 113 # 2 for ARM 32bit
 114 #   - a high and a medium setting for the CCARGS
 115 #   - the high setting is default (needs >= cortex-a15)
 116 #   - the medium setting is enabled with: DISTRO_FEATURES:append = " agl-medium-arm-compiler "
 117 # 1 for ARM 64bit / AARCH64
 118 # 1 for x86-64
 119 # 1 for RISC-V 64-bit
 120 require conf/distro/include/${TARGET_ARCH}-tune.inc
 121
 122 # Generic qemu and qemuboot (runqemu) enhancements
 123 # check qemuboot.bbclass
 124 # - use 2G RAM by default
 125 QB_MEM ?= "-m 2048"
 126 # use pulseaudio on the host side - off as qemu-native is built with alsa
 127 #QB_AUDIO_DRV = "pa"
 128 # expose a virtual 'hda' sound card to the guest (arm/aarch64/x86-64)
 129 QB_AUDIO_OPT = "-device intel-hda -device hda-duplex -audiodev alsa,id=agl"
 130
 131 # Board templates can add extra IMAGE_FSTYPES through this.
 132 # It is added (late) through the AGL image recipes.
 133 AGL_EXTRA_IMAGE_FSTYPES ??= ""
 134 AGL_EXTRA_INITRAMFS_FSTYPES ??= ""
 135 #
 136 # Default IMAGE FSTYPES wic.xz
 137 AGL_DEFAULT_IMAGE_FSTYPES ?= "wic.xz wic.bmap wic.xz.sha256sum"
 138 AGL_DEFAULT_IMAGE_FSTYPES:qemuall ?= "${@bb.utils.contains('AGL_FEATURES', 'AGLCI', 'ext4.xz', 'ext4', d)}"
 139 AGL_DEFAULT_IMAGE_FSTYPES:append:netboot = " ${@bb.utils.contains('AGL_FEATURES', 'AGLCI', 'ext4.xz', 'ext4', d)}"
 140 AGL_DEFAULT_INITRAMFS_FSTYPES ?= "ext4.gz"
 141
 142 # DEFAULT IMAGE_FSTYPES for AGL (no - BSPs should not set this)
 143 #
 144 IMAGE_FSTYPES = "${AGL_DEFAULT_IMAGE_FSTYPES} ${AGL_EXTRA_IMAGE_FSTYPES}"
 145 INITRAMFS_FSTYPES = "${AGL_DEFAULT_INITRAMFS_FSTYPES} ${AGL_EXTRA_INITRAMFS_FSTYPES}"
 146 #