meta-agl-bsp/recipes-kernel/linux/linux-agl.inc

   1 FILESEXTRAPATHS_prepend := "${THISDIR}/linux:"
   2
   3 DEPENDS += "kern-tools-native"
   4
   5 # returns all the elements from the src uri that are .cfg files
   6 def find_cfgs(d):
   7     sources=src_patches(d, True)
   8     sources_list=[]
   9     for s in sources:
  10         if s.endswith('.cfg'):
  11             sources_list.append(s)
  12
  13     return sources_list
  14
  15 do_configure_append () {
  16     [ ! -f .config ] && cp -a ${WORKDIR}/defconfig .config
  17     merge_config.sh -m .config ${@" ".join(find_cfgs(d))}
  18     yes '' | make oldconfig
  19 }
  20
  21 # Extra configuration options for the AGL kernel
  22 SRC_URI_append = "\
  23             file://can-bus.cfg \
  24             file://usb.cfg \
  25             file://uvc.cfg \
  26             file://joystick.cfg \
  27             file://fanotify.cfg \
  28             file://uinput.cfg \
  29             file://hid.cfg \
  30             file://drm.cfg \
  31             file://btusb.cfg \
  32             file://usbaudio.cfg \
  33             file://i2c-led.cfg \
  34             file://nfc.cfg \
  35             "
  36 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/can-bus.cfg"
  37 # Enable support for usb video class for usb camera devices
  38 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/uvc.cfg"
  39 # Enable support for joystick devices
  40 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/joystick.cfg"
  41 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/fanotify.cfg"
  42 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/uinput.cfg"
  43 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/hid.cfg"
  44 # Enable DRM support for graphics
  45 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/drm.cfg"
  46 # Enable Bluetooth USB devices
  47 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/btusb.cfg"
  48 # Enable USB audio devices
  49 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/usbaudio.cfg"
  50 # Enable I2C and LED for demontrator
  51 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/i2c-led.cfg"
  52 # Enable NFC devices
  53 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/nfc.cfg"
  54
  55 # Enable required features for the agl-netboot feature
  56 SRC_URI_append_netboot = " file://nbd.cfg \
  57         file://ramdisk.cfg"
  58 KERNEL_CONFIG_FRAGMENTS_append_netboot = " ${WORKDIR}/nbd.cfg ${WORKDIR}/ramdisk.cfg"
  59
  60 # Enable support for TP-Link TL-W722N USB Wifi adapter
  61 SRC_URI_append = " file://ath9k_htc.cfg"
  62 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/ath9k_htc.cfg"
  63
  64 # Enable support for RTLSDR
  65 SRC_URI_append = " file://rtl_sdr.cfg"
  66 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/rtl_sdr.cfg"
  67
  68 # Additional drivers for virtual machines
  69 # OVERRIDES save us some c'n'p below ...
  70 OVERRIDES_prepend_qemux86 = "virtualmachine:"
  71 OVERRIDES_prepend_qemux86-64 = "virtualmachine:"
  72 SRC_URI_append_virtualmachine = " file://vbox-vmware-sata.cfg"
  73 KERNEL_CONFIG_FRAGMENTS_append_virtualmachine = " ${WORKDIR}/vbox-vmware-sata.cfg"
  74
  75 # Enable support for smack
  76 KERNEL_CONFIG_FRAGMENTS_append_with-lsm-smack = "\
  77        ${WORKDIR}/audit.cfg \
  78        ${WORKDIR}/smack.cfg \
  79        ${WORKDIR}/smack-default-lsm.cfg \
  80 "
  81
  82 # snd-aloop support for 4a
  83 SRC_URI_append = " file://4a-sound.cfg"
  84 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/4a-sound.cfg"
  85
  86 # iio-dummy-device support for test iiodevice
  87 SRC_URI_append = " file://iiodevice.cfg"
  88 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/iiodevice.cfg"