meta-agl-bsp/recipes-kernel/linux/linux-agl.inc

   1 FILESEXTRAPATHS_prepend := "${THISDIR}/linux:"
   2
   3 DEPENDS += "kern-tools-native"
   4
   5 # returns all the elements from the src uri that are .cfg files
   6 def find_cfgs(d):
   7     sources=src_patches(d, True)
   8     sources_list=[]
   9     for s in sources:
  10         if s.endswith('.cfg'):
  11             sources_list.append(s)
  12
  13     return sources_list
  14
  15 do_configure_append () {
  16     [ ! -f .config ] && cp -a ${WORKDIR}/defconfig .config
  17     merge_config.sh -m .config ${@" ".join(find_cfgs(d))}
  18     yes '' | make oldconfig
  19 }
  20
  21 # Extra configuration options for the AGL kernel
  22 SRC_URI_append = "\
  23             file://can-bus.cfg \
  24             file://usb.cfg \
  25             file://uvc.cfg \
  26             file://joystick.cfg \
  27             file://fanotify.cfg \
  28             file://uinput.cfg \
  29             file://hid.cfg \
  30             file://drm.cfg \
  31             file://btusb.cfg \
  32             file://usbaudio.cfg \
  33             file://usbmodem.cfg \
  34             file://i2c-led.cfg \
  35             file://nfc.cfg \
  36             "
  37 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/can-bus.cfg"
  38 # Enable support for usb video class for usb camera devices
  39 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/uvc.cfg"
  40 # Enable support for joystick devices
  41 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/joystick.cfg"
  42 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/fanotify.cfg"
  43 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/uinput.cfg"
  44 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/hid.cfg"
  45 # Enable DRM support for graphics
  46 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/drm.cfg"
  47 # Enable Bluetooth USB devices
  48 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/btusb.cfg"
  49 # Enable USB audio devices
  50 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/usbaudio.cfg"
  51 # Enable I2C and LED for demontrator
  52 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/i2c-led.cfg"
  53 # Enable NFC devices
  54 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/nfc.cfg"
  55
  56 # Enable required features for the agl-netboot feature
  57 SRC_URI_append_netboot = " file://nbd.cfg \
  58         file://ramdisk.cfg"
  59 KERNEL_CONFIG_FRAGMENTS_append_netboot = " ${WORKDIR}/nbd.cfg ${WORKDIR}/ramdisk.cfg"
  60
  61 # Enable support for TP-Link TL-W722N USB Wifi adapter
  62 SRC_URI_append = " file://ath9k_htc.cfg"
  63 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/ath9k_htc.cfg"
  64
  65 # Enable support for RTLSDR
  66 SRC_URI_append = " file://rtl_sdr.cfg"
  67 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/rtl_sdr.cfg"
  68
  69 # Additional drivers for virtual machines
  70 # OVERRIDES save us some c'n'p below ...
  71 OVERRIDES_prepend_qemux86 = "virtualmachine:"
  72 OVERRIDES_prepend_qemux86-64 = "virtualmachine:"
  73 SRC_URI_append_virtualmachine = " file://vbox-vmware-sata.cfg"
  74 KERNEL_CONFIG_FRAGMENTS_append_virtualmachine = " ${WORKDIR}/vbox-vmware-sata.cfg"
  75
  76 # Enable support for smack
  77 KERNEL_CONFIG_FRAGMENTS_append_with-lsm-smack = "\
  78        ${WORKDIR}/audit.cfg \
  79        ${WORKDIR}/smack.cfg \
  80        ${WORKDIR}/smack-default-lsm.cfg \
  81 "
  82
  83 # ALSA support and other sound related configuration
  84 SRC_URI_append = " file://sound.cfg"
  85 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/sound.cfg"
  86
  87 # iio-dummy-device support for test iiodevice
  88 SRC_URI_append = " file://iiodevice.cfg"
  89 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/iiodevice.cfg"
  90
  91 # external rtc support via e.g. http://wiki.seeedstudio.com/Grove-RTC/
  92 SRC_URI_append = " file://rtc.cfg"
  93 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/rtc.cfg"
  94
  95 # netfilter options
  96 SRC_URI_append = " file://netfilter.cfg"
  97 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/netfilter.cfg"