meta-agl-bsp/recipes-kernel/linux/linux-agl.inc

   1 FILESEXTRAPATHS_prepend := "${THISDIR}/linux:"
   2
   3 DEPENDS += "kern-tools-native"
   4
   5 # returns all the elements from the src uri that are .cfg files
   6 def find_cfgs(d):
   7     sources=src_patches(d, True)
   8     sources_list=[]
   9     for s in sources:
  10         if s.endswith('.cfg'):
  11             sources_list.append(s)
  12
  13     return sources_list
  14
  15 do_configure_append () {
  16     [ ! -f .config ] && cp -a ${WORKDIR}/defconfig .config
  17     # Need to clear CONFIG_LSM for 5.1+ kernels to ensure it'll get
  18     # regenerated to reflect configuration changes (e.g. SMACK).
  19     sed -i '/^CONFIG_LSM/d' .config
  20     merge_config.sh -m .config ${@" ".join(find_cfgs(d))}
  21     yes '' | make oldconfig
  22 }
  23
  24 # Extra configuration options for the AGL kernel
  25 SRC_URI_append = "\
  26             file://can-bus.cfg \
  27             file://usb.cfg \
  28             file://uvc.cfg \
  29             file://joystick.cfg \
  30             file://fanotify.cfg \
  31             file://uinput.cfg \
  32             file://hid.cfg \
  33             file://drm.cfg \
  34             file://btusb.cfg \
  35             file://usbaudio.cfg \
  36             file://usbmodem.cfg \
  37             file://i2c-led.cfg \
  38             file://nfc.cfg \
  39         "
  40
  41 SRC_URI_append = " ${@bb.utils.contains('AGL_XEN_GUEST_WANTED','1','file://xen_domu.cfg','',d)}"
  42
  43 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/can-bus.cfg"
  44 # Enable support for usb video class for usb camera devices
  45 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/uvc.cfg"
  46 # Enable support for joystick devices
  47 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/joystick.cfg"
  48 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/fanotify.cfg"
  49 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/uinput.cfg"
  50 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/hid.cfg"
  51 # Enable DRM support for graphics
  52 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/drm.cfg"
  53 # Enable Bluetooth USB devices
  54 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/btusb.cfg"
  55 # Enable USB audio devices
  56 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/usbaudio.cfg"
  57 # Enable I2C and LED for demontrator
  58 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/i2c-led.cfg"
  59 # Enable NFC devices
  60 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/nfc.cfg"
  61 # Enable XEN support of the guest
  62 KERNEL_CONFIG_FRAGMENTS_append = " ${@bb.utils.contains('AGL_XEN_GUEST_WANTED','1','${WORKDIR}/xen_domu.cfg','',d)}"
  63
  64 # Enable required features for the agl-netboot feature
  65 SRC_URI_append_netboot = " file://nbd.cfg \
  66         file://ramdisk.cfg"
  67 KERNEL_CONFIG_FRAGMENTS_append_netboot = " ${WORKDIR}/nbd.cfg ${WORKDIR}/ramdisk.cfg"
  68
  69 # Enable support for TP-Link TL-W722N USB Wifi adapter (rev 1 and 2)
  70 SRC_URI_append = " file://wifi.cfg"
  71 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/wifi.cfg"
  72
  73 # Enable support for RTLSDR
  74 SRC_URI_append = " file://rtl_sdr.cfg"
  75 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/rtl_sdr.cfg"
  76
  77 # Additional drivers for virtual machines
  78 # OVERRIDES save us some c'n'p below ...
  79 OVERRIDES_prepend_qemux86 = "virtualmachine:"
  80 OVERRIDES_prepend_qemux86-64 = "virtualmachine:"
  81 SRC_URI_append_virtualmachine = " file://vbox-vmware-sata.cfg"
  82 KERNEL_CONFIG_FRAGMENTS_append_virtualmachine = " ${WORKDIR}/vbox-vmware-sata.cfg"
  83
  84 # Extra configuration for using qemux86-64 image on physical hardware
  85 SRC_URI_append_qemux86-64 = "\
  86     file://x86-extra-graphic-devices.cfg \
  87     file://x86-net-devices.cfg \
  88     file://x86-security-tpm.cfg \
  89     file://x86-usb-devices.cfg \
  90     file://x86-upsquare.cfg \
  91 "
  92 KERNEL_CONFIG_FRAGMENTS_append_qemux86-64 = "\
  93     ${WORKDIR}/x86-extra-graphic-devices.cfg \
  94     ${WORKDIR}/x86-net-devices.cfg \
  95     ${WORKDIR}/x86-security-tpm.cfg \
  96     ${WORKDIR}/x86-usb-devices.cfg \
  97     ${WORKDIR}/x86-upsquare.cfg \
  98 "
  99
 100 # Enable support for smack
 101 KERNEL_CONFIG_FRAGMENTS_append_with-lsm-smack = "\
 102        ${WORKDIR}/audit.cfg \
 103        ${WORKDIR}/smack.cfg \
 104        ${WORKDIR}/smack-default-lsm.cfg \
 105 "
 106
 107 # ALSA support and other sound related configuration
 108 SRC_URI_append = " file://sound.cfg"
 109 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/sound.cfg"
 110
 111 # iio-dummy-device support for test iiodevice
 112 SRC_URI_append = " file://iiodevice.cfg"
 113 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/iiodevice.cfg"
 114
 115 # external rtc support via e.g. http://wiki.seeedstudio.com/Grove-RTC/
 116 SRC_URI_append = " file://rtc.cfg"
 117 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/rtc.cfg"
 118
 119 # netfilter options
 120 SRC_URI_append = " file://netfilter.cfg"
 121 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/netfilter.cfg"
 122
 123 # Enable support for SystemTap
 124 SRC_URI_append = " ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', 'file://systemtap.cfg', '', d)}"
 125 KERNEL_CONFIG_FRAGMENTS_append = " ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', '${WORKDIR}/systemtap.cfg', '', d)}"