meta-agl-bsp/recipes-kernel/linux/linux-agl.inc

   1 FILESEXTRAPATHS_prepend := "${THISDIR}/linux:"
   2
   3 DEPENDS += "kern-tools-native"
   4
   5 # returns all the elements from the src uri that are .cfg files
   6 def find_cfgs(d):
   7     sources=src_patches(d, True)
   8     sources_list=[]
   9     for s in sources:
  10         if s.endswith('.cfg'):
  11             sources_list.append(s)
  12
  13     return sources_list
  14
  15 do_configure_append () {
  16     [ ! -f .config ] && cp -a ${WORKDIR}/defconfig .config
  17     merge_config.sh -m .config ${@" ".join(find_cfgs(d))}
  18     yes '' | make oldconfig
  19 }
  20
  21 # Extra configuration options for the AGL kernel
  22 SRC_URI_append = "\
  23             file://can-bus.cfg \
  24             file://usb.cfg \
  25             file://uvc.cfg \
  26             file://joystick.cfg \
  27             file://fanotify.cfg \
  28             file://uinput.cfg \
  29             file://hid.cfg \
  30             file://drm.cfg \
  31             file://btusb.cfg \
  32             file://usbaudio.cfg \
  33             "
  34 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/can-bus.cfg"
  35 # Enable support for usb video class for usb camera devices
  36 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/uvc.cfg"
  37 # Enable support for joystick devices
  38 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/joystick.cfg"
  39 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/fanotify.cfg"
  40 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/uinput.cfg"
  41 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/hid.cfg"
  42 # Enable DRM support for graphics
  43 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/drm.cfg"
  44 # Enable Bluetooth USB devices
  45 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/btusb.cfg"
  46 # Enable USB audio devices
  47 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/usbaudio.cfg"
  48
  49 # Enable required features for the agl-netboot feature
  50 SRC_URI_append_netboot = " file://nbd.cfg \
  51         file://ramdisk.cfg"
  52 KERNEL_CONFIG_FRAGMENTS_append_netboot = " ${WORKDIR}/nbd.cfg ${WORKDIR}/ramdisk.cfg"
  53
  54 # Enable support for TP-Link TL-W722N USB Wifi adapter
  55 SRC_URI_append = " file://ath9k_htc.cfg"
  56 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/ath9k_htc.cfg"
  57
  58 # Enable support for RTLSDR
  59 SRC_URI_append = " file://rtl_sdr.cfg"
  60 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/rtl_sdr.cfg"
  61
  62 # Additional drivers for virtual machines
  63 # OVERRIDES save us some c'n'p below ...
  64 OVERRIDES_prepend_qemux86 = "virtualmachine:"
  65 OVERRIDES_prepend_qemux86-64 = "virtualmachine:"
  66 SRC_URI_append_virtualmachine = " file://vbox-vmware-sata.cfg"
  67 KERNEL_CONFIG_FRAGMENTS_append_virtualmachine = " ${WORKDIR}/vbox-vmware-sata.cfg"
  68
  69 # Enable support for smack
  70 KERNEL_CONFIG_FRAGMENTS_append_with-lsm-smack = "\
  71        ${WORKDIR}/audit.cfg \
  72        ${WORKDIR}/smack.cfg \
  73        ${WORKDIR}/smack-default-lsm.cfg \
  74 "