meta-agl-bsp/virtualization-layer/recipes-kernel/linux/linux-yocto_5.10.bb

   1 KBRANCH ?= "v5.10/standard/base"
   2
   3 require recipes-kernel/linux/linux-yocto.inc
   4
   5 # board specific branches
   6 KBRANCH:qemuarm  ?= "v5.10/standard/arm-versatile-926ejs"
   7 KBRANCH:qemuarm64 ?= "v5.10/standard/qemuarm64"
   8 KBRANCH:qemumips ?= "v5.10/standard/mti-malta32"
   9 KBRANCH:qemuppc  ?= "v5.10/standard/qemuppc"
  10 KBRANCH:qemuriscv64  ?= "v5.10/standard/base"
  11 KBRANCH:qemuriscv32  ?= "v5.10/standard/base"
  12 KBRANCH:qemux86  ?= "v5.10/standard/base"
  13 KBRANCH:qemux86-64 ?= "v5.10/standard/base"
  14 KBRANCH:qemumips64 ?= "v5.10/standard/mti-malta64"
  15
  16 SRCREV_machine:qemuarm ?= "d8551cae1ccdbe062a5c6068ce39ea8f4e1c72db"
  17 SRCREV_machine:qemuarm64 ?= "cf5b0320cf4544d3db9ce3ddd6ddb7553a610651"
  18 SRCREV_machine:qemumips ?= "7f1f1ad2f2d90b1b070c6b0a82f0add9aa492e37"
  19 SRCREV_machine:qemuppc ?= "cf5b0320cf4544d3db9ce3ddd6ddb7553a610651"
  20 SRCREV_machine:qemuriscv64 ?= "cf5b0320cf4544d3db9ce3ddd6ddb7553a610651"
  21 SRCREV_machine:qemuriscv32 ?= "cf5b0320cf4544d3db9ce3ddd6ddb7553a610651"
  22 SRCREV_machine:qemux86 ?= "cf5b0320cf4544d3db9ce3ddd6ddb7553a610651"
  23 SRCREV_machine:qemux86-64 ?= "cf5b0320cf4544d3db9ce3ddd6ddb7553a610651"
  24 SRCREV_machine:qemumips64 ?= "fd5ac097b891642eea13659bea536f3ec5910d6d"
  25 SRCREV_machine ?= "cf5b0320cf4544d3db9ce3ddd6ddb7553a610651"
  26 SRCREV_meta ?= "031f6c76e488a3563f35258c72ff1de3e25a512e"
  27
  28 # remap qemuarm to qemuarma15 for the 5.8 kernel
  29 # KMACHINE:qemuarm ?= "qemuarma15"
  30
  31 SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;name=machine;branch=${KBRANCH}; \
  32            git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.10;destsuffix=${KMETA}"
  33
  34 LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
  35 LINUX_VERSION ?= "5.10.25"
  36
  37 DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
  38 DEPENDS += "openssl-native util-linux-native"
  39 DEPENDS += "gmp-native"
  40
  41 PV = "${LINUX_VERSION}+git${SRCPV}"
  42
  43 KMETA = "kernel-meta"
  44 KCONF_BSP_AUDIT_LEVEL = "1"
  45
  46 KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb"
  47
  48 COMPATIBLE_MACHINE = "qemuarm|qemuarmv5|qemuarm64|qemux86|qemuppc|qemuppc64|qemumips|qemumips64|qemux86-64|qemuriscv64|qemuriscv32"
  49
  50 # Functionality flags
  51 KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc"
  52 KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
  53 KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
  54 KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
  55 KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
  56 KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
  57 KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
  58 KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc", "", d)}"